使用 XSLT 计算 XML 中字符串出现的次数

Question

我想使用 XSLT 计算 XML 文档中特定节点中字符串出现的次数。 考虑这个例子

 <mainNode>
<book>
    <price> 100 </price>
    <city> chennai </city>
    <list>
        <language> c java ruby </language>
    </list>
</book>

<book>
    <price> 200 </price>
    <city> banglore </city>
    <list>
        <language> c java </language>
    </list>
</book>

<book>
    <price> 300 </price>
    <city> delhi </city>
    <list>
        <language> java ruby </language>
    </list>
</book>
</mainNode>      

在这里我想计算“java”的出现次数

我想要这样的输出:: java -- 3

如何做到这一点？？？有什么想法吗？？？

Answer 1

使用：

count(/*/*/list/language[contains(., 'java')])

完整的 XSLT 转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
     java -- <xsl:value-of select=
       "count(/*/*/list/language[contains(., 'java')]) "/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<mainNode>
    <book>
        <price> 100 </price>
        <city> chennai </city>
        <list>
            <language> c java ruby </language>
        </list>
    </book>
    <book>
        <price> 200 </price>
        <city> banglore </city>
        <list>
            <language> c java </language>
        </list>
    </book>
    <book>
        <price> 300 </price>
        <city> delhi </city>
        <list>
            <language> java ruby </language>
        </list>
    </book>
</mainNode>

生成所需的正确结果 ：

 java -- 3

更新：

如果我们要计算字符串的所有出现次数 - 而不仅仅是包含该字符串的所有节点 - 以下是如何执行此操作：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes"/>
    <xsl:param name="pWord" select="' java '"/>

    <xsl:template match="/">
        <xsl:variable name="vResult">
            <xsl:apply-templates/>
        </xsl:variable>
        <xsl:value-of select="concat($pWord, '--- ')"/>
        <xsl:value-of select="string-length($vResult)"/>
    </xsl:template>

    <xsl:template match="list/language" name="countWord">
        <xsl:param name="pText" select="."/>

        <xsl:if test="contains($pText, $pWord)">
            <xsl:text>X</xsl:text>
            <xsl:call-template name="countWord">
                <xsl:with-param name="pText"
                 select="concat(' ', substring-after($pText, $pWord))"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

    <xsl:template match="text()"/>
</xsl:stylesheet>

当此转换应用于此 XML 文档：

<mainNode>
    <book>
        <price> 100 </price>
        <city> chennai </city>
        <list>
            <language> c java ruby </language>
        </list>
    </book>
    <book>
        <price> 200 </price>
        <city> banglore </city>
        <list>
            <language> c java </language>
        </list>
    </book>
    <book>
        <price> 300 </price>
        <city> delhi </city>
        <list>
            <language> java java ruby </language>
        </list>
    </book>
</mainNode>

想要的正确结果产生：

 java --- 4

Answer 2

也许你可以尝试这个XSL模板来计算子字符串：

<xsl:template name="substring-count">
  <xsl:param name="string"/>
  <xsl:param name="substr"/>
  <xsl:choose>
    <xsl:when test="contains($string, $substr) and $string and $substr">
      <xsl:variable name="rest">
        <xsl:call-template name="substring-count">
          <xsl:with-param name="string" select="substring-after($string, $substr)"/>
          <xsl:with-param name="substr" select="$substr"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of select="$rest + 1"/>
    </xsl:when>
    <xsl:otherwise>0</xsl:otherwise>
  </xsl:choose>
</xsl:template>

用法：

<xsl:call-template name="substring-count">
  <xsl:with-param name="string" select="'mary had a little lamb'" />
  <xsl:with-param name="substr" select="'lamb'" />
</xsl:call-template>

Answer 3

在 语句中尝试：

count(//language[contains(concat(' ',.,' '), ' java ')])< /code>

如果您的文档结构相对静态，或者您在其他地方有名为 language 的节点用于其他目的，则可以将 //language 替换为/mainNode/book/list/language。

concat 位可能看起来有点复杂，但通过确保您正在查找的文本的开头和结尾有空格，并搜索 ' java '两边都有空格，就不会错误地包含恰好包含 java 的其他术语，例如 javascript。

如果“java”可能在一个节点中多次存在，那么您将需要使用递归模板。这是一种方法：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" />
  <xsl:template match="/">
    <xsl:variable name="list">
      <xsl:for-each select="//language">
        <xsl:call-template name="count">
          <xsl:with-param name="lang">java</xsl:with-param>
        </xsl:call-template>
      </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="concat('java -- ',string-length($list))" />
  </xsl:template>

  <xsl:template name="count">
    <xsl:param name="lang" />
    <xsl:param name="text" select="text()" />
    <xsl:if test="contains(concat(' ',$text,' '),concat(' ',$lang,' '))">
      <xsl:text>0</xsl:text>
      <xsl:call-template name="count">
        <xsl:with-param name="lang" select="$lang" />
        <xsl:with-param name="text" select="substring-after($text,$lang)" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

这实际上创建了一个由 0 组成的字符串，每个 java 出现一个，然后简单地使用该字符串的长度。

如果您可以选择使用 XSLT 2.0，则可以创建一个计算字符串中出现次数的函数，并使用 或类似的东西。

正如我在对您的问题的评论中指出的那样，更好地设计源 XML 会有很大帮助；如果一种语言的每次出现都有它自己的元素，那么这一切都是不必要的。当然，这可能超出您的控制范围，但如果您可以选择更改它（或说服提供商更改它），我强烈推荐它。

Answer 4

http://www.xsltfunctions.com/xsl/functx_number-of-matches。 html

count(tokenize($arg,$pattern)) - 1

我在这里也同样回答了：查找xslt 中的字符串中出现子字符串