LINQ 中与匿名类型不同（在 VB.NET 中）

Question

假设下面引用的 List 包含 2 个元素：

Dim Countries = From c In List _
                Select New With { .Country = c.Country, .CountryID = c.CountryID }

上面的代码返回

.Country=Spain .CountryID = 1
.Country=Spain .CountryID = 1

如何获取不同的值？ Countries 查询应仅包含

.Country=Spain .CountryID = 1

Answer 1

我只能假设您坚决使用匿名类型，因为 Alex Peck 给出的答案是正确的。 （我已经投了赞成票）。

然而，这归结为 VB.NET 与 C# 编译器的讨论。

在 VB.NET 中，当遇到匿名类型时，只有那些声明为关键属性的属性可用于比较目的。因此，在没有键的 VB.NET 中，当您尝试进行不同比较时，不会发生任何事情。

在此处阅读所有相关内容。

首先，回答您的问题，这适用于匿名类型：

Dim Countries = From c In List Select New With {Key c.CountryId, c.Country} Distinct.ToList

这就是 Freedompeace 的答案不太有效的原因。

然而 C# 的编译器有点不同。

当遇到匿名类型并且需要比较操作时，C# 编译器会重写 Equals 和 GetHashCode。它将迭代匿名类型的所有公共属性来计算对象的哈希码以测试相等性。

您可以阅读更多内容关于这一点，请点击此处。

希望这能回答您的问题。

Answer 2

Dim distinctCountries = Countries.Distinct()

当我停在调试器的最后一行时，这对我有用：

Imports System.Text

<TestClass()>
Public Class UnitTest1

    Class Test
        Public Country As String
        Public CountryID As Integer
    End Class

    <TestMethod()>
    Public Sub TestMethod1()

        Dim List(1) As Test
        List(0) = New Test With {.Country = "Spain", .CountryID = 1}
        List(1) = New Test With {.Country = "Spain", .CountryID = 1}

        Dim Countries = From c In List Select c.Country, c.CountryID

        Dim distinctCountries = Countries.Distinct()
    End Sub

End Class

Answer 3

Distinct 必须以某种方式知道哪些对象是相同的。你在这里选择匿名对象，它不知道哪些是相等的。我从来没有写过一行 VB.Net，但我尝试了一些东西，它起作用了：

Module Module1

    Sub Main()
        Dim countries As List(Of Country) = New List(Of Country)
        Dim spain1 As Country = New Country()
        Dim spain2 As Country = New Country()
        Dim spain3 As Country = New Country()
        Dim hungary As Country = New Country()
        spain1.ID = 1
        spain1.Name = "Spain"
        spain2.ID = 1
        spain2.Name = "Spain"
        spain3.ID = 2
        spain3.Name = "Spain"
        hungary.ID = 3
        hungary.Name = "Hungary"
        countries.Add(spain1)
        countries.Add(spain2)
        countries.Add(spain3)
        countries.Add(hungary)

        Dim ctr = From c In countries Select c.Name, c.ID
                  Distinct

        For Each c In ctr
            Console.WriteLine(c)
        Next
    End Sub

    Public Class Country

        Protected _name As String

        Protected _id As Long

        Public Property Name() As String
            Get
                Return _name
            End Get
            Set(ByVal value As String)
                _name = value
            End Set
        End Property

        Public Property ID() As Long
            Get
                Return _id
            End Get
            Set(ByVal value As Long)
                _id = value
            End Set
        End Property

    End Class
End Module

在你的情况下：

Dim Countries = From c In List 
                Select c.Country, c.CountryID Distinct

Answer 4

有一个名为 Distinct() 的 LINQ 运算符，您可以像这样调用它：

 Dim Countries = (From c In List _
             Select c.Country, c.CountryID).Distinct()

有关 Distinct 的更多信息

Answer 5

Dim Countries = From c In List _
                 Select New With {.Country = c.Country, .CountryID = c.CountryID }.Distinct()