在保持底部 (Y) 位置的同时进行形状​​补间/变换？

Question

我正在尝试对火箭发射的影片剪辑进行补间。我希望它在升空前“挤压”，然后在升空时“拉伸”。

当我使用变换工具在时间轴上对此进行补间时，我可以“挤压”火箭，并且火箭的底部保持在“地面”上。这就是我想要的。然而，由于我不会详细说明的原因，我需要在 AS3 中执行此操作，而不是在时间轴上执行此操作。但是，当我使用“高度”补间时，影片剪辑高度会发生变化，但它会在底部收缩/拉伸（锁定在顶部）。

可以用补间类做我想做的事吗？我还需要使用“高度”之外的其他东西吗？

我应该使用变换矩阵吗？如果我使用变换矩阵，我可以对其进行补间吗？ （我在变换矩阵方面没有太多经验。）

这是我用于拉伸的补间：

var tweenPlayer1:Tween = new Tween(mc_player, "height", Strong.easeOut, mc_player.height, mc_player.height+100, 2, true);

Answer 1

可能有更好的方法来处理startingYandHeight，但这对你有用

import fl.transitions.Tween;
import fl.transitions.easing.*;
import fl.transitions.TweenEvent;

var startingYandHeight:Number = mc_player.y + mc_player.height;

var myTween:Tween = new Tween(mc_player, "height", Strong.easeOut, mc_player.height, mc_player.height + 100, 2, true);
myTween.addEventListener( TweenEvent.MOTION_CHANGE, onChange);

function onChange( e:TweenEvent ):void{
    mc_player.y = startingYandHeight - mc_player.height;
}

Answer 2

问题可能在于您将图形锚定在 FLA 中的影片剪辑对象内的位置。如果您调整图形使其底部对齐，例如影片剪辑内部的graphic.y = -graphic.height，则Y轴上的缩放应该只是从底部而不是从顶部推动图形。

Answer 3

正如我上面所描述的，这是另一种方法。这与更改注册点具有相同的效果，而无需处理子组件和层的麻烦。

基于我在这里找到的教程：http://theflashconnection。 com/content/how-to-change-registration-point-as3#viewSource

var heightChange:int = 200;

setRegPoint(mc_player, 0, mc_player.height);

var myTween:Tween = new Tween(mc_player,"height",Strong.easeOut,mc_player.height,mc_player.height - heightChange,2,true);

function setRegPoint(obj:DisplayObjectContainer, newX:Number, newY:Number):void {
    //get the bounds of the object and the location 
    //of the current registration point in relation
    //to the upper left corner of the graphical content
    //note: this is a PSEUDO currentRegX and currentRegY, as the 
    //registration point of a display object is ALWAYS (0, 0):
    var bounds:Rectangle = obj.getBounds(obj.parent);
    var currentRegX:Number = obj.x - bounds.left;
    var currentRegY:Number = obj.y - bounds.top;

    var xOffset:Number = newX - currentRegX;
    var yOffset:Number = newY - currentRegY;
    //shift the object to its new location--
    //this will put it back in the same position
    //where it started (that is, VISUALLY anyway):
    obj.x += xOffset;
    obj.y += yOffset;

    //shift all the children the same amount,
    //but in the opposite direction
    for(var i:int = 0; i < obj.numChildren; i++) {
        obj.getChildAt(i).x -= xOffset;
        obj.getChildAt(i).y -= yOffset;
    }
}