状态设计模式的功能等价

Question

与状态设计模式等效的函数式编程是什么？或者更具体地说，状态设计模式的这个维基百科示例将如何转换为 FP？

Answer 1

此模式是使用 State monad 的示例，这是一种计算
环境可以用状态来增强代码。

这是 Haskell 中的一个实现。

一些帮助器：

import Control.Monad.Trans.State
import Control.Monad.IO.Class
import Data.Char

程序的两种操作模式

data Mode = A | B

使用此模式的状态计算类型，并用计数器进行增强。

type StateM a = StateT (Int, Mode) IO a

write函数，StateM上下文中的函数，
根据有状态模式更改其行为：

writeName :: String -> StateM ()
writeName s = do
    (n,mode) <- get
    case mode of
        A -> do liftIO (putStrLn (map toLower s))
                put (0,B)
        B -> do let n' = n + 1
                liftIO (putStrLn (map toUpper s))
                if n' > 1 then put (n', A)
                          else put (n', B)

运行程序，最初在状态 A 下启动有状态计算

main = flip runStateT (0, A) $ do
    writeName "Monday"
    writeName "Tuesday"
    writeName "Wednesday"
    writeName "Thursday"
    writeName "Saturday"
    writeName "Sunday"

从上面的代码中，main 的输出为：

monday
TUESDAY
WEDNESDAY
thursday
SATURDAY
SUNDAY

请注意，这是一个纯函数式解决方案。该程序中没有可变或破坏性更新。相反，状态单子通过计算线程化所需的模式。

Answer 2

一种编码：

import Data.Char (toUpper, toLower)

newtype State = State { unState :: String -> IO State }

stateA :: State
stateA = State $ \name -> do
    putStrLn (map toLower name)
    return stateB

stateB :: State
stateB = go 2
    where
    go 0 = stateA
    go n = State $ \name -> do
               putStrLn (map toUpper name)
               return $ go (n-1)

不要被 IO 愚弄，这是该模式的纯粹翻译（我们不使用 IORef 来存储状态或任何内容）。展开 newtype，我们可以看到这个类型的含义：

State = String -> IO (String -> IO (String -> IO (String -> ...

它需要一个字符串，执行一些 I/O 并请求另一个字符串，等等。

这是我最喜欢的 OO 中抽象类模式的编码：抽象类->类型、子类 ->该类型的元素。

newtype State 声明取代了抽象 writeName 声明及其签名。我们不传递一个 StateContext 来分配新状态，而是让它返回新状态。将返回值嵌入IO表示允许新状态依赖于I/O。由于在本示例中这在技术上不是必需的，因此我们可以使用更严格的类型

newtype State = State { unState :: String -> (State, IO ()) }

，在该类型中我们仍然可以表达此计算，但状态序列是固定的并且不允许依赖于输入。但让我们坚持原来的、更宽松的类型。

对于“测试客户端”：

runState :: State -> [String] -> IO ()
runState s [] = return ()
runState s (x:xs) = do
    s' <- unState s x
    runState s' xs

testClientState :: IO ()
testClientState = runState stateA
                   [ "Monday"
                   , "Tuesday"
                   , "Wednesday"
                   , "Thursday"
                   , "Saturday"
                   , "Sunday" ]

Answer 3

也许使用 State monad 与自定义修饰符和访问器相结合？

Answer 4

我不认为状态模式有纯功能上的等价物。因为纯函数式编程没有状态和时间的概念。状态模式本质上是关于状态和时间的。但我认为非纯函数等价物存在，它是无限惰性评估流。您可以使用 C# Yield 来实现它。