相当于 VB.NET 中的 SQL IN

Question

我想做的是检查一个值是否与两个数字之一匹配（并且可以轻松地添加到要比较的数字中）。 我没有采用冗长的方式，例如：

If Number = 1 Or Number = 2 Then ...

我正在尝试这样做：

If Number In (1,2) Then...

由于 In 运算符在 VB 中不可用，因此我尝试了以下代码：

Protected SectionID As Integer = HttpContext.Current.Request.QueryString("sectionid")
Protected PageID As Integer = HttpContext.Current.Request.QueryString("pageid")

Protected Sub HotspotsLV_ItemDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.ListViewItemEventArgs) Handles HotspotsLV.ItemDataBound
    Dim SecondLineHolder As HtmlControl = e.Item.FindControl("SecondLineHolder")
    Select Case True
        Case New String("2", "3").Contains(SectionID) : SecondLineHolder.Attributes("style") = "color:#21720B"
        Case New String("8", "12").Contains(PageID) : SecondLineHolder.Attributes("style") = "color:#1B45C2"
    End Select
End Sub

我发现仅当 SectionID 为 2 或 PageID 为 8 时才有效。如果 SectionID 为 3 或 PageID 为 12，则它不起作用。这是为什么？我可以采取什么措施来解决这个问题？谢谢。

Answer 1

经过一番尝试后，我找到了一个很好的解决方案：

Select Case True
    Case Array.IndexOf(New Integer() {2, 3}, SectionID) > -1 : SecondLineHolder.Attributes("style") = "color:#21720B"
    Case Array.IndexOf(New Integer() {8, 12}, PageID) > -1 : SecondLineHolder.Attributes("style") = "color:#1B45C2"
End Select

Answer 2

Dim Numbers() As Integer = {1, 2}
If Numbers.Any(Function(i) i = Number) Then

Answer 3

您正在创建一个 String 实例而不是数组。尝试将其更改为：

Protected SectionID As Integer = HttpContext.Current.Request.QueryString("sectionid")
Protected PageID As Integer = HttpContext.Current.Request.QueryString("pageid")

Protected Sub HotspotsLV_ItemDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.ListViewItemEventArgs) Handles HotspotsLV.ItemDataBound
    Dim SecondLineHolder As HtmlControl = e.Item.FindControl("SecondLineHolder")
    Dim sections As Integer() = New Integer(){2,3}
    Dim pages As Integer() = New Integer(){8,12}
    Select Case True
        Case sections.Contains(SectionID) : SecondLineHolder.Attributes("style") = "color:#21720B"
        Case pages.Contains(PageID) : SecondLineHolder.Attributes("style") = "color:#1B45C2"
    End Select
End Sub

如果您使用Option Strict On，则类型不匹配将突出显示。在初始代码中，New String("2", "3") 将创建一个值为 222 的字符串。

编辑

对于 3.5 之前的 .Net 版本，Contains 方法将不可用。这可以使用 IndexOf 来模仿：

Array.IndexOf(sections, SectionID) > -1
' Equivalent to sections.Contains(SectionID)