F# 中的分割序列

Question

我应该通过元素的属性将 seq 拆分为 seq> 。如果此属性等于给定值，则必须在该点“拆分”。我怎样才能在FSharp中做到这一点？

最好将一个“函数”传递给它，如果必须在该项目上拆分或不拆分，则返回一个布尔值。

样本： 输入序列：seq: {1,2,3,4,1,5,6,7,1,9} 当它等于 1 时，应该在每个项目上进行拆分，因此结果应该是：

seq
{
seq{1,2,3,4}
seq{1,5,6,7}
seq{1,9}
}

Answer 1

您真正要做的就是分组——每次遇到值时创建一个新组。

let splitBy f input =
  let i = ref 0
  input 
  |> Seq.map  (fun x -> 
    if f x then incr i
    !i, x)
  |> Seq.groupBy fst
  |> Seq.map (fun (_, b) -> Seq.map snd b)

例子

let items = seq [1;2;3;4;1;5;6;7;1;9]
items |> splitBy ((=) 1)

再次，更短，斯蒂芬的很好的改进：

let splitBy f input =
  let i = ref 0
  input
  |> Seq.groupBy (fun x ->
    if f x then incr i
    !i)
  |> Seq.map snd

Answer 2

不幸的是，编写使用序列（seq<'T> 类型）的函数有点困难。它们不能很好地处理功能概念，例如列表上的模式匹配。相反，您必须使用 GetEnumerator 方法和生成的 IEnumerator<'T> 类型。这通常会使代码变得非常命令式。在这种情况下，我会写以下内容：

let splitUsing special (input:seq<_>) = seq { 
  use en = input.GetEnumerator()
  let finished = ref false
  let start = ref true
  let rec taking () = seq {
    if not (en.MoveNext()) then finished := true
    elif en.Current = special then start := true
    else 
      yield en.Current
      yield! taking() }

  yield taking()
  while not (!finished) do
    yield Seq.concat [ Seq.singleton special; taking()] }

我不建议使用函数式风格（例如使用 Seq.skip 和 Seq.head），因为这相当效率低下 - 它创建一个序列链，从其他序列中获取值并返回它（因此通常有 O(N^2) 复杂度）。

或者，您可以使用计算生成器来编写此代码以与 IEnumerator<'T> 一起使用，但这不是标准的。如果您想使用它，可以在这里找到它。

Answer 3

以下是一个不纯粹的实现，但会惰性地产生不可变序列：

let unflatten f s = seq {
    let buffer = ResizeArray()

    let flush() = seq { 
        if buffer.Count > 0 then 
            yield Seq.readonly (buffer.ToArray())
            buffer.Clear() }

    for item in s do
        if f item then yield! flush()
        buffer.Add(item)

    yield! flush() }

f 是用于测试元素是否应该是分割点的函数：

[1;2;3;4;1;5;6;7;1;9] |> unflatten (fun item -> item = 1)

Answer 4

可能不是最有效的解决方案，但这可行：

let takeAndSkipWhile f s = Seq.takeWhile f s, Seq.skipWhile f s

let takeAndSkipUntil f = takeAndSkipWhile (f >> not)

let rec splitOn f s =
    if Seq.isEmpty s then
        Seq.empty
    else
        let pre, post =
            if f (Seq.head s) then
                takeAndSkipUntil f (Seq.skip 1 s)
                |> fun (a, b) ->
                    Seq.append [Seq.head s] a, b
            else
                takeAndSkipUntil f s
        if Seq.isEmpty pre then
            Seq.singleton post
        else
            Seq.append [pre] (splitOn f post)

splitOn ((=) 1) [1;2;3;4;1;5;6;7;1;9] // int list is compatible with seq<int>

splitOn 的类型是 ('a -> bool) -> seq<'a> ->序列>。我还没有在很多输入上测试过它，但它似乎有效。

Answer 5

如果您正在寻找实际上像 split 作为字符串拆分一样工作的东西（即不包含谓词返回 true 的项目），下面是我想到的..尝试尽可能实用:)

let fromEnum (input : 'a IEnumerator) = 
    seq {
        while input.MoveNext() do
            yield input.Current
    }

let getMore (input : 'a IEnumerator) = 
    if input.MoveNext() = false then None
    else Some ((input |> fromEnum) |> Seq.append [input.Current])

let splitBy (f : 'a -> bool) (input : 'a seq)  = 
    use s = input.GetEnumerator()
    let rec loop (acc : 'a seq seq) = 
        match s |> getMore with 
        | None -> acc
        | Some x ->[x |> Seq.takeWhile (f >> not) |> Seq.toList |> List.toSeq]
                   |> Seq.append acc
                   |> loop
    loop Seq.empty |> Seq.filter (Seq.isEmpty >> not)

seq [1;2;3;4;1;5;6;7;1;9;5;5;1]
|> splitBy ( (=) 1) |> printfn "%A"