对于多个数组

Question

在Scheme中，您可以使用for-each迭代多个列表：

> (for-each (lambda (a b) (display (+ a b)) (newline)) '(10 20 30) '(1 2 3))
11
22
33
> 

我知道在Perl中您可以使用for迭代单个列表。像方案示例中那样迭代多个列表的好方法是什么？

我对 Perl 5 或 6 的答案感兴趣。

Answer 1

在 Perl 6 中，Zip 运算符是最好的选择。如果您想获取两个值（而不是直接计算总和），则可以使用不带加号的值：

for (10, 11, 12) Z (1, 2, 3) -> $a, $b {
    say "$a and $b";
}

Answer 2

在 Perl 5 中，您可以使用模块 List::MoreUtils。可以使用成对的方式，也可以使用each_array 返回的迭代器（可以并行遍历两个以上的数组）。

use 5.12.0;
use List::MoreUtils qw(pairwise each_array);

my @one = qw(a b c d e);
my @two = qw(q w e r t);

my @three = pairwise {"$a:$b"} @one, @two;

say join(" ", @three);

my $it = each_array(@one, @two);
while (my @elems = $it->()) {
    say "$elems[0] and $elems[1]";
}

Answer 3

使用 Zip 运算符，您可以实现您使用 Scheme 所做的事情：

> .say for (10, 20, 30) Z+ (1, 2, 3)
11
22
33

请参阅 http://perlcabal.org /syn/S03.html#Zip_operators

Answer 4

如果您确定数组的索引大小相同，则可以迭代它们：

foreach( 0 .. $#array1 ) {
  print $array1[$_] + $array2[$_], "\n";
}

Answer 5

Algorithm::Loops 提供了一个 MapCar 函数，用于迭代多个数组（具有以不同方式处理不平等问题的变体）大小的数组）。

Answer 6

一种方法是：

sub for_each
{
    my $proc = shift ;

    my $len = @{$_[0]} ;

    for ( my $i = 0 ; $i < $len ; $i++ )
    {
        my @args = map $_->[$i] , @_ ;

        &$proc ( @args ) ;
    }
}

for_each sub { say $_[0] + $_[1] } , ([10,20,30],[1,2,3])

使用 List::MoreUtils 中的 each_arrayref：

sub for_each
{
    my $proc = shift ;

    my $it = each_arrayref ( @_ ) ;

    while ( my @elts = $it->() ) { &$proc ( @elts ) } ;
}

for_each sub { say $_[0] + $_[1] } , ([10,20,30],[1,2,3])

感谢 Alex 指出 List::MoreUtils。

Answer 7

只要问题很简单，只需添加（/乘法、除法……）即可
数组不是数组的数组，您还可以使用超级运算符来完成您的任务：（

<1 2 3> «+» <10 20 30>

当然这是 Perl6 答案）

如果您无法访问法语引号 «»，您可以将其重写为

<1 2 3> <<+>> <10 20 30>

Answer 8

一种解决方案（有很多可供选择）可能如下所示：

my @argle = (10, 20, 30);
my @bargle = (1, 2, 3);
do {
    my $yin = shift @argle;
    my $yang = shift @bargle;
    say $yin + $yang;
} while (@argle && @bargle);

我感觉您正在询问 foreach，它可能如下所示：

my @argle = (10, 20, 30);
my @bargle = (1, 2, 3);
for my $yin (@argle) {
    my $yang = shift @bargle;
    say $yin + $yang;
}

但在这种情况下它并不那么顺利。如果任一数组较短会发生什么？