修复了在 XML::Twig 中使用的 XPath 谓词

Question

我正在尝试用 Perl 编写一个子例程，当提供一些子节点的文本值时，该子例程将删除 XML 中的给定节点。

给定如下 XML：

<Path>
  <To>
    <My>
      <Node>
        <ChildA>ValA</ChildA>
        <ChildB>ValB</ChildB>
        <ChildC>ValC</ChildC>
      </Node>
    </My>
  </To>
</Path>
<!-- A lot of siblings follow... -->

我正在使用的 XPath 表达式本质上是：

/Path/To/My/Node[ChildA="ValA" and ChildB="ValB" and ChildC="ValC"]

当我尝试运行我的脚本时，我收到如下错误：

Error in XPath expression
/Path/To/My/Node[ChildA="ValA" and ChildB="ValB" and ChildC="ValC"] at 
ChildA="ValA" and ChildB="ValB" and ChildC="ValC" at Twig.pm line 3353

我对此不知所措，正在寻找建议。我尝试用谷歌搜索，但找不到尝试在 XML::Twig 中使用这样的谓词的工作示例。我不知道问题是否出在我的 XPath 语法中，或者问题出在我如何使用 XML::Twig 中。

为了更好地衡量，我也尝试过：

/Path/To/My/Node[ChildA/text()="ValA" and ChildB/text()="ValB" and ChildC/text()="ValC"]

也没有运气。解决办法是什么？

Answer 1

在测试中，Node 是上下文节点，因此您必须说：

/Path/To/My/Node[./ChildA="ValA" and ./ChildB="ValB" and ./ChildC="ValC"]

这在使用 XML::XPath 的简短测试程序中对我有用。

编辑：抱歉，我对 XML::Twig 不太熟悉，并且我对其 XPath 功能做出了错误的假设。根据文档，它仅支持“类似 XPath”的语法，不会达到示例的复杂程度。但是，如果您使用 XML::Twig::XPath 而不是 XML::Twig，您将获得完整的 XPath 引擎：

my $twig = XML::Twig::XPath->new;
$twig->parse('your string');
my $nodes = $twig->findnodes('/Path/To/My/Node[ChildA="ValA" and ChildB="ValB" and ChildC="ValC"]');
print $nodes;

这将打印“ValAValBValC”。

Answer 2

有两种方法可以做到这一点：加载整个 XML 并删除不需要的节点，然后输出树枝，或者在进行过程中进行过滤，这稍微复杂一点，但使用的内存更少。

第一种方式（您可能需要最新版本的 XML::XPathEngine，我还没有使用旧版本或 XML::XPath 进行测试，它也可以充当 XPath 引擎）

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig::XPath;

my $t= XML::Twig::XPath->new( pretty_print => 'indented')
                       ->parse( \*DATA);
$_->delete for ($t->findnodes( '/Path/To/My/Node[./ChildA="ValA" and ./ChildB="ValB" and ./ChildC="ValC"]'));

$t->print;

__DATA__
<Path>
  <To>
    <My>
      <Node>
        <ChildA>ValA</ChildA>
        <ChildB>ValB</ChildB>
        <ChildC>ValC</ChildC>
      </Node>
      <Node>
        <ChildA>ValD</ChildA>
        <ChildB>ValB</ChildB>
        <ChildC>ValC</ChildC>
      </Node>
    </My>
  </To>
</Path>

和“过滤器”方式：

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

XML::Twig->new( twig_roots => { '/Path/To/My/Node' => \&filter },
                twig_print_outside_roots => 1,
                keep_spaces => 1,
              )
         ->parse( \*DATA);
exit;

# the handler expressions cannot lookahead, so we need to look at each node
# once it's completely parsed
sub filter
  { my( $t, $node)= @_;
    if(    ($node->field( 'ChildA') eq 'ValA')
        && ($node->field( 'ChildB') eq 'ValB')
        && ($node->field( 'ChildC') eq 'ValC')
      )
      { $node->delete; }
    else
      { $t->flush; }
  }

__DATA__
<Path>
  <To>
    <My>
      <Node>
        <ChildA>ValA</ChildA>
        <ChildB>ValB</ChildB>
        <ChildC>ValC</ChildC>
      </Node>
      <Node>
        <ChildA>ValD</ChildA>
        <ChildB>ValB</ChildB>
        <ChildC>ValC</ChildC>
      </Node>
    </My>
  </To>
</Path>