Mathematica 列表 - 搜索二级并返回一级？

Question

我需要在列表的第二级中进行字符串匹配，但在第一级返回真实案例（第一级中有我需要对返回进行分类的信息）。

 First /@ GatherBy[#, #[[3]] &] &@
  Cases[#, x_List /;
   MemberQ[x, s_String /;
    StringMatchQ[s, ("*PHYSICAL EXAMINATION*"), 
     IgnoreCase -> True]], {2}] &@
  Cases[MemoizeTable["Diagnostic_table.txt"], {_, 
   11111, __}]

顶部的 GatherBy 命令只是按日期组织所有条目，因此我不会得到任何重复项。然后，我询问诊断表中具有与字符串“体检”匹配的术语的病例。

我只需搜索列表的第二级。如果我只搜索第一个，我不会返回所有真实的案例。如果我搜索第一层和第二层，我会得到重复项（某些情况下在第一层和第二层都包含所需的字符串，因此列表的第一层和第二层都会分别返回）。

我需要在第二级搜索字符串，然后仅返回包含匹配的第二级的列表的第一级。我不需要排除第二级，我只是不希望它像搜索第一级和第二级那样单独返回。

任何帮助将不胜感激！

Answer 1

也许是这样的？

list = {{a, b, c, {x, y}, d, x}, {a, b, c, d, x}, {{a, b, c, d}, x}}

Select[list, MemberQ[#, x, {2}] &]

输出：

{{a, b, c, {x, y}, d, x}}

更新

这也可以

Cases[list, _?(MemberQ[#, x, {2}] &)]

---

更新@rose问题（参见评论）

以下数据如何选择在字符串中包含单词“PHYSICAL EXAMINATION”的条目，例如在字符串“P-023 PHYSICAL EXAMINATION，TECHNICIAN，NOS”中，在第二级（即仅在子列表）？ （我稍微修改了@rose的示例）

rdata2={{1111113,21119,SQLDateTime[{2011,1,11,11,11,0.`}],31111,"EB/JW",1,47000,"T-510 CHEEK",{"T-510 CHEEK","No Examination, NOS"},"Text bla bla bla physical examination bla bla"},{1111114,21119,SQLDateTime[{2011,2,11,11,11,0.`}],31112,"EB/JW",1,47000,"T-510 CHEEK",{"T-510 CHEEK","P-023 PHYSICAL EXAMINATION, TECHNICIAN, NOS"},"Text bla bla bla"},
{1111115,21000,SQLDateTime[{2011,1,11,11,11,0.`}],31111,"EB/JW",1,47000,"T-510 CHEEK",{"T-510 CHEEK","P-023 physical examination, TECHNICIAN, NOS"},"Text bla bla bla physical examination bla bla"}};

（1）一种方式（仅返回条目1111114）

Select[rdata2, 
 MemberQ[Characters@#, 
   Flatten@{___, Characters["PHYSICAL EXAMINATION"], ___}, {2}] &]

（2）忽略大小写（但仍在子列表中选择）

Select[rdata2,MemberQ[ToLowerCase@Characters@#,
Flatten@{___,ToLowerCase@
Characters["PHYSICAL EXAMINATION"],___},{2}]&]

（选择条目1111114和1111115）

（3）最后一个示例（选择子列表中包含“No Examination”的条目，但“No”和“Examination”之间可能有零个或多个个字符，并且其中大小写再次被忽略）

Select[rdata2, 
 MemberQ[ToLowerCase@Characters@#, 
   Flatten@Riffle[
     ToLowerCase@Characters@{"No", "Examination"}, ___, {1, -1, 
      2}], {2}] &]

（选择条目 1111113）

毫无疑问，有更有效的方法可以继续。我希望我正确地解释了这个问题。

Answer 2

如果我了解您的要求，您可以考虑：

dat = {{1111113, 21119, SQLDateTime[{2011, 1, 11, 11, 11, 0.`}], 
    31111, "EB/JW", 1, 47000, 
    "T-510 CHEEK", {"T-510 CHEEK", "No Examination, NOS"}, 
    "Text bla bla bla physical examination bla bla"}, {1111114, 21119,
     SQLDateTime[{2011, 2, 11, 11, 11, 0.`}], 31112, "EB/JW", 1, 
    47000, "T-510 CHEEK", {"T-510 CHEEK", 
     "P-023 PHYSICAL EXAMINATION, TECHNICIAN, NOS"}, 
    "Text bla bla bla"}, {1111115, 21000, 
    SQLDateTime[{2011, 1, 11, 11, 11, 0.`}], 31111, "EB/JW", 1, 47000,
     "T-510 CHEEK", {"T-510 CHEEK", 
     "P-023 physical examination, TECHNICIAN, NOS"}, 
    "Text bla bla bla physical examination bla bla"}};

p = 
 Position[ dat,
   _String?(StringMatchQ[#, "*PHYSICAL EXAMINATION*", IgnoreCase -> True] &),
   {2, 3}
 ];

dat[[ Union[First /@ p] ]]