怎么能不使用“最终”呢？是一个安全问题吗？

Question

来自 O'Reilly 的 Essential ActionScript 3.0 (2007) 第 113 页：

final 方法有助于隐藏类的内部细节。制作一个类或一个 方法final阻止其他程序员扩展类或重写 该方法用于检查类的内部结构。这样的预防 被认为是保护应用程序免遭攻击的方法之一 恶意利用。

这是指使用已编译、闭源包的 API 并“恶意利用”来学习有关类设计的内容的用户吗？这真的是个问题吗？

对于更多上下文，这是使用 final 的两个原因中的第二个。在 2007 年版中，它位于第 113 页的“继承”一章中，副标题为“防止类被扩展和方法被重写”。

在 ActionScript 中使用 Final 属性有两个原因：

• 在某些情况下，最终方法比非最终方法执行得更快。如果你 正在寻求以各种可能的方式提高应用程序的性能，请尝试 使其方法最终确定。但请注意，在未来的 Flash 运行时中，Adobe 期望非最终方法与最终方法一样快地执行。

• final 方法有助于隐藏类的内部细节。制作一个类或一个 方法final阻止其他程序员扩展类或重写 该方法用于检查类的内部结构。这样的预防 被认为是保护应用程序免遭攻击的方法之一 被恶意利用。

Answer 1

在许多语言中，重写方法是从基类中选择加入的。通常，virtual 关键字允许基类作者选择重写的可能性。

然而，在 AS3 中，重写方法的能力是选择退出的。这就是 final 关键字的作用。它允许基类作者说“这个方法可能不会被重写”。

有一些关于封装的老派想法表明 AS3 这样做会带来安全问题。但这主要是在公共 API 的情况下，您希望隐藏内容但公开功能。

但是，在更现代的时代，我们了解到反汇编和反射将允许恶意开发人员做他/她想做的任何事情，所以今天这不再是一个问题。在我看来，依靠 final 来保证安全是一个拐杖，任何关于它的建议都应该被驳回。安全性需要比这更仔细地考虑。 API 需要进行架构设计，以便开发人员可以执行需要执行的操作，但安全关键信息不应包含在公共 API 中。

这并不是说 final 没有用。 final 告诉从您的类派生的开发人员您从未打算让他们重写该函数。它让你说“请只调用这个函数。不要覆盖。”在我看来，它更像是一种接口或通信机制。

Answer 2

Final 关键字不用于这种安全性。它不能替代通常需要的加密解决方案。

在这类讨论中，“安全”通常指的是安全对象模型的概念，也就是说，消费者不能出于类的原始作者的非预期目的而操纵对象模型。

某种程度上，一个构造良好的类将封装其状态，而一个仅具有最终方法的类将不允许使用者覆盖该类的行为并更改状态的封装方式。类可以公开其状态（例如通过公共字段），并且没有final关键字能够保护该状态的完整性。

它更多的是“改变”东西而不是“保护”。最终关键字只是放弃了更改/修改/扩展任何方法的能力。

它不会使您的代码更安全，它比其他任何东西都更能保证线程安全。如果变量被标记为final，则在创建对象时必须为其赋值。创建对象后，不能使该变量引用另一个值。

此行为允许您推断对象的状态，并在多个线程同时访问该对象时做出某些假设。

我不认为进行现场决赛会增加针对恶意攻击的安全性（更有可能针对错误，当然还有线程问题）。安全性的唯一“真实形式”是，如果您有一个最终常量字段，它可能会在编译时内联，因此在运行时更改其值不会产生任何影响。

我在继承的背景下更多地听说过最终和安全性。通过将类设为最终类，您可以防止某人对其进行子类化并触摸或覆盖其受保护的成员，但我再次使用它来避免错误而不是防止威胁。

Answer 3

假设您向公众发布了一些精美的 SWC 库。在这种情况下，您可以防止方法被覆盖。

package
{
    import flash.display.Sprite;

    public class FinalDemo extends Sprite
    {
        public function FinalDemo()
        {
            super();
            var someClientInstance:ExtendedAPIClient = new ExtendedAPIClient();
            // doSomething is overridden by ExtendedAPIClient
            someClientInstance.doSomething();
            // activate cannot be overridden
            someClientInstance.activate("mySecretAPIKey");

            var myApp:MySupaDupaApplication = new MySupaDupaApplication(someClientInstance);

        }
    }
}

/**
 * Assume this class is within a swc that you release to the public.
 * You want every developer to get some APIKey
 * */
internal class MySupaDupaApplication{
    public function MySupaDupaApplication($apiClient:APIClient):void{
        if($apiClient.activated)trace("It's a valid user, do something very cool");
    }
}

/**
 * In order to activate a Client the developer needs to pass a 
 * instance of the API Client to the Application.
 * The application checks the activated getter in order to determine
 * if the api key is valid.
 * */
internal class APIClient{

    private var __activated:Boolean = false;

    public function APIClient(){        
        trace("APIClient Constructor");
    }

    /**
     * override possible
     * */
    public function doSomething():void{
        trace("doing something");
    }

    /**
     * override not possible
     * */
    public final function activate($key:String):void{
        trace("activate "+$key);
        if($key == "mySecretAPIKey"){
            __activated = true;
        }else{
            __activated = false;
            throw new Error("Illegal Key");
        }
    }

    /**
     * override not possible
     * */
    public final function get activated():Boolean{
        return __activated;
    }   
}

/**
 * Class within some developers library using MySupaDupaApplication
 * Changes the Client behaviour
 * Exploit of activation not possible
 * */
internal class ExtendedAPIClient extends APIClient{

    public function ExtendedAPIClient(){
        trace("ExtendedAPIClient Constructor");
        super();
    }

    override public function doSomething():void{
        trace("doing something else");
    }

    /* this will throw a compiler error */
    /*
    override public function activate($key:String):void{
        // do nothing
    }

    override public function get isActivated($key:String):Boolean{
        return true;
    }   
    */  
}