远程检查文件大小并获取报告

Question

此脚本尝试：

• 从 txt 文件（计算机名称列表）获取输入，

• 检查是否列表中计算机上的日志文件大于 1000 字节，

• 创建一个 txt 报告，其中包含出现该错误的计算机的名称日志文件超过1000 字节，

• 使用文件少于 1000 字节的计算机名称创建另一个 txt 报告。< /p>

然而，出了点问题。任何帮助都会很好。

@echo off
for /f "tokens=*" %%I in (computernames.txt)do call :checksz %%I
goto :eof

:checksz
setlocal
set file="\\%1\c$\data\info.log"
set min=1000

FOR /F "usebackq" %%A IN ('%file%') DO set size=%%~zA

if %size% GTQ %min% (
echo. %1 >>logsizemin.txt
) ELSE (
echo. %1>>logsizemax.txt
)

大家好， 感谢您的宝贵支持。我祝贺那些构思和建立这个网站的人做得非常好并且很有用。 我对脚本做了一些修改，您建议合并其他功能，但有些东西没有按照我想要的方式工作..如您所见，我使用 editv32 来隐藏批处理中的密码，原理是相同的，但是正如您在检查日志大小后所看到的，使用“maxlongsize.txt”来获取执行下一个活动的 PC 的名称。我希望在文件“logsizemax.txt”中的所有电脑上按顺序执行这些活动，一开始只进行一次身份验证。我注意到，由于某种原因，有时文件“logsizemin.txt”没有创建，但我不明白为什么。最多是放入另一个文件，例如“计算机无法访问”那些无法通过网络访问的电脑，但我完全不知道如何实现它。我希望我已经充分解释了。抱歉英语不好！我想你明白我的意图:)。跟随批次

@setlocal
@echo off
editv32 -p "Enter username:" USR    
editv32 -m -p "Enter password:" PWD
for /f "tokens=1" %%I in (computernames.txt) do call :checksz %%I
endlocal
goto :eof

:checksz
setlocal
set file="\\%1\c$\data\data.log"
set min=1000
type NUL>logsizemax.txt
type NUL>logsizemin.txt
if not exist %file% goto :eof
FOR /F "usebackq delims=" %%A IN ('%file%') DO set size=%%~zA

if %size% GEQ %min% ( echo %1>>logsizemax.txt ) ELSE ( echo %1>>logsizemin.txt )
endlocal

@setlocal
for /f "tokens=1" %%I in (logsizemax.txt) do call :sw %%I
endlocal
goto :eof

:sw
echo.
echo *****************************************
echo *          VBS & Deploy script      *
echo *****************************************

echo.
echo Run VBS and deploy script .....

psexec \\%1 -u %USR% -p %PWD% cscript "\\rep\Reg.vbs"
psexec \\%1 -u %USR% -p %PWD% cmd /c "\\rep\deploy.cmd"

echo.
echo **************************
echo *        EXE Run         *
echo **************************

echo.
echo Running exe .....

psexec -u %USR% -p %PWD% \\%1 "c:\Program Files\test.exe" 

echo.
echo ***********************************
echo *    Exe application launched     *
echo ***********************************
echo.
goto END

:END
exit

Answer 1

您可以避免使用环境变量并同时使用第二个 FOR 。尝试这个更简单的蝙蝠版本，使用更通用的 :checksz 例程。

@echo off
for /f "tokens=*" %%a in (computernames.txt) do (
  call :checksz "\\%%a\c$\data\info.log" 1000 "%%a"
)
goto :eof

:checksz
if %~z1 GTR %2 (
echo %~3 >> logsizemin.txt
) ELSE (
echo %~3 >> logsizemax.txt
)
goto :eof

请参阅帮助呼叫了解更多信息。

Answer 2

更改：GTG->GEQ，不要用引号将变量括起来两次，从 echo 中删除前导空格，并进行一些清理。

@setlocal
@echo off
for /f "tokens=1" %%I in (computernames.txt) do call :checksz %%I
endlocal
goto :eof

:checksz
setlocal
set file=\\%1\c$\data\info.log
set min=1000

if not exist %file% endlocal && goto :eof
FOR /F "usebackq delims=" %%A IN ('%file%') DO set size=%%~zA

if %size% GEQ %min% ( echo %1>>logsizemin.txt ) ELSE ( echo %1>>logsizemax.txt )
endlocal
goto :eof

编辑：根据 PA 和 Andriy M 的评论进行更新 - 如果文件不存在，则删除 \ 更新注释。