Actionscript 3：将 MovieClip 放置在特定层上？

Question

我目前正在开发一款平台游戏，我有一堆不同的图块用来形成我的地图。这些瓷砖的外观差异很大，而且彼此相邻放置，变化非常剧烈，不太美观。我一直在尝试通过以下方式解决此问题：

我有四层，每个要褪色的块有两层。第一层是实际图块（图形）所在的位置。第二层是面具。在遮罩层中，我有一个渐变，它与其他图块遮罩层完全相反（遮罩层 1 向下，遮罩层 2 向上）。然而，我需要能够动态地改变这些，将新的渐变放置在适当的遮罩层中，并将新的图块放置在适当的图形层中。

我在过去一个小时左右的时间里一直在谷歌搜索，试图找到一种方法来定义新的 MovieClip 放置在哪一层，但我找到的只是 setChildIndex，因为一层充当遮罩，所以我可以不用。 Actionscript中是否有这样的功能，或者我是否要手动制作所有图块组合？

感谢您的帮助， -Birjolaxew

Answer 1

尝试使用类似此类的内容：

package
{
    import flash.display.Sprite;

    public class LayeredContainer extends Sprite
    {
        // vars
        private var _layers:Array = [];

        /**
         * Constructor
         */
        public function LayeredContainer()
        {
            createLayer("_fallback_");
        }

        /**
         * Defines the layers to use
         * @param ...layers A list of layers to add
         */
        public function createLayers(...layers):void
        {
            var i:String;
            for each(i in layers)
                createLayer(i);
        }

        /**
         * Creates a single layer, adding it to the top of the display list
         * @param id The layer id
         */
        public function createLayer(id:String):Sprite
        {
            var l:Sprite = new Sprite();
            _layers[id] = l;

            addChild(l);

            return l;
        }

        /**
         * Returns a layer based on id
         * @param id The layer to return
         */
        public function layer(id:String):Sprite
        {
            return _layers[id] || layer("_fallback_");
        }
    }
}

然后您可以创建图层并添加如下内容：

var lc:LayeredContainer = new LayeredContainer();
lc.createLayers("tiles", "whatever", "mask");

addChild(lc);

lc.layer("tiles").addChild(_some_tile_you_made_);