如何设置 AoArrayrefs 属性并从标量强制转换为 arrayref？

Question

我想设置一个属性，它是一个 arrayrefs 数组，并将非 arrayrefs 强制转换为数组引用。例如。

[ 0, [ 0, 0, 0 ], [1,2,3] ] 到 [ [0], [ 0, 0, 0 ], [1,2,3] ]

另外，我希望能够也可以通过强制方式将元素推送或设置到 AoA。这是我的尝试：

{
    package MyArray;
    use namespace::autoclean;
    use Moose::Util::TypeConstraints;
    use Moose;

    subtype 'My::ArrayRef' => as 'ArrayRef';
    coerce  'My::ArrayRef'
      => from 'Num|Str'
         => via {[$_]};

    has 'ents' => (
        traits  => ['Array'],
        is      => 'rw',
        isa     => 'ArrayRef[My::ArrayRef]',
        default => sub { [] },
        handles => {
            push      => 'push',
            get       => 'get',
            set       => 'set',
            elements  => 'elements',
            count     => 'count',
        },
        coerce => 1,
    );

    __PACKAGE__->meta->make_immutable;

}

use Modern::Perl;

my $a0 = MyArray->new( ents => [ 0, [ 0, 0, 0 ], [1,2,3] ] ) ;

use Data::Dumper;

print Dumper $a0;

$a0->set(0,'cat');
print Dumper $a0;
$a0->push(1.0);
print Dumper $a0;

Answer 1

该类型需要在强制转换之前匹配失败，但在强制转换之后成功。

这可以解决问题（已测试）：

my $array_ref = Moose::Util::TypeConstraints::find_type_constraint('ArrayRef');

# Create an alias so we don't affect others with our coercion.
subtype 'My::Data::Structure'
   => as 'ArrayRef[ArrayRef[Str|Num]]';

coerce 'My::Data::Structure'
   => from 'ArrayRef[ArrayRef[Str|Num]|Str|Num]'
      => via { [ map $array_ref->check($_) ? $_ : [ $_ ], @$_ ] };