在 Mathematica 中计算笛卡尔坐标系中的距离

Question

分析屏幕上的眼球运动，我将原点设置为屏幕的左下角 （当时很难修改）。

尝试计算某些点与屏幕中心之间的距离，我使用下面显示的简单公式。 问题是，在条件语句中使用它会变得很难看。

Sqrt[
(
(fixationX - centerX)^2 + (fixationY - centerY)^2
)
]

有没有办法自定义 Norm 来计算点之间的距离而不是点与原点之间的距离？

或者就我而言，将原点设置为当前坐标系的“中心”？

Answer 1

Simon 方法的一个细微变化是在函数中使用默认值，而不是全局变量 ($Center)。

假设您的默认原点是 (5, 5)，那么：

myNorm[pos:{_, _}, center_:{5, 5}] := EuclideanDistance[pos, center]

请注意使用 _:{5, 5} 来定义默认值。

现在你可以这样做：

myNorm[{5, 7}]

(* Out[]= 2 *)

或者暂时使用不同的中心：

myNorm[{5, 7}, {8, 8}]

(* Out[]= Sqrt[10] *)

对于这个简单的函数，你可以在第二种情况下使用EuclideanDistance，但我希望你能看到这个方法的实用性是定义myNorm 更复杂。

此方法的缺点是您无法轻松更改默认中心。

---

另一种允许人们轻松更改默认中心的变体是使用 Options：

Options[myNorm2] = {Center -> {5, 5}};

myNorm2[pos : {_, _}, OptionsPattern[]] := 
 EuclideanDistance[pos, OptionValue[Center]]

语法是：

myNorm2[{5, 7}]

myNorm2[{5, 7}, Center -> {8, 8}]

   2

   Sqrt[10]

更改默认中心：

SetOptions[myNorm2, Center -> {8, 8}];

myNorm2[{5, 7}]

   Sqrt[10]

Answer 2

您可以只使用 EuclideanDistance

In[1]:= EuclideanDistance[{x,y}, {cx,cy}]
Out[1]= Sqrt[Abs[-cx +x ]^2 + Abs[-cy + y]^2]

或者定义一个 $Center 和一个新的 CNorm，例如

$Center = {cx, cy};
CNorm[pos:{x_, y_}] := EuclideanDistance[pos, $Center]