如何在 Coffeescript 中正确格式化长复合 if 语句

Question

如果我有一个复杂的 if 语句，我不想​​仅仅出于美观目的而溢出，那么分解它的最合理的方法是什么，因为在这种情况下，coffeescript 会将 return 解释为语句的主体？

if (foo is bar.data.stuff and foo isnt bar.data.otherstuff) or (not foo and not bar)
  awesome sauce
else lame sauce

Answer 1

如果该行以运算符结尾，CoffeeScript 不会将下一行解释为语句的主体，因此这是可以的：

# OK!
if a and
not 
b
  c()

它会编译为

if (a && !b) {
  c();
}

您的 if 可以格式化为

# OK!
if (foo is 
bar.data.stuff and 
foo isnt bar.data.otherstuff) or 
(not foo and not bar)
  awesome sauce
else lame sauce

或任何其他换行方案只要行以 and 或 or 或 is 或 == 或 not 或一些这样的运算

符至于缩进，您可以缩进非第一个只要正文更加缩进，您的 if 行就可以了：

# OK!
if (foo is 
  bar.data.stuff and 
  foo isnt bar.data.otherstuff) or 
  (not foo and not bar)
    awesome sauce
else lame sauce

您不能做的是：

# BAD
if (foo  #doesn't end on operator!
  is bar.data.stuff and 
  foo isnt bar.data.otherstuff) or 
  (not foo and not bar)
    awesome sauce
else lame sauce

Answer 2

这会在一定程度上改变代码的含义，但可能会有一些用处：

return lame sauce unless foo and bar
if foo is bar.data.stuff isnt bar.data.otherstuff
  awesome sauce
else
  lame sauce

请注意 is...isnt 链，它是合法的，就像 a a b＜ c 在 CoffeeScript 中是合法的。当然，蹩脚酱的重复是不幸的，你可能不想立即返回。另一种方法是使用 soaks 来编写

data = bar?.data
if foo and foo is data?.stuff isnt data?.otherstuff
  awesome sauce
else
  lame sauce

if foo and 有点不优雅；如果 foo 不可能是 undefined，那么您可以丢弃它。

Answer 3

就像任何其他语言一样，首先就没有它们。给不同的部分命名并分别对待它们。要么通过声明谓词，要么只是创建几个布尔变量。

bar.isBaz = -> @data.stuff != @data.otherstuff
bar.isAwsome = (foo) -> @isBaz() && @data.stuff == foo
if not bar? or bar.isAwesome foo
  awesome sauce
else lame sauce

Answer 4

对我来说，转义换行符看起来最具可读性：

if (foo is bar.data.stuff and foo isnt bar.data.otherstuff) \
or (not foo and not bar)
  awesome sauce
else lame sauce

Answer 5

当出现大量低级样板文件时，您应该提高抽象级别。

最好的解决方案是：

• 使用好的命名变量和函数

• if 中的逻辑规则/else 语句

逻辑规则之一是：

（不是 A 也不是 B）== 不是（A 或 B）

第一种方法。 变量：

isStuff              = foo is bar.data.stuff
isntOtherStuff       = foo isnt bar.data.otherstuff
isStuffNotOtherStuff = isStuff and isntOtherStuff
bothFalse            = not (foo or bar)
if isStuffNotOtherStuff or bothFalse
  awesome sauce
else lame sauce

这种方法的主要缺点是速度慢。如果我们使用 and 和 or 运算符功能并用函数替换变量，我们将获得更好的性能：

• C = A 和 B

如果 A 为 false 运算符and 不会调用

• C = A 或 B

如果 A 为 true 运算符 or 不会调用

第二种方式。 功能：

isStuff              = -> foo is bar.data.stuff
isntOtherStuff       = -> foo isnt bar.data.otherstuff
isStuffNotOtherStuff = -> do isStuff and do isntOtherStuff
bothFalse            = -> not (foo or bar)
if do isStuffNotOtherStuff or do bothFalse
  awesome sauce
else lame sauce