Objective-c++：是否可以定义一个 c++具有返回 Objective-C 类并使用协变返回的方法的类？

Question

**编辑：这只发生在 llvm 上； gcc 很好地支持这一点。

请考虑以下事项。

Objective-c 类 A 和 B。

B 是 A 的子类

。我们想要一个如下所示的 C++ 层次结构：

class X {
  //...
  public:
    virtual A* getFoo();
};
class Y : public X {
  //...
  public:
    B* getFoo();
};

但是，如果这样做，您会收到错误，因为 Objective-c 类型会混淆 C++ 编译器：

error: virtual function 'getFoo' has a different return type ('Y *') than the function it overrides (which has return type 'X *')

I想知道是否有人有解决方法？ （显然，从长远来看，我们将放弃 Objective-c 类，但那不是今天）。

PS 这个似乎是我能找到的最相似的问题，但我很确定这是一个不同的问题。

Answer 1

这对我来说编译和运行良好：

#import <Cocoa/Cocoa.h>

@interface A : NSObject

- (NSString*) bar;

@end

@implementation A

- (NSString*) bar
{
    return @"";
}

@end

@interface B : A
@end

@implementation B

- (NSString*) bar
{
    return @"!!!";
}

@end

class X {
  //...
  public:
    virtual A* getFoo() = 0;
};

class Y : public X {
  //...
  public:
    virtual B* getFoo() { return [B new]; }
};


int main (int argc, char const *argv[])
{
    X* x = new Y;
    NSLog(@"%@", [x->getFoo() bar]);  // >> !!!

    return 0;
}

也许你的问题是你没有将 B 的头文件导入到定义 Y 的文件中？您无法在不完整的类上获得协方差（至少在 C++ 中），因为编译器需要知道 B 继承自 A 才能编译 Y。

无论如何，为了回答您的问题，看起来可以做到这一点。