如何使用 ORACLE 中的 SQL UPDATE 命令将 BLOB 数据附加/连接到 BLOB 列

Question

我需要将数据附加到我的 BLOB 字段， 如何使用 UPDATE 命令执行此操作？ 我要问的是；是否可以连接 blob 数据，以便我最终可以将其设置为类似的字段 更新BLOB_表 放 BLOB_field = BLOB_field + BLOB_data

我尝试使用 DBMS_LOB.APPEND 但它不返回值；所以我创建了一个函数，它给出了“指定的 LOB 定位器无效”的错误

CREATE OR REPLACE FUNCTION MAKESS.CONCAT_BLOB(A in BLOB,B in BLOB) RETURN BLOB IS
 C BLOB;
BEGIN
DBMS_LOB.APPEND(c,A);
DBMS_LOB.APPEND(c,B);
RETURN c;
END;
/

Answer 1

您需要使用 创建一个临时 blob DBMS_LOB.createtemporary：

SQL> CREATE OR REPLACE FUNCTION CONCAT_BLOB(A IN BLOB, B IN BLOB) RETURN BLOB IS
  2     C BLOB;
  3  BEGIN
  4     dbms_lob.createtemporary(c, TRUE);
  5     DBMS_LOB.APPEND(c, A);
  6     DBMS_LOB.APPEND(c, B);
  7     RETURN c;
  8  END;
  9  /

Function created

那么您应该能够在更新语句中使用它：

SQL> CREATE TABLE t (a BLOB, b BLOB, c BLOB);

Table created

SQL> INSERT INTO t VALUES
  2     (utl_raw.cast_to_raw('aaa'), utl_raw.cast_to_raw('bbb'), NULL);

1 row inserted

SQL> UPDATE t SET c=CONCAT_BLOB(a,b);

1 row updated

SQL> SELECT utl_raw.cast_to_varchar2(a),
  2         utl_raw.cast_to_varchar2(b),
  3         utl_raw.cast_to_varchar2(c)
  4  FROM t;

UTL_RAW.CAST_TO_VARCHAR2(A UTL_RAW.CAST_TO_VARCHAR2(B UTL_RAW.CAST_TO_VARCHAR2(C
-------------------------- -------------------------- --------------------------
aaa                        bbb                        aaabbb 

Answer 2

借助 PL/SQL blob 可以就地更新，根本不需要自定义函数：

BEGIN
   FOR c IN (select a, b from t where a is not null for update) LOOP
       DBMS_LOB.APPEND(c.a, c.b);
   END LOOP;
END;
/