在 xsl 中格式化科学数字表示形式

Question

我的 XML -1.8959581529998104E-4 中有以下值。我想将其格式化为应该使用 XSL 给我 -0.000189595815299981 的确切数字。

format-number(-1.8959581529998104E-4,'0.000000;-0.000000') gives me NaN.

有什么想法吗？

Answer 1

XSLT 1.0 不支持科学计数法。

：number('-1.8959581529998104E-4')
结果：NaN

此：number('-0.000189595815299981')
结果：-0.000189595815299981

XSLT 2.0 支持科学记数

法：number('-1.8959581529998104E-4')
结果：-0.000189595815299981

编辑：一个非常简单的 XSLT 1.0 解决方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="number[substring-after(.,'E')]">
        <xsl:variable name="vExponent" select="substring-after(.,'E')"/>
        <xsl:variable name="vMantissa" select="substring-before(.,'E')"/>
        <xsl:variable name="vFactor"
             select="substring('100000000000000000000000000000000000000000000',
                               1, substring($vExponent,2) + 1)"/>
        <xsl:choose>
            <xsl:when test="starts-with($vExponent,'-')">
                <xsl:value-of select="$vMantissa div $vFactor"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$vMantissa * $vFactor"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

使用此输入：

<number>-1.8959581529998104E-4</number>

输出：

-0.00018959581529998104

Answer 2

这是基于 user357812 的回答。但我让它像一个函数一样工作并处理非科学记数法

<xsl:template name="convertSciToNumString" >
    <xsl:param name="inputVal" select="0"/>
    <xsl:variable name="vExponent" select="substring-after($inputVal,'E')"/>
    <xsl:variable name="vMantissa" select="substring-before($inputVal,'E')"/>
    <xsl:variable name="vFactor"
         select="substring('100000000000000000000000000000000000000000000',
                           1, substring($vExponent,2) + 1)"/>
    <xsl:choose>
        <xsl:when test="number($inputVal)=$inputVal">
            <xsl:value-of select="$inputVal"/>
        </xsl:when>
        <xsl:when test="starts-with($vExponent,'-')">
            <xsl:value-of select="format-number($vMantissa div $vFactor, '#0.#############')"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="format-number($vMantissa * $vFactor, '#0.#############')"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

用法：

<xsl:template match="X">
    <X>
        <xsl:call-template name="convertSciToNumString">
            <xsl:with-param name="inputVal" select="text()"/>
        </xsl:call-template>
    </X>    
</xsl:template>

这应该处理科学记数法和十进制值的混合。

Answer 3

没有模板的另一种可能的解决方法：

<xsl:stylesheet version="1.0" ... xmlns:java="http://xml.apache.org/xslt/java">
...
<xsl:value-of select="format-number(java:java.lang.Double.parseDouble('1E-6'), '0.000')"/>

Answer 4

在 Moop 和 user357812 在一种特定场景中确定 vFactor 时。

如果 vExponent 是一位正数（前面没有“+”号），则 vFactor 将设置为空字符串。这是因为假设 vExponent 的第一个字符是加号/减号，因此我们对第二个字符以后的字符感兴趣。然后，vMantissa 变量乘以一个空字符串，导致模板输出 NaN。

如果 vExponent 是多位正数（前面没有“+”号），则 vFactor 设置为不正确的值。由于上述假设，第一个数字被忽略，然后将 vMantissa 乘以不正确的 vFactor。

因此，我对之前发布的代码进行了一些修改，以便它可以处理以下形式的科学数字：2E-4、2E+4 和 2E4。

<xsl:template name="convertSciToNumString" >
    <xsl:param name="inputVal" select="0"/>
    <xsl:variable name="vMantissa" select="substring-before(., 'E')"/>
    <xsl:variable name="vExponent" select="substring-after(., 'E')"/>
    <xsl:variable name="vExponentAbs" select="translate($vExponent, '-', '')"/>
    <xsl:variable name="vFactor" select="substring('100000000000000000000000000000000000000000000', 1, substring($vExponentAbs, 1) + 1)"/>
    <xsl:choose>
        <xsl:when test="number($inputVal)=$inputVal">
            <xsl:value-of select="$inputVal"/>
        </xsl:when>
        <xsl:when test="starts-with($vExponent,'-')">
            <xsl:value-of select="format-number($vMantissa div $vFactor, '#0.#############')"/>
        </xsl:when>
        <xsl:otherwise>         
            <xsl:value-of select="format-number($vMantissa * $vFactor, '#0.#############')"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 5

刚刚在 Linux 下使用 1.1.24 版本中的 libxslt1.1 与 xsltproc 进行了尝试：

即使没有任何专用模板，XSLT 1.1 现在也能够以指数/科学格式读取，它似乎很简单:-))