如何使用Delphi Prism进行串口通信？

Question

我对 Delphi Prism 非常陌生。事实上，你甚至可以说我是一个新手，但我已经用 Delphi 编程了 10 年了。我能够将在以前版本的 Delphi 中编写的遗留软件移植到 Delphi 2010。现在，我准备使用 Delphi Prism 为 WEB (ASP.NET) 的 Delphi.Net 编写相同的软件。对于我的一生，我似乎无法理解 Delphi Prism 的总体布局或工作原理。我已经阅读了教程和示例，甚至在 Stackoverflow 上搜索了示例和代码。尽管如此，我似乎还是无法理解 Delphi Prism，尽管我已经花了整整一个星期的时间来玩 Delphi Prism IDE。

网上有人说，只需使用.NET框架，就可以将一个窗口独立程序编写为完全用于Web的程序。

现在我只是尝试使用 SerialPort 组件创建一个 Web 表单以在 comport 上进行通信。我能够设计网页控件（按钮、标签）...该程序在本地主机启动时编译并加载。我在浏览器上看到按钮，但它无法在串行端口上进行通信。

我很困惑。看来我做得不对。有人能给我一个 Delphi Prism SerialPort 组件使用的例子吗？

我不确定是我安装了它还是它随 Delphi Prism IDE 一起提供。但是，如果启动 Delphi Prism 后查看“组件”部分下的工具箱，您将看到一个名为 SerialPort 的组件。显然，它是 Microsoft .NET Framework 的一部分。

我想问如何使用 Delphi Prism IDE 附带的串行端口组件。

非常感谢，

Answer 1

您必须寻找 .Net 串行端口组件，而不是寻找用于串行端口的 Delphi prism 组件。您可以使用这篇文章 SerialPort（RS-232 串行 COM 端口） C# .NET 作为有关此主题的指南。

现在检查这个处理串行端口通信（仅接收数据）的delphi prism类。

namespace SerialComm;

interface

uses
  System.IO.Ports, //this namespace contains classes for controlling serial ports.      
  System.Collections.Generic,
  System.Linq,
  System.Text;

type
  DataMode = (Text,Hex);

  TSerialComm = public class
  private
    CurrentDataMode     : DataMode;
    method port_DataReceived( sender : object;  e : SerialDataReceivedEventArgs);
  public
    ComPort             : SerialPort := new SerialPort();
    method OpenPort();
    method ClosePort();
    method Init;
  end;

implementation

//here you receive the data
method TSerialComm.port_DataReceived( sender : object;  e : SerialDataReceivedEventArgs);

    method  ByteArrayToHexString(data : Array of Byte) : string;
    Begin
      var sb : StringBuilder := new StringBuilder(data.Length * 3);
      for each b in data do 
      sb.Append(Convert.ToString(b, 16).PadLeft(2, '0').PadRight(3, ' '));
      result:=sb.ToString().ToUpper();
    end;

Var
  data :string ;
begin

    if not ComPort.IsOpen then  exit;

    try
              // text mode
              if (CurrentDataMode = DataMode.Text) then
              begin                                    
                   data  := comport.ReadExisting();    
             //do your stuff here 
              end
              else
              ///binary (hex) mode
              begin
                var bytes : Integer  := ComPort.BytesToRead;
                var buffer : Array of byte  := new byte[bytes];
                ComPort.Read(buffer, 0, bytes);
                Data:= ByteArrayToHexString(buffer);
                //do your stuff here 
              end;

    except
      on ex: exception do begin         
          OutLog('port_DataReceived: ' + ex.Message + ' ** Trace: ' + ex.StackTrace);
         exit;
      end;
    end;
end;

method TSerialComm.OpenPort();
begin
      CurrentDataMode := DataMode.Text;
      OutLog('Open Port COM');
      if ComPort.IsOpen then ClosePort();       
       ComPort.DataReceived += new SerialDataReceivedEventHandler(port_DataReceived); 

        //ComPort.ReadTimeout:=100;
        ComPort.BaudRate := Convert.ToInt32(_Settings.BaudRate);
        ComPort.DataBits := Convert.ToInt32(_Settings.DataBits);
        var  aStopBits : StopBits  := StopBits(Enum.Parse(typeof(StopBits), _Settings.StopBits, true));
        ComPort.StopBits           := aStopBits;
        var  aParity : Parity      := Parity(Enum.Parse(typeof(Parity), _Settings.Parity, true));
        ComPort.Parity             := aParity;
        ComPort.PortName := _Settings.PortName;
        ComPort.Open();
        if ComPort.IsOpen then
         OutLog('Port '+ComPort.PortName+' Open')
        else
         OutLog('was not possible open the port '+ComPort.PortName);
end;

method TSerialComm.ClosePort();
begin
    if ComPort.IsOpen then
    begin
      ComPort.DataReceived +=nil;
      ComPort.ReadExisting;
      ComPort.Close();
    end;    
end;

method TSerialComm.Init;
begin 
 ComPort.DataReceived += new SerialDataReceivedEventHandler(port_DataReceived);
end;

注1：OutLog只是一个记录函数，您可以注释对此函数的调用。

注2：此代码必须从服务器端运行。