编译 X 驱动程序时，如何在 configure.ac 中测试 XFIXES 的版本？

Question

我正在为 X 编写一个视频设备驱动程序，它需要 XFIXES 扩展提供的一些功能。现在，我非常确定 X Server 的所有目标版本都将至少安装 XFIXES 版本 2，但我真的很想在我的 configure.ac 文件中测试这一点，以在用户尝试时发出警告为非常旧版本的服务器或（由于某种原因）未包含 XFIXES 的服务器编译我的驱动程序。现在我只是这样做：

# Essentially this is just supposed to check if the server currently supports
# V2 or better of the XFIXES protocol, and to define XFIXES if it does.
AC_CHECK_HEADER(X11/extensions/Xfixes.h,
    HAVE_XFIXES="yes"; 
    AC_DEFINE([HAVE_XFIXES],[1],[XFixes Proto Found]),,
    [#include <X11/Xlib.h>])
# should have a better test for this
if test "x${HAVE_XFIXES}" = "xyes"; then
  AC_DEFINE([XFIXES],[1],[XFixes >= 2.0])
fi

Answer 1

您可以使用 AC_CHECK_FUNC检查库中是否存在特定函数。您之前必须已在该库上运行过 AC_CHECK_LIB 才能正常工作。

Answer 2

像这样的事情：

AC_CACHE_CHECK([for Xfixes >= 2.0], [foo_have_xfixes_2],
[AC_LINK_IFELSE([AC_LANG_PROGRAM(
                [[#include <X11/Xlib.h>
                  #include <X11/extensions/Xfixes.h>]],
                [[#if !(XFIXES_MAJOR >= 2)
                  #error XFIXES_LT_2
                  #endif]])],
                [foo_have_xfixes_2=yes], [foo_have_xfixes_2=no])])

if test "x${foo_have_xfixes_2}" = "xyes"; then
  AC_DEFINE([XFIXES],[1],[XFixes >= 2.0])
else
  AC_MSG_WARN("XFixes >= 2.0 not present")
fi

编辑——我现在有点明白问题了。我们将在此基础上构建初始解决方案。
现在我知道我们不能使用 XFIXES_MAJOR （或类似的东西），请使用您关心的结构本身作为测试的结构定义。对于此示例，我假设该结构是 XFixesCursorImage，因为当 XFIXES_MAJOR >= 2 时，它具有一些新组件（例如，名称）。希望定义相同结构的有效服务器标头也将具有这些组件新组件：

AC_CACHE_CHECK([for Xfixes >= 2.0], [foo_have_xfixes_2],
[AC_LINK_IFELSE([AC_LANG_PROGRAM(
                [[#include <???>
                  XFixesCursorImage bar;]],
                [[bar.name = "bar";]])],
                [foo_have_xfixes_2=yes], [foo_have_xfixes_2=no])])

if test "x${foo_have_xfixes_2}" = "xyes"; then
  AC_DEFINE([XFIXES],[1],[XFixes >= 2.0])
else
  AC_MSG_WARN("XFixes >= 2.0 not present")
fi

包含标头现在应该是标头的服务器版本。这个想法是服务器标头中 XFIXES_MAJOR < 2 将没有该组件并且编译将会失败。如果违反该假设，则该方法也将不起作用。