如何使用新的 movieClip 作为类或在不引用其类的情况下复制它？

Question

我正在用 2 个相同的 BG movieClip（B1 和 B2）制作循环背景。这两个是同一个班级的“新”人。

var B1:MovieClip = new BG();
var B2:MovieClip = new BG();

但是因为这个BG类图片是从网上加载的，而且图片比较大。当我使用 ProgressEvent 解决其加载问题时。图片确实加载了2次。无论如何，我是否可以基于 B1 创建 B2 而无需再次使用 new BG() ？因为它肯定会创建一个新的BG，里面有Loader代码。 谢谢您的帮助^^

对于BG类代码：

var URLvar:URLRequest;
var BGLoader : Loader = new Loader( );
URLvar = new URLRequest( "somewherelink.jpg" );
BGLoader.load(URLvar);
this.addChild(BGLoader);

有什么方法可以设置如果B1完全加载，我将其复制到B2中吗？或任何其他方式来实现相同的目标？

import flash.display.*;
import flash.utils.*;
var obj:Class = getDefinitionByName(“bluebox”) as Class;
addChild(MovieClip(new obj()));

我在动态创建类中找到了这个，但我不知道如何使用T_T，你能给我解释一下吗？我可以在这种情况下使用它吗？ 谢谢您的宝贵时间^^

Answer 1

对于这个答案，我假设您总是希望拥有相同的图像两次，而不是两个不同的图像。您遇到的问题是您的 BG 类完全在内部完成加载和附加。我的首选方法是加载一次，然后创建加载内容的实例。

//first lets create a single loader
var bgLoader:Loader = new Loader();
bgLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeHandler);
//and load the content
var urlVar:URLRequest = new URLRequest("somewherelink.jpg");
bgLoader.load(urlVar);
//notice that we don't add the loader to the stage

function completeHandler(evt:Event):void
{
    //remove the loader listener for memory conservation purposes
    evt.target.removeEventListener(Event.COMPLETE,completeHandler);
    //reference the content
    var content:DisplayObject = evt.target.content;
    //so now create a bitmapData object
    var bmd:BitmapData = new BitmapData(content.width,content.height,false); // use (content.width,content.height,true,0) if loading image with transparancy
    //and draw the loaded image into to bitmap data
    bmd.draw(content);
    //now you can create as many Bitmap objects from this data as you like
    var bg1:Bitmap = new Bitmap(bmd);
    var bg2:Bitmap = new Bitmap(bmd);
    //offset bg2 so both are visible
    bg2.x = 100;
    addChild(bg1);
    addChild(bg2);
}

对于第二个问题... getDefinitionByName 返回一个代表命名类的对象，而不是它的实例。因此，在您的示例中，它正在获取“bluebox”类的定义，该类位于应用程序源的根目录中（而不是在文件夹中）。

获得该类对象后，您可以使用 new 关键字创建它的实例。就我而言，最大的缺点是您不导入该类，因此在您的示例中 obj 被转换为 MovieClip。这使得代码编辑器的功能（例如代码完成和错误突出显示）无法正常工作，因为“bluebox”的属性和方法没有公开。

我通常只使用它来创建将在其他地方定义其类的对象，例如在运行时加载的 XML 文件中。

Answer 2

如果两个浏览器的 URLRequest URL 相同，则浏览器将在第二次提供缓存版本。该请求向浏览器发出两次，但仅向服务器发出一次。您可以使用 httpfox、charles 或 fiddler 等 http 嗅探器来验证请求。