XPath/XSLT 嵌套谓词：如何获取外部谓词的上下文？

Question

似乎这个问题之前没有在 stackoverflow 上讨论过，除了 Working With Nested XPath Predicates 。 .. 精炼了，提供了不涉及嵌套谓词的解决方案。

所以我尝试编写我想要得到的过于简单的示例：

输入：

<root>
    <shortOfSupply>
        <food animal="doggie"/>
        <food animal="horse"/>
    </shortOfSupply>
    <animalsDictionary>
        <cage name="A" animal="kittie"/>
        <cage name="B" animal="dog"/>
        <cage name="C" animal="cow"/>
        <cage name="D" animal="zebra"/>
    </animals>
</root>

输出：

<root>
    <hungryAnimals>
        <cage name="B"/>
        <cage name="D"/>
    </hungryAnimals>
</root>

或者，如果没有交集，

<root>
    <everythingIsFine/>
</root>

并且我想使用嵌套谓词来获取它：

<xsl:template match="cage">
    <cage>
        <xsl:attribute name="name">
            <xsl:value-of select="@name"/>
        </xsl:attribute>
    </cage>
</xsl:template>

<xsl:template match="/root/animalsDictionary">
    <xsl:choose>
        <!--                                                             in <food>     in <cage>       -->
        <xsl:when test="cage[/root/shortOfSupply/food[ext:isEqualAnimals(./@animal, ?????/@animal)]]">
            <hungryAnimals>
                <xsl:apply-templates select="cage[/root/shortOfSupply/food[ext:isEqualAnimals(@animal, ?????/@animal)]]"/>
            </hungryAnimals>
        </xsl:when>
        <xsl:otherwise>
            <everythingIsFine/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

那么我应该写什么来代替那个 ??????？

我知道我可以使用另一个模板和变量/参数的广泛使用来重写整个样式表，但它甚至使这个样式表变得更加复杂，更不用说我针对实际问题所拥有的真正样式表了。

XPath参考文献中写道，点.符号表示当前上下文节点，但它并没有说明是否有可能获取在此之前的上下文节点；我简直不敢相信 XPath 缺少这个明显的功能。

Answer 1

XPath 2.0 单行：

for $a in /*/animalsDictionary/cage
      return
        if(/*/shortOfSupply/*[my:isA($a/@animal, @animal)])
          then $a
          else ()

当应用于提供的 XML 文档选择时：

   <cage name="B"/>
   <cage name="D"/>

无法使用单个 XPath 1.0 表达式来查找给定笼子中包含饥饿的动物.

这是一个 XSLT 解决方案（XSLT 2.0 仅用于避免使用扩展函数进行比较 - 在​​ XSLT 1.0 解决方案中，人们将使用扩展函数进行比较，并且xxx:node-set() 扩展来测试通过在变量主体中应用模板生成的 RTF 是否包含任何子元素）：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="my:my" exclude-result-prefixes="xs my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <my:Dict>
  <a genName="doggie">
    <name>dog</name>
    <name>bulldog</name>
    <name>puppy</name>
  </a>
  <a genName="horse">
    <name>horse</name>
    <name>zebra</name>
    <name>pony</name>
  </a>
  <a genName="cat">
    <name>kittie</name>
    <name>kitten</name>
  </a>
 </my:Dict>

 <xsl:variable name="vDict" select=
  "document('')/*/my:Dict/a"/>

 <xsl:template match="/">
  <root>
   <xsl:variable name="vhungryCages">
    <xsl:apply-templates select=
    "/*/animalsDictionary/cage"/>
   </xsl:variable>

   <xsl:choose>
    <xsl:when test="$vhungryCages/*">
     <hungryAnimals>
       <xsl:copy-of select="$vhungryCages"/>
     </hungryAnimals>
    </xsl:when>
    <xsl:otherwise>
     <everythingIsFine/>
    </xsl:otherwise>
   </xsl:choose>
  </root>
 </xsl:template>

 <xsl:template match="cage">
  <xsl:if test="
  /*/shortOfSupply/*[my:isA(current()/@animal,@animal)]">

  <cage name="{@name}"/>
  </xsl:if>
 </xsl:template>

 <xsl:function name="my:isA" as="xs:boolean">
  <xsl:param name="pSpecName" as="xs:string"/>
  <xsl:param name="pGenName" as="xs:string"/>

  <xsl:sequence select=
   "$pSpecName = $vDict[@genName = $pGenName]/name"/>
 </xsl:function>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时< /strong>（已更正为格式正确）：

<root>
    <shortOfSupply>
        <food animal="doggie"/>
        <food animal="horse"/>
    </shortOfSupply>
    <animalsDictionary>
        <cage name="A" animal="kittie"/>
        <cage name="B" animal="dogs"/>
        <cage name="C" animal="cow"/>
        <cage name="D" animal="zebras"/>
    </animalsDictionary>
</root>

生成所需的正确结果：

<root>
   <hungryAnimals>
      <cage name="B"/>
      <cage name="D"/>
   </hungryAnimals>
</root>

说明：请注意 XSLT current()< 的使用/代码> 函数。

Answer 2

XPath 1.0 不是“相对完整的”——它不能进行任意连接。如果您使用 XSLT，则始终可以通过将变量绑定到中间节点集或（有时）使用 current() 函数来绕过限制。

XPath 2.0 引入了范围变量，这使得它在关系上变得完整，所以这个限制已经消失了。

Answer 3

不足以表达您的测试条件吗？

Answer 4

注意 XPath 中的点运算符与当前上下文有关。在XSLT中，当前模板上下文由函数current()给出，大多数时候（并不总是） strong>) 与 . 一致。

---

您可以使用父轴缩写 (../) 执行测试（以及应用模板）：

 cage[@animal=../../shortOfSupply/food/@animal]

此外，第一个模板中的匹配模式是错误的，它应该相对于root：

 /root/animalsDictionary

@Martin 的建议显然也是正确的。

您的最终模板略有修改：

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="root/animalsDictionary">
        <xsl:choose>
            <xsl:when test="cage[@animal=../../shortOfSupply/food/@animal]">
                <hungryAnimals>
                    <xsl:apply-templates select="cage[@animal
                            =../../shortOfSupply/food/@animal]"/>
                </hungryAnimals>
            </xsl:when>
            <xsl:otherwise>
                <everythingIsFine/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="cage">
        <cage name="{@name}"/>
    </xsl:template> 

</xsl:stylesheet>