VBA 代码在 Access 2007 中工作，但在 Access 2010 中不起作用。有什么想法吗？

Question

我的妻子编写了以下代码，当她的组织使用 Access 2007 时，它对她来说工作得很好。他们刚刚更新到 Access 2010，它就不再工作了。我对 Access 一点也不熟悉，但我建议我将其呈现给 Stack，看看你们是否可以直接看到在 Access 2010 中无法使用的任何内容。提前感谢您提供任何见解。

Private Sub Originating_Zone_AfterUpdate()

Dim EscortDB As DAO.Database

Dim rstBldgs As DAO.Recordset

Set EscortDB = CurrentDb()
Set rstBldgs = EscortDB.OpenRecordset("SELECT BuildingName FROM" & _
" ZoneBldgLookup WHERE ZoneLocation = '" & _
Forms!DateID!EscortIDSubform.Form.[Originating Zone] & _
"' ORDER BY BuildingName", [dbOpenDynaset])


rstBldgs.MoveLast

rstBldgs.MoveFirst

Do Until rstBldgs.EOF
Forms!DateID!EscortIDSubform.Form.[Pick Up Location].AddItem rstBldgs!BuildingName
rstBldgs.MoveNext
Loop

rstBldgs.Close


End Sub

更新：她使用以下代码使其正常工作。感谢您的帮助！

Private Sub Originating_Zone_AfterUpdate()

Dim sBuildList As String

sBuildList = ("SELECT BuildingName FROM" & _
" ZoneBldgLookup WHERE ZoneLocation = '" & _
Forms!DateID!EscortIDSubform.Form.[Originating Zone] & _
"' ORDER BY BuildingName")

Forms!DateID!EscortIDSubform.Form.[Pick Up Location].RowSource = sBuildList
Forms!DateID!EscortIDSubform.Form.[Pick Up Location].Requery

End Sub

Answer 1

这是可怕的代码。通过遍历记录集和 .AddItem 来填充下拉列表或列表框的效率非常低。只需将 SQL 字符串分配给组合框/列表框的 Rowsource 属性，无需代码即可完成整个操作。

现在，显然，列表根据此 AfterUpdate 事件所附加的控件中的选择而变化，但这意味着您在此事件中分配 Rowsource。也许，上面的所有代码都可以用这个替换：

  Forms!DateID!EscortIDSubform.Form.[Pick Up Location].Rowsource = "SELECT BuildingName FROM" & _
     " ZoneBldgLookup WHERE ZoneLocation = '" & _
     Forms!DateID!EscortIDSubform.Form.[Originating Zone] & _
     "' ORDER BY BuildingName"

我不能说代码不工作有什么问题（我怀疑存在沙箱模式/宏安全问题），但它的代码行数比需要的要多。

Answer 2

除了@David-W-Fenton 的建议之外，我认为您应该使用字符串变量来保存 SELECT 语句。然后您可以将其调试。打印到立即窗口，将其复制到新查询（在 SQL 视图中），并确保它实际返回行。

Dim strSql As String
strSql = "SELECT BuildingName FROM" & _
    " ZoneBldgLookup WHERE ZoneLocation = '" & _
    Forms!DateID!EscortIDSubform.Form.[Originating Zone] & _
    "' ORDER BY BuildingName"
Debug.Print strSql
Forms!DateID!EscortIDSubform.Form.[Pick Up Location].Rowsource = strSql

另外，如果这是名为 DateID 的表单模块中的代码，您可以将 Forms!DateID 替换为关键字 Me （这是“此表单”的简写...包含您正在运行的代码的表单）。这并没有显着缩短，但如果表单被重命名，则不需要更改 Me。仍然没什么大不了的……只是少了一个细节，你以后就不用再去摆弄了。