使用 applescript 处理 automator 中选定文本的列表

Question

在尝试执行从选定文本作为输入打开多个选项卡的自动操作时，我遇到了一个暂时无法解决的 applescript 问题。这包括答案，我将其发布在这里是因为我无法找到有关如何处理“输入”中的数据以接收“任何应用程序”自动操作中选定的“文本”的文档，所有内容都是针对以下文件的已经作为一个列表出现了。

当放入 applescript 操作时，您会得到：

on run {input, parameters}

这里的问题是输入不是列表格式，并且尝试对其执行任何操作都会破坏脚本或引发错误。即我不能这样做：

        repeat with URL in input
        set this_URL to URL

那么我如何将选定文本的列表视为项目列表？

Answer 1

解决方案是首先将输入视为字符串，然后分解每个段落。

on run {input, parameters}

set inputText to input as string
set URL_list to every paragraph of inputText

如果在执行“每个段落”之前不先将输入“视为字符串”，它将无法工作。

这是最终的工作脚本，将“some_url”替换为您自己的。您将能够在编辑器中选择多行文本，并将每一行视为固定网址的参数，在新的 Safari 选项卡中打开每一行。这可以通过为 url 上的多个参数分隔每一行来扩展。

on run {input, parameters}

set inputText to input as string
set URL_list to every paragraph of inputText
tell application "Safari"
    activate
    repeat with URL in URL_list
        set this_URL to URL
        # extra processing of URL could be done here for multiple params
        my new_tab()
        set tab_URL to "http://some_url.com?data=" & this_URL
        set the URL of document 1 to tab_URL
    end repeat
end tell
return input
end run

on new_tab()
    tell application "Safari" to activate
    tell application "System Events"
        tell process "Safari"
            click menu item "New Tab" of ¬
                menu "File" of menu bar 1
        end tell
    end tell
end new_tab

举个例子，假设您拥有该列表并使用“http://stackoverflow.com/posts/”和“http://stackoverflow.com/posts/”获得了上述服务。 this_URL

6318162 
6318163 
6318164

您现在可以选择它们，单击服务并选择您的“StackOverflow - 查看问题”服务，它将在新的 safari 选项卡中附加并打开每个服务。就我而言，我需要验证服务器中的多个 dns 条目是否仍然有效，并进行大量 whois 查找。

Answer 2

我一直在寻找同样的东西，只是寻找从 Automator 到 AppleScript 输入的文件。

ddowns 的技巧对此不起作用，但最终使用了这个，希望它对寻求解决我遇到的相同问题的人有帮助：

on run {input, parameters}

    -- create empty list
    set selectedFiles to {}

    -- add each list item to the empty list
    repeat with i in input
        copy (POSIX path of i) to end of selectedFiles
    end repeat

    -- show each item (just for testing purposes of course) 
    repeat with currentFile in selectedFiles
        display dialog currentFile as text
    end repeat

end run

Answer 3

正如 Hanzaplastique 所说，对于 Automator 中的 AppleScript，您不需要 Safari AppleScript，因为有一个 Action。我使用以下操作：

• 从文本中提取 URL（实际上是“从文本中提取数据”操作）
• 运行 AppleScript
• 显示网页

我将其用作添加到“服务”菜单中的工作流程，以便我可以右键单击电子邮件中的选定文本，然后在 Safari 选项卡中打开多个 URL。

特别是，我通过电子邮件收到服务器/WordPress 更新，但 URL 只是域的顶层，我想跳转到 WordPress 的插件页面。所以，我的 AppleScript（感谢 Hanzaplastique）是：

on run {input, parameters}
    set AppleScript's text item delimiters to {return & linefeed, return, linefeed, character id 8233, character id 8232}
    -- create empty list
    set selectedFiles to {}
    -- add each list item to the empty list
    repeat with i in input
        set AppleScript's text item delimiters to {" "}
        set i to i & "/wp-admin/plugins.php"
        copy i to end of selectedFiles
    end repeat
    return selectedFiles
end run

我发现我需要“返回 selectedFiles”。总是神秘的（对我来说）文本分隔符可能不是必需的，并且来自仅提取单个 URL 的先前版本。