使用 XSL 删除命名空间并提取 XML 文件的子集

Question

当我的输入 Xml 为：

 <country>
       <state>
           <city>
               <name>DELHI</name>            
           </city>
      </state>
    </country>

对于如下所需的输出：

<city>
  <name>DELHI</name>            
</city

以下 xsl 工作正常：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" omit-xml-declaration="yes" />
    <xsl:template match="/">
        <xsl:copy-of select="//city">
        </xsl:copy-of>
    </xsl:template>
</xsl:stylesheet>

但相同的 XSL 不适用于上述输入 XML，如果添加了名称空间： 如下所示：

<country xmlns="http://india.com/states" version="1.0">
   <state>
       <city>
           <name>DELHI</name>            
       </city>
  </state>
</country>

我希望名称空间与要复制的城市元素一起被删除。

任何帮助将不胜感激。 谢谢

Answer 1

这是有关 XPath、XML 和 XSLT 的最多常见问题解答。搜索“默认命名空间和 XPath 表达式”。

解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://india.com/states">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="*">
  <xsl:element name="{name()}">
   <xsl:copy-of select="@*"/>
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>


 <xsl:template match="*[not(ancestor-or-self::x:city)]">
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<country xmlns="http://india.com/states" version="1.0">
    <state>
        <city>
            <name>DELHI</name>
        </city>
    </state>
</country>

想要的结果生成：

<city>
   <name>DELHI</name>
</city>

解释：

1. 在 XPath 中，无前缀的元素名称始终被认为位于“无命名空间”中。但是，所提供的 XML 文档中的每个元素名称都位于非空命名空间中（默认命名空间 "http://india.com/states"）。因此，//city 不选择任何节点（因为 XML 文档中没有任何元素不是命名空间），而 //x:city 其中 x: 绑定到命名空间 "http://india.com/states" 选择所有城市元素（位于命名空间"http://india.com/states ").

2. 在此转换中有两个模板。第一个模板匹配任何元素并重新创建它，但在无命名空间中。它还复制所有属性，然后将模板应用于该元素的子节点。

3. 对于不是 city 元素的祖先或本身不是 city 元素的所有元素，第二个模板会覆盖第一个模板。这里的操作是在所有子节点上应用模板。

更新：OP修改了询问为什么在处理新的、修改的XML文档的结果中存在不需要的文本的问题：

<country xmlns="http://india.com/states" version="1.0">
        <state>
            <city>
                <name>DELHI</name>
            </city>
        </state>
        <state2>
            <city2>
                <name2>MUMBAI</name2>
            </city2>
        </state2>
</country>

为了不生成文本“ MUMBAI”，上面的转换需要稍微修改一下——忽略（而不是复制）任何没有 x:city 祖先的文本节点。为此，我们添加以下一行空模板：

 <xsl:template match="text()[not(ancestor::x:city)]"/>

整个转换现在变为：

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:x="http://india.com/states">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:template match="*">
      <xsl:element name="{name()}">
       <xsl:copy-of select="@*"/>
       <xsl:apply-templates/>
      </xsl:element>
     </xsl:template>

     <xsl:template match="*[not(ancestor-or-self::x:city)]">
      <xsl:apply-templates/>
     </xsl:template>

     <xsl:template match="text()[not(ancestor::x:city)]"/>
</xsl:stylesheet>

结果仍然是想要的正确结果：

<city>
   <name>DELHI</name>
</city>

Answer 2

您可以使用以下模板获得所需的输出：

 <xsl:template match="*[not(ancestor-or-self::x:*[starts-with(name(),'city')])]">
  <xsl:apply-templates/>
 </xsl:template>

或

 <xsl:template match="/">
     <xsl:apply-templates select="//x:*[starts-with(name(),'city')]"/>
 </xsl:template>

在它提供的新输入上使用 Microsoft (R) XSLT Processor Version 4.0 进行测试：

<city>
   <name>DELHI</name>
</city>
<city2>
   <name2>MUMBAI</name2>
</city2>