格式化 XML 的十进制值

Question

我目前遇到一个问题，我们连接的系统期望接收 XML，其中包含三个格式化为小数点后一位的双精度字段。就我个人而言，我认为我们的系统应该能够以默认格式发送值，然后由其他系统根据需要格式化自己的表示形式，但可惜这似乎不是一个选项。

我的基于 Java 的系统当前正在通过使用 XStream 将对象转换为 XML。我们有一个 XSD，它伴随着 XML 并将各种元素定义为字符串、双精度、日期时间等。

我有三个双精度字段，它们保存 12.5、100.123、5.23445 等值。现在它们几乎按原样转换为XML。我需要将这些值在 XML 中格式化为小数点后一位； 12.5、100.1、5.2 等。

我简要地想出了实现此目的的选项：

• 在这些值进入 XML 之前，以某种方式让 Java 将这些值格式化为这种精度。也许 NumberFormat 可以做到这一点，尽管我认为这主要用于字符串输出。
• 希望XSD能为我做这件事；我知道您可以在 XSD 中对精度进行限制，但我不确定它是否真正处理舍入本身，或者只是说“123.123 的值对此模式无效”？
• 使用 XSLT 以某种方式为我完成此任务。

我想请大家集思广益，看看在这种情况下使用什么是“可接受的”方式/最佳实践。

谢谢， 戴夫.

Answer 1

XStream 有转换器 (教程）。您必须注册自己的 Double 转换器来处理此问题。在转换器中使用 DecimalFormat< /a> 限制小数位数。

Answer 2

这可以在单个 XPath 表达式中完成。

使用：

floor(.) + round(10*(. -floor(.))) div 10

使用 XSLT 作为 XPath 主机进行验证：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="text()[contains(.,'.')]">
    <xsl:value-of select=
     "floor(.) + round(10*(. -floor(.))) div 10"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
 <n>12.5</n>
 <n>100.123</n>
 <n>5.26445</n>
</t>

所需的、正确的生成结果：

<t>
   <n>12.5</n>
   <n>100.1</n>
   <n>5.3</n>
</t>

说明：标准 XPath 函数的使用 floor()，round() 和 XPath 运算符 div 和你的逻辑。

通用表达式：

floor(.) + round($vFactor*(. -floor(.))) div $vFactor

其中$vFactor为10^N，其中N为小数点后的位数我们想要。

使用此表达式，修改后的 XSLT 转换如下：

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:param name="pPrecision" select="4"/>

     <xsl:variable name="vFactor" select=
     "substring('10000000000000000000000',
                 1, $pPrecision+1
                )
     "/>

     <xsl:template match="node()|@*">
         <xsl:copy>
           <xsl:apply-templates select="node()|@*"/>
         </xsl:copy>
     </xsl:template>

     <xsl:template match="text()[contains(.,'.')]">
        <xsl:value-of select=
         "floor(.) + round($vFactor*(. -floor(.))) div $vFactor"/>
     </xsl:template>
</xsl:stylesheet>

当此转换应用于同一个 XML 文档（如上）时，我们会为任何有意义的 $pPrecision 值生成所需的输出。在上面的示例中，它设置为4，结果包含小数点后四舍五入的所有数字：

<t>
   <n>12.5</n>
   <n>100.123</n>
   <n>5.2645</n>
</t>