为什么版本->解析在没有前面打印的情况下无法工作？

Question

我不得不承认，这个让我着迷。

考虑这段代码：

use version;
use Data::Dumper;
my $codeLevel = q{6.1.0.7 (build 25.3.1103030000)};
print STDERR qq{$codeLevel\n};
my $vrmf;
if($codeLevel =~ /^\s*([0-9.]*) \(build.*\)/) { 
    print STDERR "$1\n";
    $vrmf = version->parse($1);
}

print STDERR Dumper($vrmf);

正如预期的那样，输出是：

6.1.0.7 (build 25.3.1103030000)
6.1.0.7
$VAR1 = bless( {
                 'original' => '6.1.0.7',
                 'qv' => 1,
                 'version' => [
                                6,
                                1,
                                0,
                                7
                              ]
               }, 'version' );

但是，删除第二个打印：

use version;
use Data::Dumper;
my $codeLevel = q{6.1.0.7 (build 25.3.1103030000)};
print STDERR qq{$codeLevel\n};
my $vrmf;
if($codeLevel =~ /^\s*([0-9.]*) \(build.*\)/) {
    $vrmf = version->parse($1);
}
print STDERR Dumper($vrmf);

输出变为：

6.1.0.7 (build 25.3.1103030000)
$VAR1 = bless( {
                 'original' => '0',
                 'version' => [
                                0
                              ]
               }, 'version' );

我找不到任何说明 print 可以影响传递给它的变量的文档，或者它影响正则表达式匹配变量。

有人可以向我解释一下这里发生了什么吗？

Answer 1

Perl 中的标量值可以同时是数字和字符串。。 SV 对象（SV = 标量值）具有用于整数、浮点和字符串值的槽以及标识这些值中哪些值在任何时间点有效的标志。当您使用值作为字符串时，perl 会计算该字符串值并设置一个标志，将其标识为有效。 （其他操作，例如加 1 会使字符串值无效。）当您打印某些内容时，您（毫不奇怪）将其用作字符串。您可以使用 Devel::Peek 来查看这一点。

use Devel::Peek;

my $s = '6.1.0.7 (build 25.3.1103030000)';
if ($s =~ /^\s*([0-9.]*) \(build.*\)/) { 
    Dump($1);
    printf STDERR "\$1 = $1\n";
    Dump($1);
}

结果是

SV = PVMG(0x1434ca4) at 0x144d83c
  REFCNT = 1
  FLAGS = (GMG,SMG)
  IV = 0
  NV = 0
  PV = 0
  MAGIC = 0x146c324
    MG_VIRTUAL = &PL_vtbl_sv
    MG_TYPE = PERL_MAGIC_sv(\0)
    MG_OBJ = 0x144d82c
    MG_LEN = 1
    MG_PTR = 0x14631c4 "1"
$1 = 6.1.0.7
SV = PVMG(0x1434ca4) at 0x144d83c
  REFCNT = 1
  FLAGS = (GMG,SMG,pPOK)
  IV = 0
  NV = 0
  PV = 0x1487a1c "6.1.0.7"\0
  CUR = 7
  LEN = 8
  MAGIC = 0x146c324
    MG_VIRTUAL = &PL_vtbl_sv
    MG_TYPE = PERL_MAGIC_sv(\0)
    MG_OBJ = 0x144d82c
    MG_LEN = 1
    MG_PTR = 0x14631c4 "1"

请注意，在第二个转储输出中，PV 槽（字符串值）已被填充，并且 pPOK 标志已添加到 FLAGS 下。

所以，是的，print 具有某种副作用，尽管在正常情况下您永远不会注意到。 version->parse() 似乎需要一个字符串参数，但不会触发字符串语义。鉴于 version 更喜欢使用 XS 实现，这可能是那里的错误，而不是 Perl 中的错误。请注意，复制捕获数据会导致问题消失：

use Data::Dump qw'pp';

my $s = '6.1.0.7 (build 25.3.1103030000)';
if ($s =~ /^\s*([0-9.]*) \(build.*\)/) { 
    my $x = $1;
    pp(version->parse($x));
}

结果：

bless({ original => "6.1.0.7", qv => 1, version => [6, 1, 0, 7] }, "version")

Answer 2

看起来像是 version::parse 中的一个错误，它没有正确触发传入参数的 get magic 。

查看代码可以发现 CPAN 和核心“版本”中存在同样的问题；它在处理 get magic 之前很久就检查 SvOK 。不幸的是，这将涉及模块代码和 Perl 核心的修复。

Answer 3

这在 MacOS X 10.6.8 上使用 Perl 5.14.1 进行重现，使用“版本”0.91 的 XS 实现（即版本 0.91）...

但是，这是 version::vxs （XS 实现），而不是 version::vpp （纯 Perl）实现。

use version::vxs;
use Data::Dumper;
my $codeLevel = q{6.1.0.7 (build 25.3.1103030000)};
print STDERR qq{$codeLevel\n};
my $vrmf;
if($codeLevel =~ /^\s*([0-9.]*) \(build.*\)/) { 
    $vrmf = version::vxs->parse($1);
}

print STDERR Dumper($vrmf);

正如你所展示的那样，这失败了。当我编译纯 Perl 版本（perl Makefile.PL --perl_only，如 README 文件中所述）并对其进行测试时，它工作正常：

$ perl -Iblib/lib x4.pl
6.1.0.7 (build 25.3.1103030000)
$VAR1 = bless( {
                 'original' => '6.1.0.7',
                 'qv' => 1,
                 'version' => [
                                6,
                                1,
                                0,
                                7
                              ]
               }, 'version::vpp' );

$ cat x4.pl
use version::vpp;
use Data::Dumper;
my $codeLevel = q{6.1.0.7 (build 25.3.1103030000)};
print STDERR qq{$codeLevel\n};
my $vrmf;
if($codeLevel =~ /^\s*([0-9.]*) \(build.*\)/) { 
    $vrmf = version::vpp->parse($1);
}

print STDERR Dumper($vrmf);
$

我认为您可以明智地 在 CPAN RT 上举报（作者是 JPEACOCK）。作为解决方法，手动安装纯 Perl 版本并删除 XS 版本（因为代码首先查找 XS 代码 - 请参阅 version-0.91/lib/version.pm）。如果您真的很勇敢，请考虑找出真正的错误是什么。

Answer 4

不总是这样吗？你提出一个问题，然后找到答案！

此代码：

use version;
use Data::Dumper;
my $codeLevel = q{6.1.0.7 (build 25.3.1103030000)};
print STDERR qq{$codeLevel\n};
my $vrmf;
if($codeLevel =~ /^\s*([0-9.]*) \(build.*\)/) {
    $vrmf = version->parse("$1");
}
print STDERR Dumper($vrmf);

工作正常。请注意，$1 已在此处进行字符串化。

尽管如此，这仍然留下了一个有趣的观察结果：打印变量似乎会永久地将其字符串化！

Answer 5

我不知道版本号背后的特殊魔力，但是通过重载，您几乎可以给字符串化带来任何副作用。

package My::Class;
use overload
    '""' => \&arbitrary_function;

...

$obj = My::Class->new();
print $obj;                 # invokes &arbitrary_function