Node.js 和文件系统：这是竞争条件吗？

Question

我在类中有以下代码。 （它是coffescript——它用于couchdb实用程序！——但这实际上是一个node.js问题）。我正在尝试使用 Node 0.49 以 Node Way 的方式进行操作，这意味着对文件系统操作使用异步调用。起初，我很抓狂，因为在处理过程中 this.sentinel 多次变为零，所以我知道我在那里做错了什么。但后来我遇到了一个更奇怪的问题：在 load_directory 中，看到那些 console.log() 调用吗？观察当我运行这个时会发生什么。

check_sentinel: ->
    @sentinel--
    if @sentinel == 0
        @emit('designDirLoaded', @object)

load_file: (rootdir, filename, object) ->
    @sentinel++
    fname = path.join(rootdir, filename)
    @manifest.push(fname)
    fs.readFile fname, (err, data) =>
        object[filename] = data
        @check_sentinel()

load_directory: (dirpath, object) ->
    @sentinel++
    fs.readdir dirpath, (err, files) =>
        for fname in files
            console.log("X1: ", fname)
            fs.stat path.join(dirpath, fname), (err, stats) =>
                console.log("X2: ", fname)
                if stats.isFile()
                    @load_file(dirpath, fname, object)
                if stats.isDirectory()
                    object[fname] = {}
                    @load_directory(path.join(dirpath, fname), object[fname])
        @check_sentinel()

这就是我得到的结果：

X1:  memberByName.js
X1:  memberByClub.js
X2:  memberByClub.js
X2:  memberByClub.js

这是超现实的，它看起来很像竞争条件。 “memberByName”被传递给 fs.stat()，后者又将“memberByClub”传递给 load_file()，这意味着......什么？因为 load_file() 立即返回，所以它会争先恐后地向函数调用提供数组中的下一个文件名？或者我对给定范围内价值观的持久性有一些误解？

Answer 1

不，你所看到的是预期的。您必须记住的一件事是 fs.stat 是异步的。因此，外部循环（for fname in files）将在调用 fs.stat 的任何回调之前完成循环。

您看到 memberByClub.js 两次的原因是您在日志记录语句中使用 fname，但该变量来自闭包，在回调时该变量已更改调用fs.stat。

您可以使用 do (fname) => 包装内部循环以获得正确的日志记录语句，但我认为您需要重新构造代码以实现您想要对整个类执行的操作。

load_directory: (dirpath, object) ->
    @sentinel++
    fs.readdir dirpath, (err, files) =>
        for fname in files
            do (fname) =>
                console.log("X1: ", fname)
                fs.stat path.join(dirpath, fname), (err, stats) =>
                    console.log("X2: ", fname)
                    if stats.isFile()
                         @load_file(dirpath, fname, object)
                    if stats.isDirectory()
                        object[fname] = {}
                        @load_directory(path.join(dirpath, fname), object[fname])
        @check_sentinel()