如何使用 NASM 查找字符串的长度？

Question

我正在尝试使用 NASM 编写一个程序，该程序从命令行参数获取输入。由于未提供字符串长度，我正在尝试创建一个函数来计算我自己的字符串长度。这是我的尝试，它获取指向 ebx 寄存器中字符串的指针，并返回 ecx 中字符串的长度：

len:
    push ebx
    mov ecx,0
    dec ebx
    count:
        inc ecx
        inc ebx
        cmp ebx,0
        jnz count
    dec ecx
    pop ebx
    ret

我的方法是遍历字符串，逐个字符，检查是否为空。如果不是，我会增加 ecx 并转到下一个字符。我相信问题在于 cmp ebx,0 对于我想要做的事情来说是不正确的。我将如何正确地检查该字符是否为空？另外，还有其他我可以做得更好的事情吗？

Answer 1

您正在将 ebx 中的值与 0 进行比较，这不是您想要的。 ebx 中的值是内存中字符的地址，因此应该像这样取消引用：

cmp byte[ebx], 0

此外，最后一个push ebx 应该是pop ebx >。

Answer 2

以下是我在检查 argv[1] 的 64 位 Linux 可执行文件中执行此操作的方法。内核使用堆栈上的 argc 和 argv[] 启动一个新进程，如 x86-64 System V ABI 中所述。

_start:
    pop    rsi              ; number of arguments (argc)
    pop    rsi              ; argv[0] the command itself (or program name)
    pop    rsi              ; rsi = argv[1], a pointer to a string
    mov    ecx, 0           ; counter
.repeat:
    lodsb                   ; byte in AL
    test   al,al            ; check if zero
    jz     .done            ; if zero then we're done
    inc    ecx              ; increment counter
    jmp    .repeat          ; repeat until zero
.done:
    ; string is unchanged, ecx contains the length of the string


; unused, we look at command line args instead
section .rodata
    asciiz:    db    "This is a string with 36 characters.", 0

这是缓慢且低效的，但很容易理解。

为了提高效率，您只需要

• 循环中的 1 个分支（为什么循环总是编译成“do...while”样式（尾部跳转）？）
• 通过使用 movzx 加载而不是合并到之前的 RAX 中来避免错误的依赖关系价值（为什么 GCC 不使用部分寄存器？）。
• 在循环后减去指针，而不是增加内部的计数器。

当然，SSE2 在 x86-64 中始终可用，因此我们应该使用它来检查 16 字节的块（在达到对齐边界后）。查看优化的手写 strlen 实现，例如 glibc 中的实现。 (https://code.woboq.org/userspace/glibc /sysdeps/x86_64/strlen.S.html）。

Answer 3

这是我如何编码的

len:
      push ebx
      mov  eax, ebx
lp:
        cmp byte [eax], 0
        jz  lpend
        inc eax
        jmp lp
lpend:
        sub eax, ebx

      pop ebx
      ret

（结果在 eax 中）。可能有更好的方法。