搜索和替换的替代方法，用于告诉应用程序将内容放在 Word 文档中的位置

Question

我编写了一个还可以进行文档管理的应用程序。我在 Delphi 中执行此操作，但问题也可能适用于 C#。我刚刚收到一个非常有用的回复 我问的这个问题使得“搜索和替换”工作变得更容易。

我的一个要求是每次用户打开文档时根据数据库数据自动在文档中插入一些数据。到目前为止（这包括上面提到的问题的主题）我只做了一次：“从模板创建文档”=替换一次，工作就完成了。搜索与Replace 非常适合这个，对于用户来说也很容易。

现在的要求是每次打开文档时连续执行此操作，因此同一文档应包含“占位符”和“真实数据”（一旦我打开它）。

一个简单的例子是这样的：

在Word文档的标题中，用户想要为3个字段插入一种占位符：company_logo（图像）、修订编号（整数）、修订日期（日期时间）。

目前我所知道的唯一技术是：

1）搜索和搜索。替换 - 我已经用它来做其他事情

2）占位符 - 我从未使用过它，但我想它是可行的（这里有几个帖子，例如 这个）

带有搜索和；替换我会这样做：

a）我要求用户准备一个word文档，在其中他在大括号中写入数据库字段，如{NAME} {SURNAME}（注意：这只是大括号，而不是MSWord占位符）。 b) 当用户“签出”文档进行编辑时，他将继续阅读 {NAME} 和 SURNAME} c）当用户“以只读模式打开”时，我执行搜索和替换技巧

这肯定会与搜索和替换一起工作。替换对于用户来说是一种非常简单易懂的技术。

我想占位符也同样适用（可以使用 CTRL + F9 在 Word 中插入的占位符）。

但如何处理图像呢？

可以使用哪些替代方法在运行时在 Word 文档中插入内容？

Answer 1

在对您的问题的评论中如何避免 255 限制 ( 如何使用 OLE 绕过 MSWord 搜索和替换中的 255 个字符限制），我提到文档变量可能是向单词添加运行时内容的更简单方法 文档。

我认为它们也是您想要在这里做的事情的答案。然而，它们对于最终用户来说并不完全直观，因此最好保留占位符。不幸的是，这并不完全可能，因为您最终会得到一个包含占位符和文档变量字段的文档。这最终会导致价值观被重复。

尽管如此，我们仍然可以为最终用户保留占位符。当然是为了他们对“模板”的初步编辑。甚至可以向已“转换为使用变量”的现有 Word 文档添加新的占位符。

下面的代码展示了如何进行。我没有包含打开和关闭 Word 和/或文档的“标准”Word 自动化部分。我从您使用模板打开新文档并且现在准备开始替换值的位置开始。解决方案在于三种方法：

HideExistingFieldCodes(Doc);
AddFieldDocVarsToPlaceHolders(Doc);
SetValuesForDocVars(Doc);

需要 HideExistingFieldCodes，因为我们也使用占位符作为文档变量的名称，如果字段显示其代码而不是值，我们最终会用新的名称替换文档变量名称。 document 变量，这可能会让 Word 大声呕吐。

procedure HideExistingFieldCodes(const Doc: WordDocument);
var
  i: Integer;
begin
  for i := 1 to Doc.Fields.Count do begin

    // Only interested in document variables.
    if Doc.Fields.Item( i ).Type_ = wdFieldDocVariable then begin
      Doc.Fields.Item( i ).ShowCodes := False;
    end;

  end;
  // Do not call Doc.Fields.Update, because that will show all fields' code again.
  // Doc.Fields.Update;
end;

一旦隐藏任何现有字段的代码，我们就可以扫描文档中的占位符，并将每个占位符替换为文档变量字段。

procedure AddFieldDocVarsToPlaceHolders(const Doc: WordDocument);
var
  i: Integer;
  OleTrue: OleVariant;
  OleFalse: OleVariant;
  OleEmpty: OleVariant;
  FindText: OleVariant;
  Replace: OleVariant;
  FieldType: OleVariant;
  NewField: Field;
begin
  OleTrue := True;
  OleFalse := False;
  OleEmpty := '';
  Replace := wdReplaceOne;
  FieldType := wdFieldDocVariable;

  // Skip the titles.
  for i := 1 to PlaceHoldersEdit.Strings.Count do begin
    FindText := Format('%s', [PlaceHoldersEdit.Keys[i]]);

    FWord.Selection.SetRange(0, 0); // Back to the beginning of the document.
    while FWord.Selection.Find.ExecuteOld({FindText}FindText, {MatchCase}EmptyParam, {MatchWholeWord}EmptyParam,
      {MatchWildcards}EmptyParam, {MatchSoundsLike}EmptyParam, {MatchAllWordForms}EmptyParam, {Forward}OleTrue,
      {Wrap}OleFalse, {Format}EmptyParam, {ReplaceWith}OleEmpty, {Replace}Replace )
    do begin
      NewField := FWord.Selection.Fields.Add({Range}FWord.Selection.Range, {Type_}FieldType, {Text}FindText, {PreserveFormatting}OleTrue);
      NewField.ShowCodes := False; // Make sure document variable name is hidden
      // Select this field and set selection to the end of its definition, making
      // doubly sure we won't find its name and replace it again.
      NewField.Select;  
      FWord.Selection.SetRange(FWord.Selection.End_, FWord.Selection.End_);
    end;

  end;
end;

我使用 TValueListEditor（名为 PlaceHoldersEdit）来保存占位符名称和值。它的第一行包含此控件中列的标题，因此会被跳过。之后，需要循环遍历所有占位符以及循环遍历其在 Word 文档中出现的位置。

最后我们可以开始添加实际的文档变量，它将保存文档变量字段的值。 （哦，我多么喜欢所有这些听起来相似的名称。）

procedure SetValuesForDocVars(const Doc: WordDocument);

  function ExtractVarNameFromField(VarCode: WideString): OleVariant;
  var
    s: string;
    i: Integer;
  begin
  // Code Text:  DOCVARIABLE Naam \* MERGEFORMAT
  // Code Text:  DOCVARIABLE Naam
    s := Trim(VarCode);
    Delete(s, 1, Length('DOCVARIABLE '));
    i := Pos('\* MERGEFORMAT', s);
    if i > 0 then begin
      Delete(s, i, Length('\* MERGEFORMAT'));
    end;
    Result := Trim(s); // Somebody might have added extra spaces by hand...
  end;

  function PlaceHolderValue(const aKey: string): string;
  begin
    Result := PlaceHoldersEdit.Values[aKey];
  end;

  function ReplaceCrLfWithCr(const aSource: string): string;
  begin
    Result := StringReplace(aSource, #13#10, #13, [rfReplaceAll]);
  end;

var
  i: Integer;
  OleVarName: OleVariant;
  OleVarValue: OleVariant;
  DocVar: Variable;
begin
  for i := 1 to Doc.Fields.Count do begin

    // Only interested in document variable fields.
    if Doc.Fields.Item( i ).Type_ = wdFieldDocVariable then begin

      OleVarName := ExtractVarNameFromField( Doc.Fields.Item( i ).Code.Text );
      OleVarValue := ReplaceCrLfWithCr(PlaceHolderValue(OleVarName));

      // Word removes fields/variables with an empty string as their value, 
      // adding a space prevents that.
      if OleVarValue = '' then begin
        OleVarValue := ' ';
      end;

      DocVar := Doc.Variables.Item(OleVarName);
      if VarIsNull(DocVar) then begin
        Doc.Variables.Add( OleVarName, OleVarValue );
      end else begin
        DocVar.Value := OleVarValue;
      end;

    end;

  end;
  Doc.Fields.Update;
  Doc.Fields.ToggleShowCodes;
end;

在这个方法中，我循环遍历所有文档变量字段并从每个字段的代码中提取变量名称。然后我尝试查找该名称的文档变量。如果它还不存在，我会添加它。如果它确实存在，我会更改它的值。如果性能是一个问题并且变量名称在许多字段中使用，则可以对此进行一些优化以仅更改该值一次。

哦，我已经使用“已保存”文档进行了测试，但我还没有向已经通过将占位符转换为文档变量字段的文档添加新的占位符。所以，你可能仍然需要把事情弄平一些。

顺便说一句：在 Word 中，Shft-F9 可在显示其代码和显示其值之间切换字段。您将不得不使用“选项”对话框（Word2003，不知道在以后的版本中最终在哪里）来一次性显示/隐藏它们。该选项是“显示”或“查看”选项卡（翻译自荷兰语）上“显示”或“显示”下的“字段代码”。