在 AIR Security Sandbox 中执行远程 SWF

Question

我尝试下载外部 SWF 并在 AIR 安全沙箱中运行它。

这是 AIR 应用程序的代码：

public class Downloader extends Sprite
{

    private static const REMOTE_FILE:URLRequest = new URLRequest("http://myserver.com/downloadable.swf");
    private var _main:NativeWindow;

    public function Downloader()
    {
        var loader:URLLoader = new URLLoader(REMOTE_FILE);
        loader.dataFormat = URLLoaderDataFormat.BINARY;
        loader.addEventListener(Event.COMPLETE, downloadComplete);
    }

    private function downloadComplete(e:Event):void{
        var ba:ByteArray = e.target.data;
        var stream:FileStream = new FileStream();
        var file:File = File.applicationStorageDirectory.resolvePath("downloadable.swf");
        stream.open(file, FileMode.WRITE);
        stream.writeBytes(ba);
        stream.close();

        loadAndRunSwf();
    }

    private function loadAndRunSwf(){       
        this._main = new NativeWindow();
        this._main.width = 1024;
        this._main.height = 768;

                    ////obsolete?
        //var context:LoaderContext = new LoaderContext();
        //context.allowLoadBytesCodeExecution = true;
        //context.applicationDomain = ApplicationDomain.currentDomain;  

        var file:File = File.applicationStorageDirectory.resolvePath("downloadable.swf");
        var loader:Loader = new Loader();
        loader.load(new URLRequest(file.url)/*,context*/);

        this._main.stage.addChild(loader);
        this._main.activate();
    }
}

downloadable.swf 的代码：

public class Downloadable extends Sprite
{
    private var _btn:Button = new Button();
    private var _baseFolder:File = new File("app-storage:/");

    public function downloadable_test()
    {
        this.addChild(_btn);
        _btn.label = "access Harddisk";
                    ...
    }
}

所以现在，如果我运行 Downloader，它将下载 swf 并尝试运行它，但我会在 Downloadable 行中遇到异常，

    private var _baseFolder:File = new File("app-storage:/");

错误如下：

SecurityError: file
at runtime::SecurityManager$/checkPrivilegeForCaller()

那么 - 我需要做什么来防止此类安全错误？我希望我的远程 SWF 被视为在与 AIR 代码相同的安全沙箱中运行的本机代码。

Answer 1

我不确定 Android，但对于常规网络播放器，您需要为加载器上下文的 securityDomain 指定 SecurityDomain.currentDomain，以便加载的代码在权限方面被视为等于加载器。另请注意，由于无法解释的原因，如果您在从 PC 上的文件系统加载时使用 SecurityDomain，Flash Player 会发出抱怨。

无论多么复杂，Flash Player 安全性通常都是一种默默无闻的安全性...因此，如果它不能按照您编码的方式工作，请尝试 Loader.loadBytes() “解决方法”。

Answer 2

function loadAndRunSwf()
{
    var context:LoaderContext=new LoaderContext(false);

    context.allowCodeImport=true;

    var ba:ByteArray=new ByteArray();
    var file:File = File.applicationStorageDirectory.resolvePath("downloadable.swf");
    var fileStream:FileStream=new FileStream();
    var loader:Loader = new Loader();

    fileStream.open(file,"read");
    fileStream.readBytes(ba);
    ba.position=0;
    loader.loadBytes(ba,context);
    this._main = new NativeWindow();
    this._main.width = 1024;
    this._main.height = 768;
    this._main.stage.addChild(loader);
    this._main.activate();
}