如何在 Perl 中关闭并重新打开 STDOUT？

Question

我想关闭 STDOUT 以防止我的代码输出我需要进行进一步计算但不希望出现在我的网页上的特定图像。

所以我想关闭 STDOUT，对代码执行我必须执行的操作，然后重新打开 STDOUT 以将内容输出到网页。 （不是文件）

我尝试的是：

    close STDOUT;
    # my code here
    open STDOUT;

这不起作用......

谢谢

Answer 1

有多种方法可以解决您的问题，其中许多方法不需要您关闭 STDOUT，也不需要冒破坏程序标准 I/O 通道的风险。

例如，您可以使用 (1-arg) select 命令来指示暂时在其他地方输出 print 命令。

 print $stuff_you_want_to_send_to_STDOUT;

 select(NOT_STDOUT);
 # now default print sends things to NOT_STDOUT.
 # This doesn't need to be a real filehandle, though you may get warning
 # messages if it is not.
 ...;
 print $the_image_you_dont_want_to_go_to_STDOUT;
 ...;

 select(STDOUT);
 # now  print  sends things to STDOUT agin
 print $more_stuff_you_do_want_to_go_to_STDOUT;

您还可以在运行时重新分配*STDOUT glob，而无需关闭任何句柄。

 *OLD_STDOUT = *STDOUT;
 print $for_STDOUT;

 *STDOUT = *NOT_STDOUT;     # again, doesn't need to be a real filehandle
 print $stuff_to_suppress;

 *STDOUT = *OLD_STDOUT;     # restore original STDOUT
 print $more_stuff_for_STDOUT;

Answer 2

关闭 STDOUT 是不好的，因为很多人都假设它总是打开的。最好将其重定向到 /dev/null (unix) 或 nul (Windows)。

如果你想重定向文件描述符，

use Sub::ScopeFinalizer qw( scope_finalizer );

{
    open(my $backup_fh, '>&', \*STDOUT) or die $!;
    my $guard = scope_finalizer { open(STDOUT, '>&', $backup_fh) or die $!; };
    open(STDOUT, '>', '/dev/null') or die $!;

    ...
}

如果你只想重定向STDOUT，

{
    local *STDOUT;
    open(STDOUT, '>', '/dev/null') or die $!;

    ...
}

如果你只想重定向默认输出句柄，

use Sub::ScopeFinalizer qw( scope_finalizer );

{
    open(my $null_fh, '>', '/dev/null') or die $!;
    my $backup_fh = select($null_fh);
    my $guard = scope_finalizer { select($backup_fh); };

    ...
}

Answer 3

您可以实现一些东西来捕获 STDOUT，如下所示：

sub stdout_of (&) {
    my $code = shift;

    local *STDOUT;
    open STDOUT, '>', \(my $stdout_string = '')
        or die "reopen STDOUT: $!";

    $code->();

    return $stdout_string;
}

然后像这样使用它：

my $stdout = stdout_of { print "hello world" };

在 stdout_of() 中本地化文件句柄可以让您避免关闭和重新打开 STDOUT 的技巧。

Answer 4

阅读open 文档。

搜索“这是一个使用各种方法保存、重定向和恢复 STDOUT 和 STDERR 的脚本”。

您想要做的不是关闭 STDOUT，而是暂时将其重定向到 /dev/null。

Answer 5

要（重新）打开 STDOUT 或 STDERR 作为内存中的文件，请先将其关闭：

 close STDOUT;
    open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";

从 perl 文档： http://perldoc.perl.org/functions/open.html
你有一个 : 结束后，不要这样做。上面的 open 也应该适用于 jus

open STDOUT;

Perl Monks 中的这个线程也可能对您有帮助： http://www.perlmonks.org/?node_id=635010" rel="nofollow">http://www.perlmonks.org perlmonks.org/?node_id=635010

Answer 6

我检查了两种方法：

1. 通过 select
2. 通过 *OLD_STDOUT = * STDOUT，并发现它们在常见情况下不可用。

原因是只有在 Perl 脚本中使用“print”或其他内容时，这两种方法才会重定向 STDOUT。但是，如果您使用“system()”调用或调用下标，它们的输出无论如何都会达到标准 STDOUT =((。

我的观点是，真正的解决方案是：

#!/usr/bin/perl -w
my $file1 = "/tmp/out.txt";
my $file2 = "/tmp/err.txt";
open my $oldSTDOUT, ">&STDOUT";
open OLDERR, ">&",\*STDERR; 
open(STDOUT, ">$file1")  or print("Can't redirect stdout: to $file1 ");
open(STDERR, ">$file2")  or print("Can't redirect stderr: to $file2 ");
print "THIS OUTPUT ISN'T GOT TO STANDARD OUTPUT\n";
system("pwd"); # this output isn;t got to standard output too, that is right!
close(STDOUT);
close(STDERR);
open STDOUT, ">>&", $oldSTDOUT;
open STDERR, ">>&OLDERR"; 
print "BUT THIS OUTPUT IS SEEN IN A STANDARD OUTPUT\n";

我检查了这个解决方案，它对我有用。