在 Windows 批处理文件中访问剪贴板

Question

知道如何使用批处理文件访问 Windows 剪贴板吗？

Answer 1

精简它（在足够新的 Windows 版本上）：

set _getclip=powershell "Add-Type -Assembly PresentationCore;[Windows.Clipboard]::GetText()"
for /f "eol=; tokens=*" %I in ('%_getclip%') do set CLIPBOARD_TEXT=%I

1. 第一行声明一个 powershell commandlet。
2. 第二行运行并将此命令行开关的控制台输出捕获到 CLIPBOARD_TEXT 环境变量中（cmd.exe 执行 bash 样式反引号的最接近方法` capture)

---

更新 2017-12-04：

感谢 @Saintali 指出 PowerShell 5.0 添加了 Get-Clipboard 作为顶层cmdlet，因此现在它可以作为单行：

for /f "eol=; tokens=*" %I in ('powershell Get-Clipboard') do set CLIPBOARD_TEXT=%I

Answer 2

Clip 命令可以很好地将文本通过管道传输到剪贴板，但它无法从剪贴板读取。 vbscript / javascript 中有一种方法可以读取/写入剪贴板，但它使用自动化和一个不可见的实例（如果 Internet Explorer 执行此操作），因此它非常丰富。

我发现用于通过脚本操作剪贴板的最佳工具是 Nirsoft 的免费 NirCmd 工具。

http://www.nirsoft.net/utils/nircmd.html

它就像瑞士人批处理命令的军刀全部在一个小 .exe 文件中。对于剪贴板命令，您会说类似

nircmd Clipboard [Action] [Parameter]

另外，您可以使用 ~$clipboard$ 变量作为参数直接引用其任何命令中的剪贴板内容。 Nircmd 中还包含用于运行其他程序或命令的命令，因此可以使用它以这种方式将剪贴板内容作为参数传递给其他批处理命令。

剪贴板操作：

      set - set the specified text into the clipboard. 
 readfile - set the content of the specified text file into the clipboard. 
    clear - clear the clipboard. 
writefile - write the content of the clipboard to a file. (text only) 
  addfile - add the content of the clipboard to a file. (text only) 
saveimage - Save the current image in the clipboard into a file. 
copyimage - Copy the content of the specified image file to the clipboard. 
  saveclp - Save the current clipboard data into Windows .clp file. 
  loadclp - Load Windows .clp file into the clipboard. 

请注意，大多数程序始终会向剪贴板写入纯文本副本，即使它们正在向剪贴板写入特殊的 RTF 或 HTML 副本，但这些程序是使用不同的剪贴板格式类型作为内容写入的，因此您可能无法访问这些格式，除非您的程序明确请求剪贴板中的该类型的数据。

Answer 3

我知道的最好方法是使用名为 WINCLIP 的独立工具。

您可以从这里获取它：Outwit

用法：

• 将剪贴板保存到文件：winclip -p file.txt

• 将标准输出复制到剪贴板：winclip -c 例如：Sed 's/find/replace/'文件| winclip -c

• 通过管道将剪贴板传输到 sed： winclip -p | sed 's/find/replace/'

• 使用 winclip 输出（剪贴板）作为另一个命令的参数：

  FOR /F "tokens=* usebackq" %%G in ('winclip -p') Do (YOUR_Command %%G ) 请注意，如果剪贴板中有多行，则此命令将一一解析。

您可能还想看看getclip & putclip 工具：CygUtils for Windows 但 winclip 更好我的意见。

Answer 4

这是使用 mshta 的一种方法：

@echo off
:printClip
for /f "usebackq tokens=* delims=" %%i in (
   `mshta "javascript:Code(close(new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(clipboardData.getData('Text'))));"`
) do (
 echo cntent of the clipboard:
 echo %%i
)

直接从控制台访问它的方法相同：

for /f "usebackq tokens=* delims=" %i in (`mshta "javascript:Code(close(new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(clipboardData.getData('Text'))));"`) do @echo %i

Answer 5

在 win 11 中运行的示例批处理文件，我必须阅读本主题中的几个答案才能找到解决方案并获取剪贴板。具体应用是YouTube下载剪贴板中的URL。

@echo off

for /f "eol=; tokens=*" %%I in ('powershell Get-Clipboard') do set CLIPBOARD_TEXT=%%I

youtube-dl -f 18 %CLIPBOARD_TEXT%

pause

Answer 6

在 Vista 或更高版本中，它是内置的。只需将输出通过管道传输到“clip”程序即可。
这是我写的一篇文章：
http://www.clipboardextender.com /general-clipboard-use/command-window-output-to-clipboard-in-vista
这篇文章还包含一个名为 Dos2Clip 的免费实用程序（我认为是我编写的）的链接，该实用程序可以在 XP 上使用。

编辑：我发现我已经把问题搞反了，我的解决方案输出到剪贴板，没有读取它。对不起！

更新：与 Dos2Clip 一起的是 Clip2Dos（在同一 zip 中），它将把剪贴板文本发送到标准输出。所以这应该对你有用。 Pascal 源代码包含在 zip 中。

Answer 7

要从批处理脚本中检索剪贴板内容：不存在“纯粹的”批处理解决方案。

如果您想要嵌入 100% 批处理解决方案，则需要从批处理中生成其他语言文件。

这是一个简短的和批量嵌入解决方案，生成 VB 文件（通常安装在大多数 Windows 上）

Answer 8

由于所有答案都令人困惑，这里我的代码没有延迟或额外的窗口来打开从剪贴板复制的流链接：

@ECHO OFF
//Name of TEMP TXT Files
SET TXTNAME=CLIP.TXT
//VBA SCRIPT
:: VBS SCRIPT
ECHO.Set Shell = CreateObject("WScript.Shell")>_TEMP.VBS
ECHO.Set HTML = CreateObject("htmlfile")>>_TEMP.VBS
ECHO.TXTPATH = "%TXTNAME%">>_TEMP.VBS
ECHO.Set FileSystem = CreateObject("Scripting.FileSystemObject")>>_TEMP.VBS 
ECHO.Set File = FileSystem.OpenTextFile(TXTPATH, 2, true)>>_TEMP.VBS
ECHO.File.WriteLine HTML.ParentWindow.ClipboardData.GetData("text")>>_TEMP.VBS
ECHO.File.Close>>_TEMP.VBS
cscript//nologo _TEMP.VBS

:: VBS CLEAN UP
DEL _TEMP.VBS

SET /p streamURL=<%TXTNAME%

DEL %TXTNAME%

:: 1) The location of Player
SET mvpEXE="D:\Tools\Programs\MVP\mpv.com"

:: Open stream to video player
%mvpEXE% %streamURL%


@ECHO ON

Answer 9

正如其他人所说，将管道输出到剪贴板是由clip 提供的。要从剪贴板读取输入，请使用此捆绑包中的 pclip 工具。那里还有很多其他好东西。

例如，您正在学习在线教程，并且想要使用剪贴板的内容创建一个文件...

c:\>pclip > MyNewFile.txt

或者您想要执行复制的命令...

c:\>pclip | cmd

Answer 10

多行

问题已解决，但失望依然存在。

我被迫将一个命令分成两个。

首先，他们很好地理解文本和服务字符，但不理解退格键。

第二个理解退格键，但不理解许多服务字符。

有人能团结他们吗？

Notepad ++ 在应打开的位置被注释掉，因为有时窗口无法输入字符，因此您需要确保它处于活动状态。

当然，最好使用笔记本进程的PID来输入字符，但是......

来自wmic的请求打开了很长一段时间，所以在bat文件关闭之前不要关闭记事本窗口。

    @echo off
    set "like=Microsoft Visual C++"
    set "flag=0"
    start /max C:\"Program Files\Notepad++\notepad++.exe" -nosession -multiInst
    ( set LF=^
    %= NEWLINE =%
    )
    set ^"NL=^^^%LF%%LF%^%LF%%LF%^^"
    ::------------------
    setlocal enabledelayedexpansion
    for /f "usebackq delims=" %%i in ( `wmic /node:"papa" product where "Name like '%%%like%%%'" get * ^| findstr /r /v "^$"`) do (
        for /f tokens^=1^ delims^=^" %%a in ("%%i") do set str=%%a
        if "!flag!"=="0" ( 
            ::start /max C:\"Program Files\Notepad++\notepad++.exe" -nosession -multiInst& set "flag=1" 
            for /f "delims=" %%i in ('mshta "javascript:new         ActiveXObject('WScript.Shell').SendKeys('{BS}{BS}{BS}{BS}');close(new         ActiveXObject('Scripting.FileSystemObject'));"') do set   
            set flag=1
        )
        @set /P "_=%%str%%"<NUL|clip
        for /f "delims=" %%i in ('mshta "javascript:new         ActiveXObject('WScript.Shell').SendKeys('^v');close(new         ActiveXObject('Scripting.FileSystemObject'));"') do set
        (echo %%NL%%)|clip  
        for /f "delims=" %%i in ('mshta "javascript:new         ActiveXObject('WScript.Shell').SendKeys('^v');close(new         ActiveXObject('Scripting.FileSystemObject'));"') do set 
    )
    setlocal disabledelayedexpansion

Answer 11

还有另一种解决方案，这是一种解决方法，但很简单。您可以从用户获取输入字符串，而不是直接获取剪贴板 - 用户可以从 cmd 窗口粘贴文本（右键单击 cmd 窗口）然后选择粘贴或使用热键：Alt+Space 然后按 E 然后按 P，简而言之，Alt+Space -> E+P）

bat 脚本为：

@ECHO OFF
set /p Input=Enter some text: 
echo %Input%

步骤 0：复制您需要的文本。

步骤1：运行上面的bat脚本。

步骤2：Alt+空格-> E+P，您应该看到剪贴板中的文本已显示，然后按 Enter。完毕！

Answer 12

这可能不是确切的答案，但它会对您的任务有所帮助。

原帖：
访问https://groups.google.com/d/msg/ alt.msdos.batch/0n8icUar5AM/60uEZFn9IfAJ
提问者罗杰·亨特
回答者 William Allen

---

更简洁的步骤：

步骤 1）使用任何文本编辑器在桌面上创建一个名为 Copy.bat 的“bat”文件，然后复制并粘贴以下代码并保存。

  @ECHO OFF
  SET FN=%1
  IF ()==(%1) SET FN=H:\CLIP.TXT

  :: Open a blank new file
  REM New file>%FN%

  ECHO.set sh=WScript.CreateObject("WScript.Shell")>_TEMP.VBS
  ECHO.sh.Run("Notepad.exe %FN%")>>_TEMP.VBS
  ECHO.WScript.Sleep(200)>>_TEMP.VBS
  ECHO.sh.SendKeys("^+{end}^{v}%%{F4}{enter}{enter}")>>_TEMP.VBS
  cscript//nologo _TEMP.VBS

  ECHO. The clipboard contents are:
  TYPE %FN%

  :: Clean up
  DEL _TEMP.VBS
  SET FN=

步骤 2) 创建一个空白文本文件（在我的例子中为 H 驱动器中的“CLIP.txt”）或任何位置，确保更新“FN=H:\CLIP”下 Copy.bat 文件中的路径.txt' 与您的目标文件路径。

就是这样。

因此，基本上，当您从任何地方复制任何文本并从桌面运行 Copy.bat 文件时，它会使用其中的剪贴板内容更新 CLIP.txt 文件并保存它。

用途：

我用它从远程连接的计算机传输数据，其中不同连接之间禁用复制/粘贴；其中共享驱动器 (H:) 对于所有连接都是通用的。

Answer 13

要设置剪贴板的内容，如 Chris Thornton、klaatu 和一堆其他人说过，使用%windir%\system32\clip.exe。

---

更新 2：

对于快速的单行代码，您可以执行以下操作：

powershell -sta "add-type -as System.Windows.Forms; [windows.forms.clipboard]::GetText()"

如果需要，使用 for /F 循环捕获和解析。这不会像下面的 JScript 解决方案执行得那么快，但它确实具有简单的优点。

---

更新的解决方案：

感谢 Jonathan 指出神秘的 htmlfile COM 对象用于检索剪贴板。可以调用批处理 + JScript 混合来检索剪贴板的内容。事实上，它只需要一行 JScript 和一行 cscript 即可触发它，并且比之前提供的 PowerShell / .NET 解决方案要快得多。

@if (@CodeSection == @Batch) @then

@echo off
setlocal

set "getclip=cscript /nologo /e:JScript "%~f0""

rem // If you want to process the contents of the clipboard line-by-line, use
rem // something like this to preserve blank lines:
for /f "delims=" %%I in ('%getclip% ^| findstr /n "^"') do (
    setlocal enabledelayedexpansion
    set "line=%%I" & set "line=!line:*:=!"
    echo(!line!
    endlocal
)

rem // If all you need is to output the clipboard text to the console without
rem // any processing, then remove the "for /f" loop above and uncomment the
rem // following line:
:: %getclip%

goto :EOF

@end // begin JScript hybrid chimera
WSH.Echo(WSH.CreateObject('htmlfile').parentWindow.clipboardData.getData('text'));

---

旧的解决方案：

可以使用 .NET 从 Windows 控制台检索剪贴板文本，而无需任何第三方应用程序。如果您安装了 powershell，您可以通过创建一个虚构的文本框并将其粘贴到其中来检索剪贴板内容。 （来源）

Add-Type -AssemblyName System.Windows.Forms
$tb = New-Object System.Windows.Forms.TextBox
$tb.Multiline = $true
$tb.Paste()
$tb.Text

如果您不这样做如果没有 powershell，您仍然可以编译一个简单的 .NET 应用程序以将剪贴板文本转储到控制台。这是一个 C# 示例。 （灵感）

using System;
using System.Threading;
using System.Windows.Forms;
class dummy {
    [STAThread]
    public static void Main() {
        if (Clipboard.ContainsText()) Console.Write(Clipboard.GetText());
    }
}

这是一个结合了这两种方法的批处理脚本。如果 %PATH% 中存在 powershell，请使用它。否则，找到 C# 编译器/链接器并构建临时 .NET 应用程序。正如您在批处理脚本注释中看到的，您可以使用 for /f 循环捕获剪贴板内容，或者简单地将它们转储到控制台。

:: clipboard.bat
:: retrieves contents of clipboard

@echo off
setlocal enabledelayedexpansion

:: Does powershell.exe exist within %PATH%?
for %%I in (powershell.exe) do if "%%~$PATH:I" neq "" (
    set getclip=powershell "Add-Type -AssemblyName System.Windows.Forms;$tb=New-Object System.Windows.Forms.TextBox;$tb.Multiline=$true;$tb.Paste();$tb.Text"
) else (
rem :: If not, compose and link C# application to retrieve clipboard text
    set getclip=%temp%\getclip.exe
    >"%temp%\c.cs" echo using System;using System.Threading;using System.Windows.Forms;class dummy{[STAThread]
    >>"%temp%\c.cs" echo public static void Main^(^){if^(Clipboard.ContainsText^(^)^) Console.Write^(Clipboard.GetText^(^)^);}}
    for /f "delims=" %%I in ('dir /b /s "%windir%\microsoft.net\*csc.exe"') do (
        if not exist "!getclip!" "%%I" /nologo /out:"!getclip!" "%temp%\c.cs" 2>NUL
    )
    del "%temp%\c.cs"
    if not exist "!getclip!" (
        echo Error: Please install .NET 2.0 or newer, or install PowerShell.
        goto :EOF
    )
)

:: If you want to process the contents of the clipboard line-by-line, use
:: something like this to preserve blank lines:
for /f "delims=" %%I in ('%getclip% ^| findstr /n "^"') do (
    set "line=%%I" & set "line=!line:*:=!"
    echo(!line!
)

:: If all you need is to output the clipboard text to the console without
:: any processing, then remove the above "for /f" loop and uncomment the
:: following line:

:: %getclip%

:: Clean up the mess
del "%temp%\getclip.exe" 2>NUL
goto :EOF