DBI::fetchall_arrayref 的 Perl 数组取消引用问题

Question

我是 Perl 新手，在取消引用 DBI 模块中 fetchall_arrayref 所导致的数组时遇到问题：

my $sql = "SELECT DISTINCT home_room FROM $classlist";
my $sth = $dbh->prepare($sql);
$sth->execute;
my $teachers = $sth->fetchall_arrayref;
foreach my $teacher (@{$teachers}) {
    print $teacher;
}

运行此命令将打印引用而不是数组中的值。

但是，当我运行时：

my $arrref = [1,2,4,5];
foreach (@{$arrref}) {
print "$_\n";
}

我得到了数组的值。

我做错了什么？感谢您的帮助！

杰夫

Answer 1

来自文档

fetchall_arrayref 方法可以是
用于获取所有数据
从准备和执行返回
语句句柄。 它返回一个
对包含以下内容的数组的引用
每行一个引用。

因此，在您的示例中， $teacher 是一个 ARRAY 引用。
所以你需要循环遍历这个数组引用

foreach my $teacher (@{$teachers}) {
    foreach my $titem (@$teacher) {
        print $titem;
    }
}

Answer 2

如果您只想提取教师列，则需要使用：

my @teachers = @{$dbh->selectcol_arrayref($sql)};

Answer 3

fetchall_arrayref 获取查询的所有结果，因此您实际返回的是对数组数组的引用。返回的每一行将是列的 arrayref。由于您的查询只有一列，您可以说：

my $teachers = $sth->fetchall_arrayref;
foreach my $teacher (@{$teachers}) {
    print $teacher->[0];
}

得到您想要的。

查看更多内容：

Perl 中的数组的数组。

Answer 4

您有对行数组的引用。每行都是对字段数组的引用。

foreach my $teacher_row (@$teachers) {
    my ($home_room) = @$teacher_row;
    print $home_room;
}

您会看到 Data::Dumper 的差异。

use Data::Dumper;
print(Dumper($teachers));
print(Dumper($arrref));

Answer 5

$sth->fetchall_arrayref 返回对每行包含一个引用的数组的引用！
请在此处查看 DBI 文档。

Answer 6

根据 DBI 的 fetchall_arrayref() 的文档：

fetchall_arrayref 方法可以是
用于获取所有数据
从准备和执行返回
语句句柄。它返回一个
对包含以下内容的数组的引用
每行一个引用。

您只需要一层间接：

my $sql = "SELECT DISTINCT home_room FROM $classlist";
my $sth = $dbh->prepare($sql);
$sth->execute;
my $teachers = $sth->fetchall_arrayref;
foreach my $teacher (@{$teachers}) {
    local $" = ', ';
    print "@{$teacher}\n";
}

数据结构有时可能有点难以可视化。当发生这种情况时，我求助于 Data::Dumper ，以便我可以插入这样的行：

print Dumper $teacher;

我发现有时通过转储数据结构，我会得到一个即时地图，在创建时用作参考点操作该结构的代码。我最近经历了一场真正的结构噩梦，只是偶尔使用 Dumper 来理顺我的头。

Answer 7

您可以使用 map 取消引用返回的结构：

@teachers = map { @$_->[0] } @$teachers;

现在您有一个简单的教师数组。