TCL - 在文件中查找规则模式并返回出现次数和出现次数

Question

我正在编写一段代码来从文件中 grep 正则表达式模式，并输出该正则表达式及其出现的次数。

这是代码：我试图在我的文件 hello.txt 中找到模式“grep”：

set file1 [open "hello.txt" r]
set file2 [read $file1]
regexp {grep} $file2 matched
puts $matched
while {[eof $file2] != 1} {
set number 0
if {[regexp {grep} $file2 matched] >= 0} {
 incr number
}

puts $number
}

我得到的输出：

grep

--------
can not find channel named "qwerty
iiiiiii
wxseddtt
lsakdfhaiowehf'
jbsdcfiweg
kajsbndimm s
grep
afnQWFH
 ACV;SKDJNCV;
    qw  qde 
 kI UQWG
grep
grep"
    while executing
"eof $file2"

Answer 1

在 while 循环中检查 eof 通常是一个错误 - 检查 gets 的返回码：

set filename "hello.txt"
set pattern {grep}
set count 0

set fid [open $filename r]
while {[gets $fid line] != -1} {
    incr count [regexp -all -- $pattern $line]
}
close $fid

puts "$count occurrances of $pattern in $filename"

另一个想法：如果你只是计算模式匹配，假设你的文件不太大：

set fid [open $filename r]
set count [regexp -all -- $pattern [read $fid [file size $filename]]]
close $fid

Answer 2

该错误消息是由命令eof $file2 引起的。原因是 $file2 不是一个文件句柄（或通道），而是包含文件 hello.txt 本身的内容。您可以使用 set file2 [read $file1] 读取此文件内容。

如果你想这样做，我建议将 $file2 重命名为 $filecontent 并循环遍历每个包含的行：

foreach line [split $filecontent "\n"] {
  ... do something ...
}

Answer 3

格伦是当场。这是另一个解决方案：Tcl 附带了 fileutil 包，其中有 grep 命令：

package require fileutil
set pattern {grep}
set filename hello.txt
puts "[llength [fileutil::grep $pattern $filename]] occurrences found"

如果您关心性能，请使用 Glenn 的解决方案。