如何在 Perl 或批处理中合并两个 Excel (xls) 文件？

Question

我有两个文件，例如 a.xls 和 b.xls。第一张包含 2 张，第二张包含 3 张。有人可以告诉我是否可以使用 Perl 或批处理脚本合并它们吗？

我想要在一个 XLS 文件中输出包含 5 页的内容。

Answer 1

对于 Perl 解决方案，请使用 Spreadsheet::ParseExcel 读取文件并 Spreadsheet::WriteExcel 保存您的 输出。这两个模块都有详细的文档记录，并附带大量示例代码（例如 WriteExcel)

Answer 2

如果您在 Windows 上运行，已安装 Excel 并且可以使用 Win32::OLE (例如，脚本不会被 Web 服务器调用等），以下应该可以工作：

#!/usr/bin/perl

use warnings;
use strict;

use FindBin qw($Bin);
use File::Spec::Functions qw( catfile );

use Win32::OLE qw(in);
use Win32::OLE::Const 'Microsoft Excel';
$Win32::OLE::Warn = 3;

my $excel = get_excel();
$excel->{Visible} = 1; # for illustration only

my @src = map $excel->Workbooks->Open($_),
          map catfile($Bin, $_),
          qw(one.xls two.xls)
          ;

my $target = $excel->Workbooks->Add(xlWBATWorksheet);
my $before = $target->Worksheets->Item(1);

for my $book ( @src ) {
    my $sheets = $book->Worksheets;
    my $it = Win32::OLE::Enum->new($sheets);

    while (defined(my $sheet = $it->Next)) {
        $sheet->Copy($before);
    }
}

$before->Delete;

$_->Close for @src;
$target->SaveAs(catfile($Bin, 'test.xls'));
$target->Close;

sub get_excel {
    my $excel = Win32::OLE->GetActiveObject('Excel.Application');
    unless(defined $excel) {
        $excel = Win32::OLE->new('Excel.Application', sub { $_[0]->Quit })
            or die "Oops, cannot start Excel: ",
                   Win32::OLE->LastError, "\n";
    }
    return $excel;
}

Answer 3

您可以使用 Alacon - Alasql 数据库的命令行实用程序来完成此操作。

它与 Node.js 配合使用，因此您需要安装 Node.js，然后安装 Alasql 包：

要从 Excel 文件中获取数据，您可以使用以下命令：

> node alacon "SELECT * INTO XLSX("main.xls",{headers:true}) 
               FROM XLSX('data1.xlsx', {headers:true}) 
               UNION ALL SELECT * FROM XLSX('data2.xlsx', {headers:true})
               UNION ALL SELECT * FROM XLSX('data3.xlsx', {headers:true})
               UNION ALL SELECT * FROM XLSX('data4.xlsx', {headers:true})
               UNION ALL SELECT * FROM XLSX('data5.xlsx', {headers:true})"

这是很长的一行。在此示例中，所有文件都在“Sheet1”工作表中具有数据。