如何在 xmonad 中设置按键释放时发生的操作？

Question

如何在 xmonad 中设置按键释放时发生的操作？

我不喜欢菜单栏和面板。 我不想使用像 xmobar 这样的面板，而是希望在按住组合键时显示全屏信息页面（时间、当前选择的窗口和工作区等），然后在松开按键时消失。 我可以自己编写信息页面应用程序。 我可以将信息页面设置为在按键时生成。

我无法设置按键释放时发生的任何事情。

如何设置按键释放时发生的操作？

我正在考虑自己扩展 xmonad 来做到这一点。 我希望我不必这样做，因为这真的很烦人。

Answer 1

XMonad 将所有接收到的事件（包括 KeyPress 事件）传递给 handleEventHook，因此此代码能够对 keyRelease 事件做出反应：

module KeyUp where

import Data.Monoid
import qualified Data.Map as M

import XMonad
import Control.Monad

keyUpEventHook :: Event -> X All
keyUpEventHook e = handle e >> return (All True)

keyUpKeys (XConf{ config = XConfig {XMonad.modMask = modMask} }) = M.fromList $ 
    [ ((modMask, xK_v), io (print "Hi")) ]

handle :: Event -> X ()
handle (KeyEvent {ev_event_type = t, ev_state = m, ev_keycode = code})
    | t == keyRelease = withDisplay $ \dpy -> do
        s  <- io $ keycodeToKeysym dpy code 0
        mClean <- cleanMask m
        ks <- asks keyUpKeys
        userCodeDef () $ whenJust (M.lookup (mClean, s) ks) id
handle _ = return ()

您可以像在 xmonad 中那样使用它。 hs 文件：

handleEventHook    = handleEventHook defaultConfig `mappend`
                     keyUpEventHook `mappend`
                     fullscreenEventHook

不幸的是，这还不起作用：它只会对在常规 keys 配置中具有相应条目的 KeyRelease 事件做出反应。这是由于 XMonad.Main 中的 grayKeys 仅抓取 keys 中提到的键。您可以通过为您想要在 KeyUp 中处理的每个组合定义一个虚拟操作来解决此问题：

myKeys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
    ...
    , ((modMask              , xK_v     ), return ())

Answer 2

myStartupHook :: X ()
myStartupHook = do
  XConf { display = dpy, theRoot = rootw } <- ask
  myKeyCode <- io $ (keysymToKeycode dpy xK_Super_R)
  io $ grabKey dpy (myKeyCode) anyModifier rootw True grabModeAsync grabModeAsync
  spawn "~/ScriptsVcs/hideTint2.sh"

myHook :: Event -> X All
myHook e = do
  case e of
    ke@(KeyEvent _ _ _ _ _ _ _ _ _ _ _ _ _ _ _) -> do
      if ev_keycode ke == 134
        then if ev_state ke == 0
          then do
            -- key has been pressed
            spawn "~/ScriptsVcs/showTint2.sh"
          else do
            spawn "~/ScriptsVcs/hideTint2.sh"
        else pure ()
    _ -> pure ()
  pure $ All True

以上是一个例子。请注意，使用修饰键 (ev_state) 可能会发生“按键释放”。