创建 Palette 用于在已安装的 Mathematica 版本之间切换 .NB 关联

Question

我想创建一个调色板，用于在 Windows 下安装的 Mathematica 版本之间切换 .NB 文件关联。

目前，我开发了以下代码，用于枚举已安装的 Mathematica 版本并在它们之间进行切换：

1) 获取已安装的 Mathematica 版本的系统注册表项名称列表：

installedVersions = 
 Select[Developer`EnumerateRegistrySubkeys["HKEY_CLASSES_ROOT"], 
  StringMatchQ[#, "Mathematica.NB." ~~ ___] || # === 
     "MathematicaNB" &]

=> {"Mathematica.NB.7.0.1.1213965", "MathematicaNB"}

2) 添加 命令行选项 -b （禁用启动屏幕）和 -directlaunch （禁用启动安装的最新 Mathematica 版本的机制）到命令行字符串用于在系统注册表中启动Mathematica前端：

customizeOpenCommand[id_String] := Module[{value},
   value = 
    Cases[Developer`ReadRegistryKeyValues[
      "HKEY_CLASSES_ROOT\\" ~~ id ~~ "\\shell\\open\\command"], 
     Verbatim[Rule][Null, 
       val_String /; 
        StringFreeQ[val, " -b -directlaunch "]] :> (Null -> 
        StringReplace[val, 
         path__ ~~ "\\Mathematica.exe\"" ~~ __ ~~ "\"%1\"" :> 
          path ~~ "\\Mathematica.exe\" -b -directlaunch \"%1\""])];
   Developer`WriteRegistryKeyValues[
    "HKEY_CLASSES_ROOT\\" ~~ id ~~ "\\shell\\open\\command", value]];

该函数可按如下方式使用：

customizeOpenCommand /@ installedVersions

3) 用于获取当前.NB文件关联的函数：

Null /. Developer`ReadRegistryKeyValues["HKEY_CLASSES_ROOT\\.nb"]

4) 用于在所有Mathematica之间切换的按钮> 安装的版本（但我认为使用Dynamic和SetterBar可能可以更好地实现）：

Column[Button[
    Row[{"Associate .NB-files with ", Style[#, Bold], " (", 
      First@Cases[
        Developer`ReadRegistryKeyValues["HKEY_CLASSES_ROOT\\" ~~ #], 
        Verbatim[Rule][Null, str_String] :> str], ")"}], 
    Developer`WriteRegistryKeyValues["HKEY_CLASSES_ROOT\\.nb", 
     Null -> #], Alignment -> Left] & /@ installedVersions]

除了上面的之外，这里还有一个禁止在不同版本之间共享首选项的命令安装的 Mathematica 版本（默认情况下，所有安装的版本都使用一个文件来存储前端设置）：

SetOptions[$FrontEnd, "VersionedPreferences" -> True]

所以我的问题是：

如何创建和安装一个小的 Palette 它将动态显示.NB 文件的当前文件关联并允许通过单击按钮在它们之间切换？我认为它可能可以仅使用 SetterBar 来实现，但我对 Dynamic 和调色板创建仍然没有经验。

Answer 1

到目前为止，我已经得出以下解决方案：

CreatePalette@
  Framed[DynamicModule[{b, installedVersions}, 
    Dynamic[Column[
      Join[{Style["Associate .NB-files with:", Bold], 
        SetterBar[
         Dynamic[val, 
          Function[{v, e}, 
           Developer`WriteRegistryKeyValues["HKEY_CLASSES_ROOT\\.nb", 
            Null -> v]; 
           e = Null /. 
             Developer`ReadRegistryKeyValues[
              "HKEY_CLASSES_ROOT\\.nb"], HoldRest], 
          Initialization -> (installedVersions = 
             Select[Developer`EnumerateRegistrySubkeys[
               "HKEY_CLASSES_ROOT"], 
              StringMatchQ[#, "Mathematica.NB." ~~ ___] || # === 
                 "MathematicaNB" &]; 
            If[StringFreeQ[
                value = 
                 Null /. 
                  Developer`ReadRegistryKeyValues[
                   "HKEY_CLASSES_ROOT\\" ~~ # ~~ 
                    "\\shell\\open\\command"], " -b -directlaunch "], 
               Developer`WriteRegistryKeyValues[
                "HKEY_CLASSES_ROOT\\" ~~ # ~~ 
                 "\\shell\\open\\command", 
                Null -> 
                 StringReplace[value, 
                  path__ ~~ "\\Mathematica.exe\"" ~~ __ ~~ "\"%1\"" :>
                    path ~~ 
                    "\\Mathematica.exe\" -b -directlaunch \"%1\""]]] \
& /@ installedVersions)], installedVersions, 
         Appearance -> "Vertical"]}, 
       If[Last@Last@Options[$FrontEnd, "VersionedPreferences"] === 
          False && 
         b == True, {Button[
          Pane[Style[
            "This FrontEnd uses shared preferences file. Press this \
button to set FrontEnd to use versioned preferences file (all the \
FrontEnd settings will be reset to defaults).", Red], 300], 
          AbortProtect[
           SetOptions[$FrontEnd, "VersionedPreferences" -> True]; 
           b = False]]}, {}]], Alignment -> Center], 
     Initialization :> 
      If[! Last@Last@Options[$FrontEnd, "VersionedPreferences"], 
       b = True, b = False]]], FrameMargins -> {{0, 0}, {0, 5}}, 
   FrameStyle -> None];

可以使用“调色板”菜单中的“安装调色板...”菜单项永久安装该调色板。

其外观如下：

欢迎任何建议和改进！

---

由于Mathematica的所有已安装版本共享相同的$BaseDirectory和$UserBaseDirectory，因此建议在安装的最旧版本中安装此调色板，以避免标准警告弹出窗口：

此笔记本是在更新版本的 Mathematica 中创建的，并且
可能无法与您使用的旧前端一起正常工作。
请联系 Wolfram Research (www.wolfram.com) 了解升级信息。