释放 OleVariant 后面的接口的正确方法是什么？

Question

我正在尝试找到一种安全/确定性的方法来释放封装在 OleVariant 中的接口。

AFAICS Delphi 在过程结束时释放接口引用，但就我而言，我必须更早执行此操作，因为我必须关闭 COM。

procedure Test;
var
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    LLibrary := Null;
    try
      LLibrary := CreateOleObject(LibraryName);
    finally
      LLibrary := Unassigned; // <-- I would like to release the interface here
    end;
  finally
    CoUninitialize; // <-- Shutdown of COM
  end;
end; // <-- The compiler releases the interface here

我想将 OleVariant 放入一个额外的类实例中，在调用 CoUninitialize 之前可以释放该实例。

procedure Test;
var
  Container: TLibraryContainer; // Holds the OleVariant
begin
  CoInitialize(nil);
  try
    Container := TLibraryContainer.Create;
    try
      {...}
    finally
      Container.Free;
    end;
  finally
    CoUninitialize;
  end;
end;

这个解决方案安全吗还是有我忽略的更好的解决方案？

Answer 1

编译器显然使用隐式本地接口变量作为 CreateOleObject 的返回值。然后在例程结束时释放它，这对你来说太晚了。

有几种方法可以解决这个问题。首先，您可以明确由 CreateOleObject 返回的 IDispatch 接口引用。这使您可以控制其生命周期。

procedure Test;
var
  intf: IDispatch;
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    intf := CreateOleObject(LibraryName);
    try
      LLibrary := intf;
    finally
      VarClear(LLibrary);
      intf := nil;
    end;
  finally
    CoUninitialize;
  end;
end;

另一种方法是将调用 CreateOleObject 的代码移至具有自己作用域的单独例程中。

procedure DoWork;
var
  LLibrary: OleVariant;
begin
  LLibrary := CreateOleObject(LibraryName);
  //do stuff with LLibrary
end;

procedure Test;
begin
  CoInitialize(nil);
  try
    DoWork;
  finally
    CoUninitialize;
  end;
end;

由于隐式本地引用位于 DoWork 范围内，因此它会在 DoWork 结束时释放，因此在运行 CoUninitialize 之前释放。

我的建议是使用第二个选项，它更干净，并强制编译器代表您完成工作。