在 Fortran 90 中，按行将数组写入文本文件的好方法是什么？

Question

我是 Fortran 新手，我希望能够以行方式将二维数组写入文本文件（列之间有空格，每行都在自己的行上）。我已经尝试了以下操作，它似乎在以下简单示例中工作：

PROGRAM test3
  IMPLICIT NONE

  INTEGER :: i, j, k, numrows, numcols
  INTEGER, DIMENSION(:,:), ALLOCATABLE :: a

  numrows=5001
  numcols=762
  ALLOCATE(a(numrows,numcols))
  k=1
  DO i=1,SIZE(a,1)
    DO j=1,SIZE(a,2)
      a(i,j)=k
      k=k+1
    END DO
  END DO

  OPEN(UNIT=12, FILE="aoutput.txt", ACTION="write", STATUS="replace")
  DO i=1,numrows
    WRITE(12,*) (a(i,j), j=1,numcols)
  END DO
END PROGRAM test3

正如我所说，这在这个简单示例中似乎工作正常：生成的文本文件 aoutput.txt 包含数字第 1 行为 1-762，第 2 行为数字 763-1524，依此类推。

但是，当我在一个更复杂的程序中使用上述想法（即上面的最后一个倒数第五行、倒数第四行、倒数第三行和倒数第二行代码）时，我运行陷入麻烦；看起来，每一行只是间歇性地分隔（由新行）。 （我没有发布，也可能不会发布，这里是我的整个复杂的程序/脚本——因为它相当长。）我的复杂程序/脚本中缺乏一致的行分隔符可能表明我的代码中存在另一个错误，而不是上面的四行写入文件例程，因为上面的简单示例似乎工作正常。不过，我想知道，您能否帮我想想是否有更好的按行写入文本文件例程我应该使用？

非常感谢您抽出时间。我真的很感激。

Answer 1

这里有几个问题。

最根本的一点是，您不应该使用文本作为大量数据的数据格式。它很大而且很慢。文本输出对于您要自己阅读的内容很有用；你不会坐下来打印 381 万个整数并翻阅它们。正如下面的代码所示，正确的文本输出比二进制输出慢大约 10 倍，大 50%。如果您转向浮点值，则使用 ascii 字符串作为数据交换格式会存在精度损失问题。 如果您的目标是与 matlab 交换数据，那么

将数据写入 matlab 可以读取的格式是相当容易的；您可以使用 matlab 中的 matOpen/matPutVariable API，或者只是将其写为 matlab 可以读取的 HDF5 数组。或者您可以直接用原始 Fortran 二进制文件写出数组，如下所示，并具有 matlab 读取。

如果您必须使用 ascii 来写出巨大的数组（如上所述，这是一个糟糕且缓慢的想法），那么您将遇到列表定向 IO 中默认记录长度的问题。最好的方法是在运行时生成一个正确描述输出的格式字符串，对于如此大的（~5000 个字符宽！）行，最安全的方法是将记录长度显式设置为大于要打印的长度因此 fortran IO 库不会帮助您打破线路。

在下面的代码中，

  WRITE(rowfmt,'(A,I4,A)') '(',numcols,'(1X,I6))'

生成字符串 rowfmt，在本例中为 (762(1X,I6))，这是您将用于打印输出的格式，以及 RECLOPEN 的 code> 选项将记录长度设置为大于 7*numcols + 1。

PROGRAM test3
  IMPLICIT NONE

  INTEGER :: i, j, k, numrows, numcols
  INTEGER, DIMENSION(:,:), ALLOCATABLE :: a
  CHARACTER(LEN=30) :: rowfmt
  INTEGER :: txtclock, binclock
  REAL    :: txttime, bintime

  numrows=5001
  numcols=762
  ALLOCATE(a(numrows,numcols))
  k=1
  DO i=1,SIZE(a,1)
    DO j=1,SIZE(a,2)
      a(i,j)=k
      k=k+1
    END DO
  END DO

  CALL tick(txtclock)
  WRITE(rowfmt,'(A,I4,A)') '(',numcols,'(1X,I6))'
  OPEN(UNIT=12, FILE="aoutput.txt", ACTION="write", STATUS="replace", &
       RECL=(7*numcols+10))
  DO i=1,numrows
    WRITE(12,FMT=rowfmt) (a(i,j), j=1,numcols)
  END DO
  CLOSE(UNIT=12)
  txttime = tock(txtclock)

  CALL tick(binclock)
  OPEN(UNIT=13, FILE="boutput.dat", ACTION="write", STATUS="replace", &
       FORM="unformatted")
  WRITE(13) a
  CLOSE(UNIT=13)
  bintime = tock(binclock)

  PRINT *, 'ASCII  time = ', txttime
  PRINT *, 'Binary time = ', bintime

CONTAINS

    SUBROUTINE tick(t)
        INTEGER, INTENT(OUT) :: t

        CALL system_clock(t)
    END SUBROUTINE tick

    ! returns time in seconds from now to time described by t
    REAL FUNCTION tock(t)
        INTEGER, INTENT(IN) :: t
        INTEGER :: now, clock_rate

        call system_clock(now,clock_rate)

        tock = real(now - t)/real(clock_rate)
    END FUNCTION tock
END PROGRAM test3

Answer 2

这可能是一种非常迂回且耗时的方法，但无论如何......您可以简单地使用 advance='no' 单独打印每个数组元素（以禁止插入换行符在您的 write 语句中打印内容之后。完成一行后，您可以使用“正常”write 语句来获取换行符，然后从下一行重新开始。这是一个小例子：

program testing

implicit none

integer :: i, j, k

k = 1

do i=1,4
   do j=1,10
      write(*, '(I2,X)', advance='no') k
      k = k + 1
   end do
   write(*, *) ''  ! this gives you the line break
end do

end program testing

当您运行该程序时，输出如下：

 1  2  3  4  5  6  7  8  9 10  
11 12 13 14 15 16 17 18 19 20  
21 22 23 24 25 26 27 28 29 30  
31 32 33 34 35 36 37 38 39 40

Answer 3

使用“*”是列表定向 IO——Fortran 将为您做出决定。有些行为没有指定。您可以使用格式语句获得更多控制。如果您想明确识别行边界，请在每行后面写一个标记符号。类似这样的内容：

  DO i=1,numrows
    WRITE(12,*) a(i,:)
    write (12, '("X")' )
  END DO

几个小时后的附录：

也许对于较大的 numcols 值，对于您用来检查文件的某些程序来说，行太长了？对于输出语句，尝试：

WRITE(12, '( 10(2X, I11) )' ) a(i,:)

这会将矩阵的每一行（如果矩阵超过 10 列）分解为文件中的多个较短的行。