检测Skype是否处于“紧凑视图”状态或“默认视图”

Question

我的应用程序的运行方式由 Skype 的视图模式决定，因为我的应用程序正在寻找类 TConversationWindow 的窗口，如果在默认视图中，该窗口是 tSkMainForm 的子级code>，并且如果在紧凑视图中，它不是 tSkMainForm 的子项。

这是我尝试做的：

Function IsCompactView:Boolean;
Var
 Wnd : Hwnd;
Begin
  Result := True;
  Wnd := FindWindow('TConversationForm',nil);

  if Wnd <> 0 then
  begin
   Wnd := GetParent(Wnd);
   // Custom function that grabs the Window Text
   if GetHandleText(Wnd) <> '' then
   Result := False;

  end;

End;

上面的函数将通过检查其父级是否有文本来查找顶级（除非我弄错了 - 没有窗口父级的窗口）TConversationForm 。如果 Skype 处于默认视图，则 TConversationForm 是 tSkMainForm 的子级，后者始终包含一些文本。它按预期工作。

现在解决实际问题：每当用户在两个视图之间切换时，顶级 TConversationForm 都不会“刷新”。它们消失了，但为了让它再次显示为 tSkMainForm 的子项（因此更改在 Winspector Spy 中可见），您必须在 Skype 中选择它，我不能依赖用户来做到这一点。

如果您不知道，这里是 2 个视图之间的区别：

紧凑视图

默认视图

如果您需要更多信息，请告诉我，谢谢！

Answer 1

不要使用 Windows 方法检测 Skype 是否处于“紧凑视图”或“默认视图”，而是尝试读取存储此类设置并通过“实时”更新的 config.xml 文件Skype。该文件位于

%AppData%\Skype\<your-skype-user-name>

例如 Windows 7 中，这是该文件内部的位置

C:\Users\<your windows user>\AppData\Roaming\Skype\<your-skype-user-name>

，存在一个名为 MultiWindowMode 的条目，

这是 MultiWindowMode 的 Xpath 位置

/config/UI/General/MultiWindowMode'

的值该条目的“1”表示“紧凑视图”，“0”表示“默认视图”。

请检查此演示，它使用 XPath 解析文件并读取 MultiWindowMode 的值。

{$APPTYPE CONSOLE}

uses
  ComObj,
  ActiveX,
  Variants,
  SysUtils;


function SkypeISCompactView(const SettingsFile : string) : Boolean;
var
   XmlDoc      : OleVariant;
   Node        : OleVariant;
begin
  Result:=False;
   if FileExists(SettingsFile) then
   begin
     XmlDoc       := CreateOleObject('Msxml2.DOMDocument.6.0');
     try
       XmlDoc.Async := False;
       XmlDoc.Load(SettingsFile);
       XmlDoc.SetProperty('SelectionLanguage','XPath');

        if (XmlDoc.parseError.errorCode <> 0) then
         raise Exception.CreateFmt('Error in Xml Data %s',[XmlDoc.parseError]);

       Node  :=XmlDoc.selectSingleNode('/config/UI/General/MultiWindowMode');
       if not VarIsClear(Node) then
        Result:=Node.text='1';
     finally
       XmlDoc:=Unassigned;
     end;
   end;
end;


begin
 try
    CoInitialize(nil);
    try
      Writeln(BoolToStr(SkypeISCompactView('C:\Users\<your windows user>\AppData\Roaming\Skype\<skype user>\config.xml'),True));
    except
      on E:Exception do
      begin
          Writeln(E.Classname, ':', E.Message);
      end;
    end;
 finally
      CoUninitialize;
 end;
 Readln;
end.