切换到另一个选项卡时从插入模式更改为正常模式？

Question

假设我有多个选项卡，分屏中有多个缓冲区。

当我在一个缓冲区中处于编辑模式并切换到另一个选项卡（ctrl-pageDown）时，我仍处于插入模式。

有没有办法在更改选项卡时自动切换到正常模式？

更好的是，返回原始缓冲区时是否可以返回插入模式？

Answer 1

您可以尝试添加一些非常简单的内容，例如

autocmd TabEnter * stopinsert

到您的 .vimrc 中。

Answer 2

在 BufLeave 中，您可以调用一个函数来检查您所处的模式并设置缓冲区变量，然后在 BufEnter 中检查它是否存在并进入该模式。

请参阅有关 mode()、b:var 的帮助。

这是 .vimrc 的一些示例。我刚刚为此目的写了它，我自己也开始使用它，我认为它会很有用。

au BufLeave * call ModeSelectBufLeave()
au BufEnter * call ModeSelectBufEnter()

function! ModeSelectBufLeave()
    let b:mode_select_mode = mode()
    " A more complex addition you could make: if mode() == v, V, <C-V>, s, S, or <C-S>, store the selection and restore it in ModeSelectBufEnter
endfunction

function! ModeSelectBufEnter()
    let l:mode = mode()
    stopinsert  " First, go into normal mode
    if (l:mode == "i" || l:mode == "R" || l:mode == "Rv") && 
    \       (!exists('b:mode_select_mode') ||
    \       b:mode_select_mode == "n" ||
    \       b:mode_select_mode == "v" ||
    \       b:mode_select_mode == "V" ||
    \       b:mode_select_mode == "\<C-V>" ||
    \       b:mode_select_mode == "s" ||
    \       b:mode_select_mode == "S" ||
    \       b:mode_select_mode == "\<C-S>")
        normal l
        " Compensate for the left cursor shift in stopinsert if going from an
        " insert mode to a normal mode
    endif
    if !exists('b:mode_select_mode')
        return
    elseif b:mode_select_mode == "i"
        startinsert
    elseif b:mode_select_mode == "R"
        startreplace
    elseif b:mode_select_mode == "Rv"
        startgreplace
    endif
endfunction

Answer 3

我的 .vimrc 中有以下内容：

nmap <C-b> :b#<CR>
imap <C-b> <ESC>:b#<CR>

这可以让我在正常或插入模式下按 Ctrl+b 切换到备用缓冲区，但让我处于正常模式。

至于你的问题，你可以这样做：

imap <C-b> <ESC>:bnext<CR>i

这会让你在插入模式下按 Ctrl+b 并切换到下一个缓冲区，让你在到达那里时进入插入模式。

如果您发现自己在相同的两个缓冲区之间来回切换，我上面的原始映射可能更有用。当然，如果您使用全部三个，则最后一个需要不同的组合键。