在Fortran 90中，是否无法在新变量的声明语句中引用先前声明的变量？

Question

在 Fortran 中，变量的声明语句是否可以引用先前声明的变量？例如，当我尝试以下操作时：

PROGRAM test3
  IMPLICIT NONE

  INTEGER :: a=2286
  INTEGER :: b=a/3

  WRITE(*,*) a, b
END PROGRAM test3

我收到编译时错误消息：

test3.f90:5.16:

  INTEGER :: b=a/3
                1
Error: Parameter 'a' at (1) has not been declared or is a variable, which
does not reduce to a constant expression

另一方面，如果我在与b 的声明，它编译并运行良好：

PROGRAM test3
  IMPLICIT NONE

  INTEGER :: a=2286
  INTEGER :: b
  b=a/3

  WRITE(*,*) a, b
END PROGRAM test3

这给了我正确的输出：

2286         762

为什么会出现这种情况——先前声明的变量不能包含在新变量的声明语句中？我做错了什么吗？或者这只是“Fortran 生活中的事实”？

非常感谢您抽出时间！

Answer 1

让我再补充一件事：在主程序和参数中初始化这样的变量（好吧，您必须像这样为参数初始化它们），但它的行为可能会让您感到惊讶，如果您太习惯使用它并开始在子例程和函数中使用它：

例如，我们大多数人最初会假设该程序：

program foo

   call bar
   call bar

contains

  subroutine bar
  integer :: i=3

      print '(A,I3)','At start of bar: i = ', i
      i = i + 1
      print '(A,I3)','At end of bar:   i = ', i
  end subroutine bar

end program foo

会打印

At start of bar: i =   3
At end of bar:   i =   4
At start of bar: i =   3
At end of bar:   i =   4

--- 但事实并非如此。它打印出

At start of bar: i =   3
At end of bar:   i =   4
At start of bar: i =   4
At end of bar:   i =   5

这是出于“历史原因”，因为当事情表现出明显错误的行为时，情况往往如此。在声明时初始化变量本质上将其转变为：

integer :: i

并且

integer, save :: i = 3

初始化仅在第一次完成。这意味着第二次，变量会记住它之前的值 (4) 并递增该值。

所以我写这篇文章的原因基本上是警告你不要在声明时初始化变量太舒服。我建议在参数和主程序中执行此操作（您不会遇到此问题，因为您只输入主程序一次），除此之外别无其他。

Answer 2

错误消息非常明确。变量声明中使用的初始值设定项必须是常量值。在您的示例中，a 不是常量。

它应该像这样工作：

PROGRAM test3
  IMPLICIT NONE

  INTEGER, PARAMETER :: a=2286
  INTEGER :: b=a/3

  WRITE(*,*) a, b
END PROGRAM test3

因为 a 是一个常量。

Answer 3

在“a”的声明中添加“,参数”。这将允许您在另一个声明中使用 a 的值。这也意味着“变量”a的值不能改变。