VB6：用多个多字符分隔符分割？

Question

我目前的 split 功能有问题。我可以仅用 1 个分隔符进行分割 (split())，也可以用许多单个字符进行分割 (custom())。有办法分割这个吗？请记住，这些分隔符是不按顺序排列的。

 "MY!!DATA@@IS!!LOCATED@@HERE!!IN!!BETWEEN@@THE@@ATS!!AND!!MARKS"

我需要你的帮助才能得到以下结果，

 "MY" , "DATA" , "IS" , "LOCATED" , "HERE" , "IN" , "BETWEEN","THE", "ATS" , "AND", "MARKS"

谢谢

Answer 1

创建一个新的 VB6 EXE 项目并向您提供的表单中添加一个按钮，并对 Button1_Click 事件使用以下代码：

Private Sub Command1_Click()
    Dim myText As String
    Dim myArray() As String
    Dim InBetweenAWord As Boolean
    Dim tmpString As String
    Dim CurrentCount As Integer

    CurrentCount = 0

    myText = "MY!!DATA@@IS!!LOCATED@@HERE!!IN!!BETWEEN@@THE@@ATS!!AND!!MARKS"

    For i = 1 To Len(myText)
        If (Mid(myText, i, 1) = "@" Or Mid(myText, i, 1) = "!") And InBetweenAWord = True Then
            CurrentCount = CurrentCount + 1
            ReDim Preserve myArray(CurrentCount)
            myArray(CurrentCount) = tmpString
            tmpString = ""
            InBetweenAWord = False
        Else
            If (Mid(myText, i, 1) <> "@" And Mid(myText, i, 1) <> "!") Then
                tmpString = tmpString & Mid(myText, i, 1)
                InBetweenAWord = True
            End If

        End If
    Next

    For i = 1 To CurrentCount
        MsgBox myArray(i)       'This will iterate through all of your words
    Next


End Sub

请注意，一旦第一个 For-Next 循环完成，[myArray] 将包含您的所有单词没有不需要的字符，因此您可以在任何您喜欢的地方使用它们。我只是将它们作为 MsgBox 显示给用户，以确保我的代码有效。

Answer 2

VB6 中的字符处理确实很尴尬。我更喜欢使用像这样的内置函数

Private Function MultiSplit(ByVal sText As String, vDelims As Variant) As Variant
    Const LNG_PRIVATE   As Long = &HE1B6 '-- U+E000 to U+F8FF - Private Use Area (PUA)
    Dim vElem           As Variant

    For Each vElem In vDelims
        sText = Replace(sText, vElem, ChrW$(LNG_PRIVATE))
    Next
    MultiSplit = Split(sText, ChrW$(LNG_PRIVATE))
End Function

使用 MultiSplit 像这样

Private Sub Command1_Click()
    Dim vElem       As Variant

    For Each vElem In MultiSplit("MY!!DATA@@IS!!LOCATED@@HERE!!IN!!BETWEEN@@THE@@ATS!!AND!!MARKS", Array("!!", "@@"))
        Debug.Print vElem
    Next
End Sub