Vim 对所有文件类型运行 autocmd，除了

Question

我有一个 Vim autocmd，可以在写入之前删除文件中的尾随空格。我几乎 100% 都希望这样做，但有一些文件类型我希望禁用它。传统的做法是在逗号分隔的列表中列出您希望 autocmd 运行的文件类型，例如：

autocmd BufWritePre *.rb, *.js, *.pl

但在这种情况下，这将是繁重的。

有没有办法将 autocmd 模式与除与该模式匹配的文件之外的所有文件进行匹配？我在文档中找不到与 NOT 匹配器等效的内容。

Answer 1

*.rb 不是文件类型。这是一个文件模式。 ruby 是文件类型，甚至可以在没有 .rb 扩展名的文件上设置。因此，您最可能想要的是 autocmd 调用的函数，以检查不应执行操作的文件类型并删除空格。

fun! StripTrailingWhitespace()
    " Don't strip on these filetypes
    if &ft =~ 'ruby\|javascript\|perl'
        return
    endif
    %s/\s\+$//e
endfun

autocmd BufWritePre * call StripTrailingWhitespace()

---

根据埃文的答案，您可以检查缓冲区局部变量并确定是否使用该变量进行剥离。如果您决定不想删除通常会删除的文件类型的缓冲区，这还允许您一次性禁用。

fun! StripTrailingWhitespace()
    " Only strip if the b:noStripeWhitespace variable isn't set
    if exists('b:noStripWhitespace')
        return
    endif
    %s/\s\+$//e
endfun

autocmd BufWritePre * call StripTrailingWhitespace()
autocmd FileType ruby,javascript,perl let b:noStripWhitespace=1

Answer 2

单行方式的另一种选择：

let blacklist = ['rb', 'js', 'pl']
autocmd BufWritePre * if index(blacklist, &ft) < 0 | do somthing you like | endif

然后您可以对除黑名单中的文件类型之外的所有文件类型执行您喜欢的操作。

Answer 3

一个好方法是将一个文件类型的局部变量设置为 true。然后，如果该变量为 false（如果为其他所有内容设置）或者它根本存在（无需预设它），则设置自动命令。

autocmd BufWritePre *.foo let b:foo=true

if !exists("b:foo")
    autocmd ...
endif

根据注释更改变量前缀

Answer 4

您可以在同一个正则表达式上执行 except 操作：

autocmd BufWritePre *\(.out\|.diffs\)\@<! <your_command>

这将对除 .out 或 .diffs 之外的所有文件扩展名执行 操作。

Answer 5

这适用于语法自动命令，其中模式（）只是文件类型。它排除任何 rst 文件：

au Syntax *\(^rst\)\@<! …

Answer 6

我们的 .vimrc 配置文件在启动时仅运行一次。所以如果你此时进行 if 测试，它将不起作用，因为当前没有 python 文件正在编辑。

但是您可以使用 .vimrc 来设置自动行为：vim 每次遇到特殊条件时都会执行此操作。条件可以是您的情况：“正在编辑一个新文件，其文件类型是‘python’”。参见:h:au

Answer 7

这已经很晚了，但我认为您可以使用两个 autocmd，一个执行“默认”行为，另一个执行“例外”行为。一个例子是，当我想将除 HTML 之外的所有文件类型的选项卡大小设置为 4 时，我希望将其设置为 2。我可以这样配置：

# for all file types
autocmd FileType * se tabstop=4
# except HTML
autocmd FileType html se tabstop=2