如何伪造 Perl 模块以获取依赖？

Question

我正在使用的外部 Perl 库有一个依赖项 (DBD::mysql)，我不会在我的应用程序 (DBD::SQLite) 中使用它，因此我希望系统假装依赖项存在，即使它存在一个“假”。

我可以创建一个空的 DBD::mysql.pm 模块来编译吗？或者有更直接的方法吗？

Answer 1

所以我认为这里没有几个问题。

当您说依赖时，您的意思是外部模块只是尝试 require 或 use DBD::mysql？如果是这种情况，那么您应该建议开发人员不要明确这样做，因为这违背了使用 DBI。应根据 DSN 即时选择数据库驱动程序。

假设作者只是使用包名称，因为他认为这是一件有用或有意义的事情，那么是的，您可以覆盖该包，并且有有几种方法可以做到这一点。

正如您所建议的，您只需创建自己的模块 DBD/mysql.pm 来定义 DBD::mysql 包。

如果您有兴趣，还可以做一些其他事情。您只需让 Perl 相信该模块已加载，而不是在源代码树中散布假目录和文件。我们可以通过直接操作%INC来做到这一点。

package main;    # or whereever

BEGIN {
    $INC{'DBD/mysql.pm'} = "nothing to see here";
}

只需添加此哈希键，我们就可以阻止在文件系统中搜索有问题的模块。请注意，这是在 BEGIN 块中。如果外部作者执行了 use，那么我们必须在评估 use 语句之前填充此值。 use 语句相当于 require 和 import 包含在 BEGIN 中。

现在让我们从一般意义上进一步推测外部作者试图调用包的方法。如果这些符号不存在，您将收到运行时错误。您可以利用 Perl 的 AUTOLOAD 来拦截此类调用并执行正确的操作。 正确的事情可能有很大差异，从简单地记录消息到更复杂的事情。例如，您可以使用此工具通过监视所有调用来检查作者引入的耦合深度。

package DBD::mysql;

sub AUTOLOAD {
    printf(
        "I don't wanna '%s' called from '%s'\n", $AUTOLOAD, caller(0)
      );
}

package main;    # or whereever

BEGIN {
    $INC{'DBD/mysql.pm'} = "nothing to see here";
}

DBD::mysql::blah()

现在我们还讨论一下这样的情况：违规作者还创建了一些面向对象的类实例，并且他的代码没有正确考虑
为你的存根代码。我们将存根我们假设是 new 的构造函数，以使用我们的包名称来祝福匿名哈希。这样你就不会得到
当他调用实例上的方法时出错。

package DBD::mysql;

sub AUTOLOAD {
    printf(
        "I don't wanna '%s' called from '%s'\n", $AUTOLOAD, caller(0)
    );
}

sub new {
    bless({}, __PACKAGE__)
}

package main;    # or whereever

BEGIN {
    $INC{'DBD/mysql.pm'} = "nothing to see here";
}

my $thing = new DBD::mysql;

$thing->blah()