使用汇编应用程序关闭 Linux 时出现分段错误

Question

以下应用程序在执行时会生成分段错误：

.set __NR_reboot, 169
.set LINUX_REBOOT_CMD_POWER_OFF, 0x4321FEDC

.section .text
.globl _start
_start:
   movl $LINUX_REBOOT_CMD_POWER_OFF, %ebx
   movl $__NR_reboot, %eax
   int $0x80

这是一个非常简单的应用程序，我一定错过了一些非常明显的东西。有人可以帮助我吗？

它是用以下内容编译的：

as shutdown.s -o shutdown.o
ld shutdown.o -o shutdown

编辑：

即使是一个仅调用系统调用sync()的简单应用程序也会生成分段错误：

.set __NR_sync, 36

.section .text
.globl _start
_start:
   movl $__NR_sync, %eax
   int $0x80

   movl $1, %eax         #syscall exit
   movl $0, %eax
   int $0x80

Answer 1

警告：请记住在调用reboot(2)之前先sync(2)。

reboot(2) 系统调用需要 4 个参数。您将其与 libc 混淆了
包装纸。

警告：请记住在调用reboot(2)之前先sync(2)。

（它实际上采用magic*参数，以便人们必须重新阅读文档并且不要忘记调用sync(2)。）

警告 ：我有说过在调用 reboot(2) 之前必须先 sync(2) 吗？

Answer 2

我正在添加final &工作源代码，因为这个问题将来可能会引起某人的兴趣：

                                     # For the right sys_call numbers on your arch,
                                     # check <asm/unistd_32.h> (or unistd_64.h)

.set __NR_sync, 36                   # sys_call sync()    
.set __NR_reboot, 88                 # sys_call reboot()

.set LINUX_REBOOT_MAGIC1, 0xfee1dead # flags are specified in: <linux/reboot.h>
.set LINUX_REBOOT_MAGIC2, 672274793
.set LINUX_REBOOT_CMD_POWER_OFF, 0x4321fedc
.set LINUX_REBOOT_CMD_RESTART, 0x01234567

.section .text
.globl _start
_start:
   movl $__NR_sync, %eax             # call sync()
   int $0x80

   movl $__NR_reboot, %eax
   movl $LINUX_REBOOT_MAGIC1, %ebx
   movl $LINUX_REBOOT_MAGIC2, %ecx
   movl $LINUX_REBOOT_CMD_RESTART, %edx
   #movl $0, %esi
   int $0x80                         # call reboot()

   movl $1, %eax
   movl $0, %ebx
   int $0x80                         # call exit()

Answer 3

来自 linux/i386/ syscall.S：函数编号应该是放置在 %eax 中，所有参数按顺序放置在以下寄存器中：%ebx、%ecx、%edx、%esi、%edi 和 %ebp。

这就是为什么代码中最后一个 movl %eax,0 应更改为 movl %ebx, 0。