Express - mongoose-auth 路由问题

Question

我有以下咖啡脚本代码。使用express和mongoose-auth，根据文档，使用中间件应该可以启用路由删除。这意味着在我调用 /auth/twitter 之后我应该使用 twitter 登录。不幸的是，由于某种原因我收到了 404 错误。有什么想法吗？

提前致谢。

express       = require 'express'
mongoose      = require 'mongoose'
mongoose_auth = require 'mongoose-auth'

UserSchema = new mongoose.Schema {}
User

UserSchema.plugin mongoose_auth, {
  everymodule: {
    everyauth: {
      User: () ->
        return User
    }
  }
  twitter: {
    everyauth: {
      myHostname:     'http://localhost:3000'
      consumerKey:    ''
      consumerSecret: ''
      redirectPath:   '/'
    }
  }
}

mongoose.model 'User', UserSchema

mongoose.connect 'mongodb://localhost/foobar'

User = mongoose.model 'User'

app = module.exports = express.createServer()

app.configure ->
  app.set 'views', "#{__dirname}/views"
  app.set 'view engine', 'jade'
  app.use require('stylus').middleware { src: "#{__dirname}/public" }
  app.use express.static "#{__dirname}/public"
  app.use express.bodyParser()
  app.use express.methodOverride()
  #app.use app.router
  app.use express.cookieParser()
  app.use express.session { secret: 'foobarmoocowetc' }
  mongoose_auth.middleware()

app.configure 'development', () ->
  app.use express.errorHandler {
    dumpExceptions: true
    showStack: true
  }

app.configure 'production', () ->
  app.use express.errorHandler()

app.get '/', (req, res) ->
  res.render 'page/index'

mongoose_auth.helpExpress app

app.listen 3000
console.log 'Express server listening on port %d in %s mode', app.address().port, app.settings.env

Answer 1

您没有将 mongoose_auth.middleware() 放入express的中间件列表中。您需要

app.use mongoose_auth.middleware()

他们的方式是，中间件刚刚创建并被忽略。可能您按照自述文件中的示例进行操作，但是当他调用 createServer 时，他正在设置中间件，并且您正在使用 app.use，这很好，但是您需要传递中间件函数 app.use 以便正确注册它。

这至少是一个问题。解决这个问题，看看会发生什么。有很多配置细节必须完美才能让 everyauth 正常工作，因此您可能还需要进行一些其他调整。