如何模式匹配 mochijson2 返回的结构？

Question

我刚刚开始修补 Erlang，并正在构建一个非常简单的测试 Web 应用程序，该应用程序只是为了显示我的 Twitter 时间线。

我正在使用 webmachine 编写应用程序并使用 erlyDTL 来呈现模板。

我的问题与 mochiweb 的 mochijson2:decode/1 函数返回的结构有关。

我可以成功获取并解码我的时间线，如下例所示：

1> Url = "http://api.twitter.com/1/statuses/user_timeline.json?screen_name=<TWITTER_SCREEN_NAME_HERE>".
2> inets:start().
3> {ok, {_, _, Response}} = httpc:request(Url).
4> DecodedJson = mochijson2:decode(Response).

mochijson2:decode/1 函数返回以下格式的元组列表：

[{struct, proplist()}, {struct, proplist()}, ...]

但是，要将时间线传递到 erlyDTL，我需要摆脱的 struct 原子标签，并简单地将 proplist 列表传递给 webmachine 资源（由 erlyDTL 渲染）。作为模式匹配的新手，我认为以下列表理解可以实现这一点：

Timeline = [Tweet || {struct, Tweet} <- DecodedJson].

事实上，这对于每个推文 proplist 中的所有项目都非常有效，除了一个 <<"user">> 。，其值本身是一个{struct, proplist()}元组。我一生都无法弄清楚如何从这个嵌套元组中删除 struct 原子，并且想知道是否有人可以提供一个 Erlang 代码示例，该示例将模式匹配 < 中的外部推文code>{struct, Tweet} 和每条推文中包含的 User {struct, User}。

最终目标是能够使用 Django 模板语言访问每条推文，如下例所示：

{{ tweet.text }}  <- works
{{ tweet.created_at }}  <- works
{{ tweet.user.profile_image_url }}  <- ???

任何帮助将不胜感激！

Answer 1

以下是我们内部用于类似目的的内容：

%% @doc Flatten {struct, [term()]} to [term()] recursively.
destruct({struct, L}) ->
    destruct(L);
destruct([H | T]) ->
    [destruct(H) | destruct(T)];
destruct({K, V}) ->
    {K, destruct(V)};
destruct(Term) ->
    Term.

对于 mochijson2 术语的其他用途，KVC 可能对您有用：https:// /github.com/etrepum/kvc

Answer 2

在我最近从事的一个项目中，我们正在处理来自 EXT JS 前端应用程序。下面是 JSON 对象的一个​​示例（这只是 JSON 的骨架）：

{
        "presence_token":"734737328233HDHSBSHSYEYEYWYWGWE",
        "presence_time":"HH:Mins:Secs",
        "friend_requests":
        [
            {
                "from":"Username",
                "type":"buddy",
                "date":"DD/MM/YY",
                "time":"HH:Mins:Secs",
                "name":"Your Full name",
                "email":"[email protected]"
            }
        ],
        "group_status":
        [
            {
                "group_name":"ecampus",
                "status":"running",
                "members":["phil","josh","shazz"],
                "start_date":"DD/MM/YY",
                "start_time":"HH:Mins:Secs"             
            },
            {
                "group_name":"buganda",
                "status":"off"
            }
        ],
        "friend_status":
        [
            {
                "friend":"Friend_username",
                "status":"online",
                "log_on_time":"HH:Mins:Secs",
                "state":"available",
                "name":"Friend_Fullname",
                "email":"[email protected]"              
            },
            {
                "friend":"Friend_username",
                "status":"offline",                 
                "name":"Friend_Fullname",
                "email":"[email protected]"              
            }           
        ]           
    }

在 mochijson2:decode/1 之后，我的结构对象如下所示：

        {struct,[{<<"presence_token">>,
                  <<"734737328233HDHSBSHSYEYEYWYWGWE">>},
                 {<<"presence_time">>,<<"HH:Mins:Secs">>},
                 {<<"friend_requests">>,
                  [{struct,[{<<"from">>,<<"Username">>},
                            {<<"type">>,<<"buddy">>},
                            {<<"date">>,<<"DD/MM/YY">>},
                            {<<"time">>,<<"HH:Mins:Secs">>},
                            {<<"name">>,<<"Your Full name">>},
                            {<<"email">>,<<"[email protected]">>}]}]},
                 {<<"group_status">>,
                  [{struct,[{<<"group_name">>,<<"ecampus">>},
                            {<<"status">>,<<"running">>},
                            {<<"members">>,[<<"phil">>,<<"josh">>,<<"shazz">>]},
                            {<<"start_date">>,<<"DD/MM/YY">>},
                            {<<"start_time">>,<<"HH:Mins:Secs">>}]},
                   {struct,[{<<"group_name">>,<<"buganda">>},
                            {<<"status">>,<<"off">>}]}]},
                 {<<"friend_status">>,
                  [{struct,[{<<"friend">>,<<"Friend_username">>},
                            {<<"status">>,<<"online">>},
                            {<<"log_on_time">>,<<"HH:Mins:Secs">>},
                            {<<"state">>,<<"available">>},
                            {<<"name">>,<<"Friend_Fullname">>},
                            {<<"email">>,<<"[email protected]">>}]},
                   {struct,[{<<"friend">>,<<"Friend_username">>},
                            {<<"status">>,<<"offline">>},
                            {<<"name">>,<<"Friend_Fullname">>},
                            {<<"email">>,<<"[email protected]">>}]}]}]}

现在我决定创建一个模块它将将此结构转换为“深层”proplist，该模块将包含一个函数 struct:all_keys/1 ，如果我向它提供结构对象，它将以有组织的方式生成列表和元组。代码如下：

-module(struct).
-export([all_keys/1]).

is_struct({struct,_}) -> true;
is_struct(_) -> false.

to_binary(S) when is_list(S)-> list_to_binary(S);
to_binary(S) when is_integer(S)-> S;
to_binary(S) when is_atom(S)-> to_binary(atom_to_list(S));
to_binary(S) -> S.

to_value(V) when is_binary(V)-> binary_to_list(V);
to_value(V) when is_integer(V)-> V;
to_value(V) when is_list(V)-> 
    try list_to_integer(V) of
        PP -> PP
    catch
        _:_ -> 
            try list_to_float(V) of
                PP2 -> PP2
            catch
                _:_ -> V
            end
    end;
to_value(A)-> A.

to_value2({struct,L})->
    all_keys({struct,L});
to_value2([{struct,_L}|_Rest] = LL)->
    [all_keys(XX) || XX <- LL];
to_value2(D) when is_binary(D)-> to_value(D);
to_value2(D) when is_list(D)-> 
    [to_value2(Any) || Any <- D].    

all_keys({struct,L})-> 
    [{to_value(Key),to_value2(Val)} || {Key,Val} <- L];
all_keys(List)-> [all_keys(X) || X <- List].

现在，调用 struct:all_keys(Struct_object) 将会给出以下输出：

[{"presence_token",P_token},
 {"presence_time",P_time},
 {"friend_requests",
  [[{"from","Username"},
    {"type","buddy"},
    {"date","DD/MM/YY"},
    {"time","HH:Mins:Secs"},
    {"name","Your Full name"},
    {"email","[email protected]"}]]},
 {"group_status",
  [[{"group_name","ecampus"},
    {"status","running"},
    {"members",["phil","josh","shazz"]},
    {"start_date","DD/MM/YY"},
    {"start_time","HH:Mins:Secs"}],
   [{"group_name","buganda"},{"status","off"}]]},
 {"friend_status",
  [[{"friend","Friend_username"},
    {"status","online"},
    {"log_on_time","HH:Mins:Secs"},
    {"state","available"},
    {"name","Friend_Fullname"},
    {"email","[email protected]"}],
   [{"friend","Friend_username"},
    {"status","offline"},
    {"name","Friend_Fullname"},
    {"email","[email protected]"}]]}]

上面的 proplist 比 struct 对象更容易使用。但是，您可能会发现 struct 模块的另一个版本，特别是在一个名为 Sticky Notes 的著名 mochiweb 示例中，我现在没有该链接。我上面粘贴的 struct 模块应该能够帮助您使用 mochijson2。
成功

Answer 3

根据您描述的结构，您可以尝试：

timeline(List) -> timeline(List, []).

timeline([], Result) -> lists:reverse(Result);
timeline([{struct, S}|T], Result) -> timeline(T, [S|Result]);
timeline([{<<"user">>, {struct, S}}|T], Result) -> timeline(T, [S|Result]);
timeline([_|T], Result) -> timeline(T, Result).

我将该代码放入名为 twitter 的模块中：

> twitter:timeline([{struct, 1}, {struct, 2}, {<<"user">>, {struct, 3}}, 5]).
[1,2,3]

您可能需要替换 <<"user">> 与 _ 取决于您的具体需求。您可能还想引入某种异常处理，因为您正在处理来自外部世界的输入。