为什么 VIProductVersion 参数会覆盖 ProductVersion 键的值？

Question

nsi 脚本中的代码片段：

VIProductVersion 1.2.0.0   
VIAddVersionKey /LANG=${LANG_ENGLISH} FileVersion 1.1.0.0

我想将 FileVersion 设置为 1.1.0.0，但在文件属性中它设置为 1.2.0.0。我还注意到，单独执行的 VIProductVersion 添加了 FileVersion 键并设置其值。

文档显示 VIProductVersion 添加了产品版本但我看到的是 FileVersion 实际上已添加。这是 NSIS 的错误吗？如果 VIAddVersionKey FileVersion 设置的值被 VIProductVersion 设置的值覆盖，那么它的用途是什么？

VIAddVersionKey 需要 VIProductVersion 调用，否则脚本无法编译。

我正在使用的版本：EclipseNSIS 0.9.8； MakeNSIS 2.46。操作系统：Windows 7。

Answer 1

版本信息资源存储在两部分中：

• VS_FIXEDFILEINFO 是一个包含产品和文件版本的固定块，VIProductVersion 设置此
• 零个、一个或多个（多种语言）带有一个或多个 name=value 字符串的字符串块，VIAddVersionKey 设置这些。

某些应用程序使用 FileVersion 字符串，如果该字符串不存在，则回退到 VS_FIXEDFILEINFO::dwFileVersion，其他应用程序仅使用 VS_FIXEDFILEINFO::dwFileVersion 等。

VIProductVersion "1.2.3.4" 将生成一个版本标头，该标头看起来

1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1

这通常就足够了，但它不会让你设置 PRODUCTVERSION != FILEVERSION。

我认为这是 NSIS 中的一个错误，他们应该添加一个 VIFileVersion 命令或将 VIProductVersion 扩展为 VIProductVersion; [文件管理器]。

您可以在跟踪器上添加功能请求。

同时，您可以通过在构建期间调用 资源黑客 来解决此问题使用 !packhdr

---

编辑：

可以在编译时使用 !packhdr、外部第 3 方工具在 2.46 中完成（我无法让 reshacker 导入 .rc 版本资源，所以我不得不首先转换为 .res）和可怕的黑客：

!macro HackyVIFileVersion reshack gorcjorg fixedfilever
;http://www.angusj.com/resourcehacker/
;http://web.archive.org/web/20090918063311/http://www.jorgon.freeserve.co.uk/Gorcjorg.zip
!searchreplace HackyVIFileVersion_id "${__TIME__}" ":" ""
!define HackyVIFileVersion_cmd "$%TEMP%\nsisVIFV${HackyVIFileVersion_id}.cmd"
!appendfile "${HackyVIFileVersion_cmd}" `@echo off&setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set eh=%TEMP%\exehead%~1.tmp$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set rh=%~2$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -extract "%eh%", "%eh%1.rc", VersionInfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `> "%eh%2.rc" echo.LANGUAGE LANG_ENGLISH, SUBLANG_ENGLISH_US $\n` ;must force lang for Gorcjorg
!appendfile "${HackyVIFileVersion_cmd}" `FOR /F "usebackq tokens=* delims=" %%A IN ("%eh%1.rc") DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `   FOR /F "usebackq" %%B IN ('%%A') DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `       if "%%~B"=="FILEVERSION" (>> "%eh%2.rc" echo.FILEVERSION %~4) else (>> "%eh%2.rc" echo.%%A)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `   )$\n`
!appendfile "${HackyVIFileVersion_cmd}" `)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%~3" /fo "%eh%.res" /r "%eh%2.rc"$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -addoverwrite "%eh%", "%eh%", "%eh%.res", versioninfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `del "%eh%2.rc"&del "%eh%1.rc"&del "%eh%.res"&del "%~0"`
!packhdr "$%TEMP%\exehead${HackyVIFileVersion_id}.tmp" '"${HackyVIFileVersion_cmd}" "${HackyVIFileVersion_id}" "${reshack}" "${gorcjorg}" "${fixedfilever}"'
!undef HackyVIFileVersion_cmd
!undef HackyVIFileVersion_id 
!macroend


VIProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 FileVersion 5.6.7.8
VIAddVersionKey /LANG=1033 ProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 Comments "A test comment"
!insertmacro HackyVIFileVersion "C:\tools\ResHacker.exe" "C:\tools\GoRC.exe" "5,6,7,8"

......你最终得到这个版本资源：

1 VERSIONINFO
FILEVERSION 5,6,7,8
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1
{
BLOCK "StringFileInfo"
{
    BLOCK "040904e4"
    {
        VALUE "Comments", "A test comment"
        VALUE "FileVersion", "5.6.7.8"
        VALUE "ProductVersion", "1.2.3.4"
    }
}

BLOCK "VarFileInfo"
{
    VALUE "Translation", 0x0409 0x04E4
}
}

Answer 2

我想我应该提到这个错误的明显解决方法。

使用 NSIS 2.46 将 VIProductVersion 设置为您的 FileVersion，然后使用 VIAddVersionKey 设置 ProductVersion，您还需要设置文件版本以避免 NSIS 编译器警告。

VIProductVersion ${INSTALLER_VERSION}
VIAddVersionKey ProductName ${PROGRAM_NAME}
VIAddVersionKey FileVersion ${INSTALLER_VERSION}
VIAddVersionKey ProductVersion ${PROGRAM_VERSION}
...